blob: 89a70260ca957cc0684436adf80510faf499126d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
CONFIG += designer plugin debug_and_release
TARGET = $$qtLibraryTarget(qtcreatorwidgets)
TEMPLATE = lib
HEADERS = customwidgets.h \
customwidget.h
SOURCES = customwidgets.cpp
# Link against the qtcreator utils lib
isEmpty(IDE_LIBRARY_BASENAME) {
IDE_LIBRARY_BASENAME = lib
}
linux-*||win32 {
# form abs path to qtcreator lib dir
QTC_LIBS=$$dirname(OUT_PWD)
QTC_LIBS=$$dirname(QTC_LIBS)
QTC_LIBS=$$dirname(QTC_LIBS)
QTC_LIBS=$$QTC_LIBS/$$IDE_LIBRARY_BASENAME/qtcreator
}
linux-*{
QMAKE_RPATHDIR *= $$QTC_LIBS
}
INCLUDEPATH += ../../../src/libs
macx {
LIBS += -L"../../../bin/Qt Creator.app/Contents/PlugIns"
CONFIG(debug, debug|release):LIBS += -lUtils_debug
else:LIBS += -lUtils
} else:win32 {
message($$QTC_LIBS)
LIBS += -L$$QTC_LIBS
CONFIG(debug, debug|release):LIBS += -lUtilsd
else:LIBS += -lUtils
} else {
message($$QTC_LIBS)
LIBS += -L$$QTC_LIBS -lUtils
}
DESTDIR= $$[QT_INSTALL_PLUGINS]/designer
|
