blob: 430e135b40521edb3ee572aff146fa4f4cb502ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
include(../../qtcreator.pri)
TEMPLATE = subdirs
SUBDIRS = \
coreplugin \
find \
texteditor \
cppeditor \
bineditor \
diffeditor \
imageviewer \
bookmarks \
projectexplorer \
vcsbase \
perforce \
subversion \
git \
cvs \
cpptools \
qtsupport \
qt4projectmanager \
locator \
debugger \
help \
cpaster \
cmakeprojectmanager \
autotoolsprojectmanager \
fakevim \
designer \
resourceeditor \
genericprojectmanager \
qmljseditor \
qmlprojectmanager \
glsleditor \
pythoneditor \
mercurial \
bazaar \
classview \
tasklist \
analyzerbase \
qmljstools \
macros \
remotelinux \
android \
madde \
valgrind \
todo \
qnx \
clearcase \
baremetal
isEmpty(QBS_INSTALL_DIR): QBS_INSTALL_DIR = $$(QBS_INSTALL_DIR)
exists(../shared/qbs/qbs.pro)|!isEmpty(QBS_INSTALL_DIR): \
SUBDIRS += \
qbsprojectmanager
isEmpty(IDE_PACKAGE_MODE) {
SUBDIRS += \
helloworld \
updateinfo
} else:!isEmpty(UPDATEINFO_ENABLE) {
SUBDIRS += \
updateinfo
}
minQtVersion(5, 1, 0) {
SUBDIRS += \
qmldesigner \
qmlprofiler \
welcome
} else {
warning("QmlDesigner plugin has been disabled.")
warning("QmlProfiler plugin has been disabled.")
warning("Welcome plugin has been disabled.")
warning("These plugins need at least Qt 5.1.")
}
for(p, SUBDIRS) {
QTC_PLUGIN_DEPENDS =
include($$p/$${p}_dependencies.pri)
pv = $${p}.depends
$$pv = $$QTC_PLUGIN_DEPENDS
}
SUBDIRS += debugger/dumper.pro
linux-* {
SUBDIRS += debugger/ptracepreload.pro
}
include (debugger/lldblib/guest/qtcreator-lldb.pri)
|
