blob: 446bfc1c2691b8288c7b54f51a54f349d66e590b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
|
// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0
import QtQuick 2.15
import QtQuick.Templates 2.15 as T
import StudioTheme 1.0 as StudioTheme
TextInput {
id: textInput
property T.Control myControl
property bool edit: textInput.activeFocus
property bool drag: false
property bool hover: mouseArea.containsMouse && textInput.enabled
property int devicePixelRatio: 1
property int pixelsPerUnit: 10
z: 2
font: myControl.font
color: StudioTheme.Values.themeTextColor
selectionColor: StudioTheme.Values.themeTextSelectionColor
selectedTextColor: StudioTheme.Values.themeTextSelectedTextColor
horizontalAlignment: Qt.AlignRight
verticalAlignment: Qt.AlignVCenter
leftPadding: StudioTheme.Values.inputHorizontalPadding
rightPadding: StudioTheme.Values.inputHorizontalPadding
readOnly: !myControl.editable
validator: myControl.validator
inputMethodHints: myControl.inputMethodHints
selectByMouse: false
activeFocusOnPress: false
clip: true
// TextInput focus needs to be set to activeFocus whenever it changes,
// otherwise TextInput will get activeFocus whenever the parent SpinBox gets
// activeFocus. This will lead to weird side effects.
onActiveFocusChanged: textInput.focus = textInput.activeFocus
Rectangle {
id: textInputBackground
x: 0
y: StudioTheme.Values.border
z: -1
width: textInput.width
height: StudioTheme.Values.height - (StudioTheme.Values.border * 2)
color: StudioTheme.Values.themeControlBackground
border.width: 0
}
Item {
id: dragModifierWorkaround
Keys.onPressed: function(event) {
event.accepted = true
if (event.modifiers & Qt.ControlModifier) {
mouseArea.stepSize = myControl.minStepSize
mouseArea.calcValue()
myControl.valueModified()
}
if (event.modifiers & Qt.ShiftModifier) {
mouseArea.stepSize = myControl.maxStepSize
mouseArea.calcValue()
myControl.valueModified()
}
}
Keys.onReleased: function(event) {
event.accepted = true
mouseArea.stepSize = myControl.stepSize
mouseArea.calcValue()
myControl.valueModified()
}
}
// Ensure that we get Up and Down key press events first
Keys.onShortcutOverride: function(event) {
event.accepted = (event.key === Qt.Key_Up || event.key === Qt.Key_Down)
}
MouseArea {
id: mouseArea
property real stepSize: myControl.stepSize
// Properties to store the state of a drag operation
property bool dragging: false
property bool hasDragged: false
property bool potentialDragStart: false
property int initialValue: myControl.value // value on drag operation starts
property real pressStartX: 0.0
property real dragStartX: 0.0
property real translationX: 0.0
property real dragDirection: 0.0
property real totalUnits: 0.0 // total number of units dragged
property real units: 0.0
property real __pixelsPerUnit: textInput.devicePixelRatio * textInput.pixelsPerUnit
anchors.fill: parent
enabled: true
hoverEnabled: true
propagateComposedEvents: true
acceptedButtons: Qt.LeftButton
cursorShape: Qt.PointingHandCursor
preventStealing: true
onPositionChanged: function(mouse) {
if (!mouseArea.dragging
&& !myControl.edit
&& Math.abs(mouseArea.pressStartX - mouse.x) > StudioTheme.Values.dragThreshold
&& mouse.buttons === Qt.LeftButton
&& mouseArea.potentialDragStart) {
mouseArea.dragging = true
mouseArea.potentialDragStart = false
mouseArea.initialValue = myControl.value
mouseArea.cursorShape = Qt.ClosedHandCursor
mouseArea.dragStartX = mouse.x
myControl.drag = true
myControl.dragStarted()
// Force focus on the non visible component to receive key events
dragModifierWorkaround.forceActiveFocus()
textInput.deselect()
}
if (!mouseArea.dragging)
return
mouse.accepted = true
var translationX = mouse.x - mouseArea.dragStartX
// Early return if mouse didn't move along x-axis
if (translationX === 0)
return
var currentDragDirection = Math.sign(translationX)
// Has drag direction changed
if (currentDragDirection !== mouseArea.dragDirection) {
mouseArea.translationX = 0
mouseArea.dragDirection = currentDragDirection
mouseArea.totalUnits = mouseArea.units
}
mouseArea.translationX += translationX
mouseArea.calcValue()
myControl.valueModified()
}
onClicked: function(mouse) {
if (textInput.edit)
mouse.accepted = false
if (mouseArea.hasDragged) {
mouseArea.hasDragged = false
return
}
textInput.forceActiveFocus()
textInput.deselect() // QTBUG-75862
}
onPressed: function(mouse) {
if (textInput.edit)
mouse.accepted = false
mouseArea.potentialDragStart = true
mouseArea.pressStartX = mouse.x
}
onReleased: function(mouse) {
if (textInput.edit)
mouse.accepted = false
mouseArea.endDrag()
}
function endDrag() {
if (!mouseArea.dragging)
return
mouseArea.dragging = false
mouseArea.hasDragged = true
if (myControl.compressedValueTimer.running) {
myControl.compressedValueTimer.stop()
mouseArea.calcValue()
myControl.compressedValueModified()
}
mouseArea.cursorShape = Qt.PointingHandCursor
myControl.drag = false
myControl.dragEnded()
// Avoid active focus on the component after dragging
dragModifierWorkaround.focus = false
textInput.focus = false
myControl.focus = false
mouseArea.translationX = 0
mouseArea.units = 0
mouseArea.totalUnits = 0
}
function calcValue() {
var minUnit = (myControl.from - mouseArea.initialValue) / mouseArea.stepSize
var maxUnit = (myControl.to - mouseArea.initialValue) / mouseArea.stepSize
var units = Math.trunc(mouseArea.translationX / mouseArea.__pixelsPerUnit)
mouseArea.units = Math.min(Math.max(mouseArea.totalUnits + units, minUnit), maxUnit)
myControl.value = mouseArea.initialValue + (mouseArea.units * mouseArea.stepSize)
if (mouseArea.dragging)
myControl.dragging()
}
onWheel: function(wheel) {
if (!myControl.__wheelEnabled) {
wheel.accepted = false
return
}
// Set stepSize according to used modifier key
if (wheel.modifiers & Qt.ControlModifier)
mouseArea.stepSize = myControl.minStepSize
if (wheel.modifiers & Qt.ShiftModifier)
mouseArea.stepSize = myControl.maxStepSize
var val = myControl.valueFromText(textInput.text, myControl.locale)
if (myControl.value !== val)
myControl.value = val
var currValue = myControl.value
myControl.value += (wheel.angleDelta.y / 120 * mouseArea.stepSize)
if (currValue !== myControl.value)
myControl.valueModified()
// Reset stepSize
mouseArea.stepSize = myControl.stepSize
}
}
states: [
State {
name: "default"
when: myControl.enabled && !textInput.edit && !textInput.hover && !myControl.hover
&& !myControl.drag && !myControl.sliderDrag
PropertyChanges {
target: textInputBackground
color: StudioTheme.Values.themeControlBackground
}
PropertyChanges {
target: mouseArea
cursorShape: Qt.PointingHandCursor
}
},
State {
name: "globalHover"
when: myControl.hover && !textInput.hover && !textInput.edit && !myControl.drag
PropertyChanges {
target: textInputBackground
color: StudioTheme.Values.themeControlBackgroundGlobalHover
}
},
State {
name: "hover"
when: textInput.hover && myControl.hover
&& !textInput.edit && !myControl.drag
PropertyChanges {
target: textInputBackground
color: StudioTheme.Values.themeControlBackgroundHover
}
},
State {
name: "edit"
when: textInput.edit && !myControl.drag
PropertyChanges {
target: textInputBackground
color: StudioTheme.Values.themeControlBackgroundInteraction
}
PropertyChanges {
target: mouseArea
cursorShape: Qt.IBeamCursor
}
},
State {
name: "drag"
when: myControl.drag
PropertyChanges {
target: textInputBackground
color: StudioTheme.Values.themeControlBackgroundInteraction
}
PropertyChanges {
target: textInput
color: StudioTheme.Values.themeInteraction
}
},
State {
name: "sliderDrag"
when: myControl.sliderDrag
PropertyChanges {
target: textInputBackground
color: StudioTheme.Values.themeControlBackground
}
PropertyChanges {
target: textInput
color: StudioTheme.Values.themeInteraction
}
},
State {
name: "disable"
when: !myControl.enabled
PropertyChanges {
target: textInputBackground
color: StudioTheme.Values.themeControlBackgroundDisabled
}
PropertyChanges {
target: textInput
color: StudioTheme.Values.themeTextColorDisabled
}
}
]
}
|