1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
|
dnl configure.ac
dnl
dnl xfwm4 - window manager for the Xfce4 desktop environment
dnl
m4_define([xfwm4_version], [4.3.90.2])
dnl init autoconf
AC_COPYRIGHT([Copyright (c) 2002-2005
The Xfce development team. All rights reserved.
Written for Xfce by Olivier Fourdan <fourdan@xfce.org>.])
AC_INIT([xfwm4], [xfwm4_version()], [xfce4-dev@xfce.org])
AM_INIT_AUTOMAKE([xfwm4], [xfwm4_version()])
AM_INIT_AUTOMAKE([AC_PACKAGE_TARNAME()], [AC_PACKAGE_VERSION()])
AM_CONFIG_HEADER([config.h])
AM_MAINTAINER_MODE
dnl check for UNIX variants
AC_AIX
AC_ISC_POSIX
AC_MINIX
AM_CONDITIONAL([HAVE_CYGWIN], [test "`uname | grep \"CYGWIN\"`" != ""])
dnl check for basic programs
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_INTLTOOL([0.31], [no-xml])
AC_PROG_LIBTOOL
dnl Check C Compiler Characteristics
AC_C_CONST
AC_C_INLINE
dnl check for standard header files
AC_HEADER_STDC
AC_CHECK_FUNCS([daemon setsid])
AC_CHECK_FUNCS(opendir)
dnl Check for i18n support
XDT_I18N([@LINGUAS@])
dnl Check for X11 window system
XDT_CHECK_LIBX11_REQUIRE
XDT_CHECK_LIBSM
dnl Check for Xext library
AC_CHECK_LIB([Xext], [XShapeCombineShape],
[
if ! echo $LIBX11_LIBS | grep -q -- '-lXext'; then
LIBX11_LIBS="$LIBX11_LIBS -lXext"
fi
], [], [$LIBX11_CFLAGS $LIBX11_LDFLAGS $LIBX11_LIBS])
XDT_CHECK_PACKAGE([GTK], [gtk+-2.0], [2.6.0])
XDT_CHECK_PACKAGE(LIBXFCE4MCS_CLIENT, libxfce4mcs-client-1.0, [4.3.90.2])
XDT_CHECK_PACKAGE(LIBXFCE4MCS_MANAGER, libxfce4mcs-manager-1.0, [4.3.90.2])
XDT_CHECK_PACKAGE([LIBXFCE4UTIL], [libxfce4util-1.0], [4.3.90.2])
XDT_CHECK_PACKAGE(LIBXFCEGUI4, libxfcegui4-1.0, [4.3.90.2])
XFCE_MCS_PLUGIN([XFCE_MCS_MANAGER], [4.3.90.2])
dnl
dnl Startup notification support
dnl
LIBSTARTUP_NOTIFICATION_FOUND="no"
XDT_CHECK_OPTIONAL_PACKAGE([LIBSTARTUP_NOTIFICATION],
[libstartup-notification-1.0], [0.5],
[startup-notification],
[startup notification library], [yes])
dnl
dnl Render support
dnl
have_render="no"
if $PKG_CONFIG --print-errors --exists xrender 2>&1; then
PKG_CHECK_MODULES(RENDER, xrender)
have_render="yes"
AC_DEFINE([HAVE_RENDER], [1], [Define to enable render])
else
dnl fallback to check for libXrender
AC_CHECK_LIB([Xrender], [XRenderCreatePicture],
[ have_render="yes"
RENDER_LIBS=" -lXrender"
AC_DEFINE([HAVE_RENDER], [1], [Define to enable render])
],[])
fi
dnl
dnl RANDR extension
dnl (please note that Xrandr requires Xrender - and no, it's not a typo ;)
dnl
AC_ARG_ENABLE([randr],
AC_HELP_STRING([--enable-randr], [try to use the randr extension])
AC_HELP_STRING([--disable-randr], [don't try to use the randr extension]),
[], [enable_randr=yes])
RANDR_LIBS=
have_xrandr="no"
if test x"$enable_randr" = x"yes"; then
if test x"$have_render" = x"yes"; then
have_xrandr="no"
ac_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $LIBX11_CFLAGS"
AC_CHECK_LIB(Xrandr, XRRUpdateConfiguration,
[AC_CHECK_HEADER(X11/extensions/Xrandr.h,
RANDR_LIBS="-lXrandr -lXrender"
AC_DEFINE([HAVE_RANDR], [1], [Define to enable xrandr])
have_xrandr="yes",,
[#include <X11/Xlib.h>])],,
$LIBS $LIBX11_LDFLAGS $LIBX11_LIBS -lXrender -lXext)
CFLAGS="$ac_CFLAGS"
fi
fi
AC_SUBST([RANDR_LIBS])
dnl
dnl Xcomposite and related extensions
dnl
compositor="no"
ENABLE_COMPOSITOR=""
AC_ARG_ENABLE([compositor],
AC_HELP_STRING([--enable-compositor], [enable compositor in xfwm4 (default)])
AC_HELP_STRING([--disable-compositor], [disable compositor in xfwm4]),
[], [enable_compositor=yes])
if test x"$enable_compositor" = x"yes"; then
if test x"$have_render" = x"yes"; then
if $PKG_CONFIG --print-errors --exists xcomposite xfixes xdamage xrender 2>&1; then
PKG_CHECK_MODULES(COMPOSITOR, xcomposite >= 0.2 xfixes xdamage)
AC_DEFINE([HAVE_COMPOSITOR], [1], [Define to enable compositor])
ENABLE_COMPOSITOR="--enable-compositor"
compositor="yes"
fi
fi
fi
AC_SUBST(ENABLE_COMPOSITOR)
dnl
dnl Old unsupported KDE systray protocol
dnl
ENABLE_KDE_SYSTRAY=""
kde_systray="no"
AC_ARG_ENABLE([kde_systray],
AC_HELP_STRING([--enable-kde-systray], [enable KDE systray proxy (deprecated)]),
kde_systray="$enableval",
kde_systray="no")
if test x"$kde_systray" = x"yes"; then
AC_DEFINE([ENABLE_KDE_SYSTRAY_PROXY], [1], [Define to enable KDE systray proxy support])
ENABLE_KDE_SYSTRAY="--enable-kde-systray"
fi
AC_SUBST(ENABLE_KDE_SYSTRAY)
dnl Check for debugging support
XDT_FEATURE_DEBUG
REVISION=@REVISION@
AC_DEFINE_UNQUOTED([REVISION], "$REVISION", [svn revision number])
AC_SUBST([REVISION])
AC_OUTPUT([
Makefile
doc/Makefile
doc/C/Makefile
doc/C/images/Makefile
doc/fr/Makefile
doc/fr/images/Makefile
doc/it/Makefile
doc/it/images/Makefile
defaults/Makefile
icons/Makefile
icons/48x48/Makefile
icons/scalable/Makefile
mcs-plugin/Makefile
po/Makefile.in
src/Makefile
themes/Makefile
themes/daloa/Makefile
themes/default/Makefile
themes/default.keys/Makefile
themes/default-4.0/Makefile
themes/default-4.2/Makefile
themes/katiola/Makefile
themes/moheli/Makefile
themes/stoneage/Makefile
themes/therapy/Makefile
themes/tyrex/Makefile
themes/wallis/Makefile
xfwm4.spec
])
echo
echo "Build Configuration for $PACKAGE version $VERSION revision $REVISION:"
echo " Startup notification support: $LIBSTARTUP_NOTIFICATION_FOUND"
echo " Render support: $have_render"
echo " Xrandr support: $have_xrandr"
echo " Embedded compositor: $compositor"
echo " KDE systray protocol proxy: $kde_systray"
echo
|
