1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
/* valatypecheck.vala
*
* Copyright (C) 2006-2010 Jürg Billeter
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Jürg Billeter <j@bitron.ch>
*/
using GLib;
/**
* Represents a type check (`is`) expression in the source code.
*/
public class Vala.TypeCheck : Expression {
/**
* The expression to be checked.
*/
public Expression expression {
get { return _expression; }
private set {
_expression = value;
_expression.parent_node = this;
}
}
/**
* The type to be matched against.
*/
public DataType type_reference {
get { return _data_type; }
private set {
_data_type = value;
_data_type.parent_node = this;
}
}
Expression _expression;
private DataType _data_type;
/**
* Creates a new type check expression.
*
* @param expr an expression
* @param type a data type
* @param source reference to source code
* @return newly created type check expression
*/
public TypeCheck (Expression expr, DataType type, SourceReference? source = null) {
expression = expr;
type_reference = type;
source_reference = source;
}
public override void accept (CodeVisitor visitor) {
visitor.visit_type_check (this);
visitor.visit_expression (this);
}
public override void accept_children (CodeVisitor visitor) {
expression.accept (visitor);
type_reference.accept (visitor);
}
public override bool is_pure () {
return expression.is_pure ();
}
public override void replace_type (DataType old_type, DataType new_type) {
if (type_reference == old_type) {
type_reference = new_type;
}
}
public override void replace_expression (Expression old_node, Expression new_node) {
if (expression == old_node) {
expression = new_node;
}
}
public override bool check (CodeContext context) {
if (checked) {
return !error;
}
checked = true;
expression.check (context);
type_reference.check (context);
if (expression.value_type == null) {
Report.error (expression.source_reference, "invalid left operand");
error = true;
return false;
}
if (type_reference.type_symbol == null) {
/* if type resolving didn't succeed, skip this check */
error = true;
return false;
}
if (type_reference is ErrorType && !(expression.value_type is ErrorType)) {
Report.error (expression.source_reference, "`%s' must be an error", expression.to_string ());
error = true;
return false;
}
if (context.profile == Profile.GOBJECT && type_reference.has_type_arguments ()) {
Report.warning (_data_type.source_reference, "Type argument list has no effect");
}
value_type = context.analyzer.bool_type;
return !error;
}
public override void emit (CodeGenerator codegen) {
expression.emit (codegen);
codegen.visit_type_check (this);
codegen.visit_expression (this);
}
public override string to_string () {
return "(%s is %s)".printf (expression.to_string (), type_reference.to_string ());
}
}
|
