1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
|
/* valatrystatement.vala
*
* Copyright (C) 2007-2010 Jürg Billeter
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Jürg Billeter <j@bitron.ch>
*/
using GLib;
/**
* Represents a try statement in the source code.
*/
public class Vala.TryStatement : CodeNode, Statement {
/**
* Specifies the body of the try statement.
*/
public Block body {
get { return _body; }
private set {
_body = value;
_body.parent_node = this;
}
}
/**
* Specifies the body of the optional finally clause.
*/
public Block? finally_body {
get { return _finally_body; }
private set {
_finally_body = value;
if (_finally_body != null)
_finally_body.parent_node = this;
}
}
public bool after_try_block_reachable { get; set; default = true; }
private Block _body;
private Block _finally_body;
private List<CatchClause> catch_clauses = new ArrayList<CatchClause> ();
/**
* Creates a new try statement.
*
* @param body body of the try statement
* @param finally_body body of the optional finally clause
* @param source_reference reference to source code
* @return newly created try statement
*/
public TryStatement (Block body, Block? finally_body, SourceReference? source_reference = null) {
this.body = body;
this.finally_body = finally_body;
this.source_reference = source_reference;
}
/**
* Appends the specified clause to the list of catch clauses.
*
* @param clause a catch clause
*/
public void add_catch_clause (CatchClause clause) {
clause.parent_node = this;
catch_clauses.add (clause);
}
/**
* Returns the list of catch clauses.
*
* @return list of catch clauses
*/
public unowned List<CatchClause> get_catch_clauses () {
return catch_clauses;
}
public override void accept (CodeVisitor visitor) {
visitor.visit_try_statement (this);
}
public override void accept_children (CodeVisitor visitor) {
body.accept (visitor);
foreach (CatchClause clause in catch_clauses) {
clause.accept (visitor);
}
if (finally_body != null) {
finally_body.accept (visitor);
}
}
public override void get_error_types (Collection<DataType> collection, SourceReference? source_reference = null) {
var error_types = new ArrayList<DataType> ();
body.get_error_types (error_types, source_reference);
foreach (CatchClause clause in catch_clauses) {
for (int i=0; i < error_types.size; i++) {
var error_type = error_types[i];
if (clause.error_type == null || error_type.compatible (clause.error_type)) {
error_types.remove_at (i);
i--;
}
}
clause.body.get_error_types (collection, source_reference);
}
if (finally_body != null) {
finally_body.get_error_types (collection, source_reference);
}
foreach (var error_type in error_types) {
collection.add (error_type);
}
}
public override bool check (CodeContext context) {
if (checked) {
return !error;
}
checked = true;
if (context.profile == Profile.POSIX) {
Report.error (source_reference, "`try' is not supported in POSIX profile");
error = true;
return false;
}
body.check (context);
foreach (CatchClause clause in catch_clauses) {
clause.check (context);
}
if (finally_body != null) {
finally_body.check (context);
}
return !error;
}
public override void emit (CodeGenerator codegen) {
codegen.visit_try_statement (this);
}
}
|
