1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
/* valabaseaccess.vala
*
* Copyright (C) 2006-2010 Jürg Billeter
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Jürg Billeter <j@bitron.ch>
*/
/**
* Represents an access to base type member in the source code.
*/
public class Vala.BaseAccess : Expression {
/**
* Creates a new base access expression.
*
* @param source reference to source code
* @return newly created base access expression
*/
public BaseAccess (SourceReference? source = null) {
source_reference = source;
}
public override void accept (CodeVisitor visitor) {
visitor.visit_base_access (this);
visitor.visit_expression (this);
}
public override string to_string () {
return "base";
}
public override bool is_pure () {
return true;
}
public override bool check (CodeContext context) {
if (checked) {
return !error;
}
checked = true;
if (!context.analyzer.is_in_instance_method ()) {
error = true;
Report.error (source_reference, "Base access invalid outside of instance methods");
return false;
}
if (context.analyzer.current_class == null) {
if (context.analyzer.current_struct == null) {
error = true;
Report.error (source_reference, "Base access invalid outside of class and struct");
return false;
} else if (context.analyzer.current_struct.base_type == null) {
error = true;
Report.error (source_reference, "Base access invalid without base type");
return false;
}
value_type = context.analyzer.current_struct.base_type;
} else if (context.analyzer.current_class.base_class == null) {
error = true;
Report.error (source_reference, "Base access invalid without base class");
return false;
} else if (context.analyzer.current_class.is_compact && context.analyzer.current_method != null
&& !(context.analyzer.current_method is CreationMethod)
&& (context.analyzer.current_method.overrides || context.analyzer.current_method.is_virtual)) {
error = true;
Report.error (source_reference, "Base access invalid in virtual overridden method of compact class");
return false;
} else if (context.analyzer.current_class.is_compact && context.analyzer.current_property_accessor != null
&& (context.analyzer.current_property_accessor.prop.overrides || context.analyzer.current_property_accessor.prop.is_virtual)) {
error = true;
Report.error (source_reference, "Base access invalid in virtual overridden property of compact class");
return false;
} else {
foreach (var base_type in context.analyzer.current_class.get_base_types ()) {
if (base_type.type_symbol is Class) {
value_type = base_type.copy ();
value_type.value_owned = false;
}
}
}
symbol_reference = value_type.type_symbol;
return !error;
}
public override void emit (CodeGenerator codegen) {
codegen.visit_base_access (this);
codegen.visit_expression (this);
}
}
|
