codegen: Properly handle and catch inner-error of finally-block

If all inner-errors are caught there is no jump-out of the current finally-
block therefore the control-flow analyzer is happy. To make this work the
surrounding inner-error must not be used or changed here.

Fixes https://gitlab.gnome.org/GNOME/vala/issues/742

1 files changed, 72 insertions, 0 deletions

diff --git a/tests/asynchronous/catch-in-finally.vala b/tests/asynchronous/catch-in-finally.vala
new file mode 100644
index 000000000..9f0f95226
--- /dev/null
+++ b/tests/asynchronous/catch-in-finally.vala
@@ -0,0 +1,72 @@
+errordomain FooError {
+	FAIL
+}
+
+async void fail () throws FooError {
+	throw new FooError.FAIL ("fail");
+}
+
+async void may_fail () throws FooError {
+}
+
+async void foo () throws FooError {
+	try {
+		yield fail ();
+	} finally {
+		try {
+			yield may_fail ();
+		} catch (FooError e) {
+			assert_not_reached ();
+		}
+	}
+	assert_not_reached ();
+}
+
+async void bar () throws FooError {
+	try {
+		yield may_fail ();
+	} finally {
+		try {
+			yield fail ();
+		} catch (FooError e) {
+		}
+	}
+
+	try {
+		yield fail ();
+	} finally {
+		try {
+			yield may_fail ();
+		} catch (FooError e) {
+			assert_not_reached ();
+		}
+	}
+	assert_not_reached ();
+}
+
+async void run () {
+	foo.begin ((o,r) => {
+		try {
+			foo.end (r);
+		} catch (FooError e) {
+			assert (e.message == "fail");
+		}
+	});
+
+	bar.begin ((o,r) => {
+		try {
+			bar.end (r);
+		} catch (FooError e) {
+			assert (e.message == "fail");
+			loop.quit ();
+		}
+	});
+}
+
+MainLoop loop;
+
+void main () {
+	loop = new MainLoop ();
+	run.begin ();
+	loop.run ();
+}