build: Add RYGEL_CHECK_VALA macro

This macro deals with all of the additional checks we have

1 files changed, 47 insertions, 1 deletions

diff --git a/m4/rygel.m4 b/m4/rygel.m4
index 6d40c57e..346ff12d 100644
--- a/m4/rygel.m4
+++ b/m4/rygel.m4
@@ -18,7 +18,12 @@ dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  US
 
 AC_DEFUN([RYGEL_ADD_STAMP],
 [
-    rygel_stamp_files="$rygel_stamp_files $1"
+    rygel_stamp_files="$rygel_stamp_files $srcdir/$1"
+])
+
+AC_DEFUN([RYGEL_ADD_VALAFLAGS],
+[
+    VALAFLAGS="${VALAFLAGS:+$VALAFLAGS }$1"
 ])
 
 # _RYGEL_ADD_PLUGIN_INTERNAL(NAME-OF-PLUGIN,
@@ -51,3 +56,44 @@ AC_DEFUN([RYGEL_ADD_PLUGIN],
         [$2],
         [$3])
 ])
+
+AC_DEFUN([RYGEL_CHECK_VALA],
+[AC_REQUIRE([AM_PROG_VALAC])[]dnl
+    AC_ARG_ENABLE([vala],
+        [AS_HELP_STRING([--enable-vala],[enable checks for vala])],,
+            [enable_vala=no])
+    AC_ARG_ENABLE([strict-valac],
+        [AS_HELP_STRING([--enable-strict-valac],[enable strict Vala compiler])],,
+              [enable_strict_valac=no])
+    AS_IF([test "x$enable_strict_valac" = "xyes"],
+          [RYGEL_ADD_VALAFLAGS([--fatal-warnings])])
+    AC_SUBST([VALAFLAGS])
+
+    dnl Enable check for Vala even if not asked to do so if stamp files are absent.
+    for stamp in $rygel_stamp_files
+    do
+        AS_IF([test ! -e "$stamp"],
+              [AC_MSG_WARN([Missing stamp file $[]stamp. Forcing vala mode])
+               enable_vala=yes
+              ])
+    done
+
+    dnl Vala
+    AS_IF([test x$enable_vala = xyes],
+          [dnl check for vala
+           AM_PROG_VALAC([$1])
+
+            AS_IF([test x$VALAC = "x"],
+                [AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])],
+                [
+                    PKG_CHECK_MODULES(GUPNP_VALA, gupnp-vala-1.0 >= $GUPNP_VALA_REQUIRED)
+
+                    VALA_CHECK_PACKAGES([$2])
+                ])
+           ],
+           []
+    )
+
+    VAPIDIR="${datadir}/vala/vapi"
+    AC_SUBST(VAPIDIR)
+])