Imported WebKit commit 2ea9d364d0f6efa8fa64acf19f451504c59be0e4 (http://svn.webkit.org/repository/webkit/trunk@104285)

1 files changed, 47 insertions, 0 deletions

diff --git a/WebKit.pro b/WebKit.pro
new file mode 100644
index 000000000..2df08f5eb
--- /dev/null
+++ b/WebKit.pro
@@ -0,0 +1,47 @@
+# -------------------------------------------------------------------
+# Root project file, used to load WebKit in Qt Creator and for
+# building QtWebKit.
+#
+# See 'Tools/qmake/README' for an overview of the build system
+# -------------------------------------------------------------------
+
+TEMPLATE = subdirs
+CONFIG += ordered
+
+QMAKEPATH = $$(QMAKEPATH)
+isEmpty(QMAKEPATH)|!exists($${QMAKEPATH}/mkspecs) {
+    error("The environment variable QMAKEPATH needs to point to $WEBKITSRC/Tools/qmake")
+    # Otherwise we won't pick up the feature prf files needed for the build
+}
+
+# Always go into JavaScriptCore to at least build WTF.
+JavaScriptCore.file = Source/JavaScriptCore/JavaScriptCore.pro
+JavaScriptCore.makefile = Makefile.JavaScriptCore
+SUBDIRS += JavaScriptCore
+
+WebCore.file = Source/WebCore/WebCore.pro
+WebCore.makefile = Makefile.WebCore
+SUBDIRS += WebCore
+
+!CONFIG(no_webkit2) {
+    webkit2.file = Source/WebKit2/WebKit2.pro
+    webkit2.makefile = Makefile.WebKit2
+    SUBDIRS += webkit2
+}
+
+QtWebKit.file = Source/QtWebKit.pro
+QtWebKit.makefile = Makefile.QtWebKit
+SUBDIRS += QtWebKit
+
+SUBDIRS += Tools
+
+OTHER_FILES = \
+    Tools/qmake/README \
+    Tools/qmake/configure.pro \
+    Tools/qmake/sync.profile \
+    Tools/qmake/config.tests/fontconfig/* \
+    Tools/qmake/mkspecs/modules/* \
+    Tools/qmake/mkspecs/features/*.prf \
+    Tools/qmake/mkspecs/features/mac/*.prf \
+    Tools/qmake/mkspecs/features/unix/*.prf \
+    Tools/qmake/mkspecs/features/win32/*.prf