blob: 29e231066a9da40289b429e6b34e947be94f712c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
TARGET = qavfmediaplayer
#DEFINES += QT_DEBUG_AVF
# Avoid clash with a variable named `slots' in a Quartz header
CONFIG += no_keywords
QT += multimedia-private network
LIBS += -framework AVFoundation -framework CoreMedia -framework CoreVideo -framework QuartzCore
DEFINES += QMEDIA_AVF_MEDIAPLAYER
HEADERS += \
avfmediaplayercontrol.h \
avfmediaplayermetadatacontrol.h \
avfmediaplayerservice.h \
avfmediaplayersession.h \
avfmediaplayerserviceplugin.h \
avfvideooutput.h \
avfvideowindowcontrol.h
OBJECTIVE_SOURCES += \
avfmediaplayercontrol.mm \
avfmediaplayermetadatacontrol.mm \
avfmediaplayerservice.mm \
avfmediaplayerserviceplugin.mm \
avfmediaplayersession.mm \
avfvideooutput.mm \
avfvideowindowcontrol.mm
qtHaveModule(widgets) {
QT += multimediawidgets-private
HEADERS += \
avfvideowidgetcontrol.h \
avfvideowidget.h
OBJECTIVE_SOURCES += \
avfvideowidgetcontrol.mm \
avfvideowidget.mm
}
ios|tvos {
qtConfig(opengl) {
HEADERS += \
avfvideoframerenderer_ios.h \
avfvideorenderercontrol.h \
avfdisplaylink.h
OBJECTIVE_SOURCES += \
avfvideoframerenderer_ios.mm \
avfvideorenderercontrol.mm \
avfdisplaylink.mm
}
LIBS += -framework Foundation
} else {
LIBS += -framework AppKit
qtConfig(opengl) {
HEADERS += \
avfvideoframerenderer.h \
avfvideorenderercontrol.h \
avfdisplaylink.h
OBJECTIVE_SOURCES += \
avfvideoframerenderer.mm \
avfvideorenderercontrol.mm \
avfdisplaylink.mm
}
}
OTHER_FILES += \
avfmediaplayer.json
PLUGIN_TYPE = mediaservice
PLUGIN_CLASS_NAME = AVFMediaPlayerServicePlugin
load(qt_plugin)
|
