1 files changed, 77 insertions, 0 deletions
diff --git a/platform/darwin/src/MGLRasterTileSource.mm b/platform/darwin/src/MGLRasterTileSource.mm
new file mode 100644
index 0000000000..02cfef4ae8
--- /dev/null
+++ b/platform/darwin/src/MGLRasterTileSource.mm
@@ -0,0 +1,77 @@
+#import "MGLRasterTileSource_Private.h"
+
+#import "MGLMapView_Private.h"
+#import "MGLSource_Private.h"
+#import "MGLTileSource_Private.h"
+#import "NSURL+MGLAdditions.h"
+
+#include <mbgl/map/map.hpp>
+#include <mbgl/style/sources/raster_source.hpp>
+
+const MGLTileSourceOption MGLTileSourceOptionTileSize = @"MGLTileSourceOptionTileSize";
+
+static const CGFloat MGLRasterTileSourceClassicTileSize = 256;
+static const CGFloat MGLRasterTileSourceRetinaTileSize = 512;
+
+@interface MGLRasterTileSource ()
+
+@property (nonatomic, readonly) mbgl::style::RasterSource *rawSource;
+
+@end
+
+@implementation MGLRasterTileSource
+
+- (instancetype)initWithIdentifier:(NSString *)identifier configurationURL:(NSURL *)configurationURL {
+    // The style specification default is 512, but 256 is the expected value for
+    // any tile set that would be accessed through a mapbox: URL and therefore
+    // any tile URL that this option currently affects.
+    BOOL isMapboxURL = ([configurationURL.scheme isEqualToString:@"mapbox"]
+                        && [configurationURL.host containsString:@"."]
+                        && (!configurationURL.path.length || [configurationURL.path isEqualToString:@"/"]));
+    CGFloat tileSize = isMapboxURL ? MGLRasterTileSourceClassicTileSize : MGLRasterTileSourceRetinaTileSize;
+    return [self initWithIdentifier:identifier configurationURL:configurationURL tileSize:tileSize];
+}
+
+- (instancetype)initWithIdentifier:(NSString *)identifier configurationURL:(NSURL *)configurationURL tileSize:(CGFloat)tileSize {
+    auto source = [self pendingSourceWithIdentifier:identifier configurationURL:configurationURL tileSize:tileSize];
+    return self = [super initWithPendingSource:std::move(source)];
+}
+
+- (std::unique_ptr<mbgl::style::RasterSource>)pendingSourceWithIdentifier:(NSString *)identifier configurationURL:(NSURL *)configurationURL tileSize:(CGFloat)tileSize {
+    NSString *configurationURLString = configurationURL.mgl_URLByStandardizingScheme.absoluteString;
+    return std::make_unique<mbgl::style::RasterSource>(identifier.UTF8String,
+                                                       configurationURLString.UTF8String,
+                                                       uint16_t(round(tileSize)));
+}
+
+- (instancetype)initWithIdentifier:(NSString *)identifier tileURLTemplates:(NS_ARRAY_OF(NSString *) *)tileURLTemplates options:(nullable NS_DICTIONARY_OF(MGLTileSourceOption, id) *)options {
+    mbgl::Tileset tileSet = MGLTileSetFromTileURLTemplates(tileURLTemplates, options);
+
+    uint16_t tileSize = MGLRasterTileSourceRetinaTileSize;
+    if (NSNumber *tileSizeNumber = options[MGLTileSourceOptionTileSize]) {
+        if (![tileSizeNumber isKindOfClass:[NSNumber class]]) {
+            [NSException raise:NSInvalidArgumentException
+                        format:@"MGLTileSourceOptionTileSize must be set to an NSNumber."];
+        }
+        tileSize = static_cast<uint16_t>(round(tileSizeNumber.doubleValue));
+    }
+
+    auto source = std::make_unique<mbgl::style::RasterSource>(identifier.UTF8String, tileSet, tileSize);
+    return self = [super initWithPendingSource:std::move(source)];
+}
+
+- (mbgl::style::RasterSource *)rawSource {
+    return (mbgl::style::RasterSource *)super.rawSource;
+}
+
+- (NSURL *)configurationURL {
+    auto url = self.rawSource->getURL();
+    return url ? [NSURL URLWithString:@(url->c_str())] : nil;
+}
+
+- (NSString *)attributionHTMLString {
+    auto attribution = self.rawSource->getAttribution();
+    return attribution ? @(attribution->c_str()) : nil;
+}
+
+@end