blob: 1ad02517c2bfaa609afc7a1f51447e3d2d17699d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# JavaScriptCore - Qt4 build info
VPATH += $$PWD
JAVASCRIPTCORE_TARGET = jscore
CONFIG(standalone_package) {
isEmpty(JSC_GENERATED_SOURCES_DIR):JSC_GENERATED_SOURCES_DIR = $$PWD/generated
} else {
isEmpty(JSC_GENERATED_SOURCES_DIR):JSC_GENERATED_SOURCES_DIR = generated
}
symbian: {
# Need to guarantee this comes before system includes of /epoc32/include
MMP_RULES += "USERINCLUDE ../JavaScriptCore/profiler"
LIBS += -lhal
}
INCLUDEPATH = \
$$PWD \
$$PWD/.. \
$$PWD/assembler \
$$PWD/bytecode \
$$PWD/bytecompiler \
$$PWD/debugger \
$$PWD/interpreter \
$$PWD/jit \
$$PWD/parser \
$$PWD/pcre \
$$PWD/profiler \
$$PWD/runtime \
$$PWD/wtf \
$$PWD/wtf/symbian \
$$PWD/wtf/unicode \
$$PWD/yarr \
$$PWD/API \
$$PWD/ForwardingHeaders \
$$JSC_GENERATED_SOURCES_DIR \
$$INCLUDEPATH
win32-*: DEFINES += _HAS_TR1=0
DEFINES += BUILDING_QT__ BUILDING_JavaScriptCore BUILDING_WTF
contains(JAVASCRIPTCORE_JIT,yes) {
DEFINES+=ENABLE_JIT=1
DEFINES+=ENABLE_YARR_JIT=1
DEFINES+=ENABLE_YARR=1
}
contains(JAVASCRIPTCORE_JIT,no) {
DEFINES+=ENABLE_JIT=0
DEFINES+=ENABLE_YARR_JIT=0
DEFINES+=ENABLE_YARR=0
}
wince* {
INCLUDEPATH += $$QT_SOURCE_TREE/src/3rdparty/ce-compat
DEFINES += WINCEBASIC
}
defineTest(addJavaScriptCoreLib) {
pathToJavaScriptCoreOutput = $$ARGS
CONFIG(debug_and_release):CONFIG(debug, debug|release): pathToJavaScriptCoreOutput = $$pathToJavaScriptCoreOutput/debug
CONFIG(debug_and_release):CONFIG(release, debug|release): pathToJavaScriptCoreOutput = $$pathToJavaScriptCoreOutput/release
win32-msvc* {
LIBS += -L$$pathToJavaScriptCoreOutput
LIBS += -l$$JAVASCRIPTCORE_TARGET
} else:symbian {
LIBS += -l$${JAVASCRIPTCORE_TARGET}.lib
} else {
# Make sure jscore will be early in the list of libraries to workaround a bug in MinGW
# that can't resolve symbols from QtCore if libjscore comes after.
QMAKE_LIBDIR = $$pathToJavaScriptCoreOutput $$QMAKE_LIBDIR
LIBS += -l$$JAVASCRIPTCORE_TARGET
}
win32-* {
LIBS += -lwinmm
}
# The following line is to prevent qmake from adding jscore to libQtWebKit's prl dependencies.
# The compromise we have to accept by disabling explicitlib is to drop support to link QtWebKit and QtScript
# statically in applications (which isn't used often because, among other things, of licensing obstacles).
CONFIG -= explicitlib
export(QMAKE_LIBDIR)
export(LIBS)
export(CONFIG)
return(true)
}
|
