blob: ba7950781c49af8d0bcec7f1630a09c335161c7a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
|
/****************************************************************************
**
** Copyright (C) 2022 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of Qt Creator.
**
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 as published by the Free Software
** Foundation with exceptions as appearing in the file LICENSE.GPL3-EXCEPT
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
****************************************************************************/
import QtQuick
import QtQuick.Controls
import StudioTheme 1.0 as StudioTheme
import StudioControls 1.0 as StudioControls
import QtQuick.Layouts 6.0
Item {
id: root
clip: true
anchors {
horizontalCenter: parent.horizontalCenter
verticalCenter: parent.verticalCenter
}
property alias thumbnailImageSource: thumbnailImage.source
property alias stateName: stateNameField.text
property alias whenCondition: whenCondition.text
property alias defaultChecked: defaultButton.checked
property alias menuChecked: menuButton.checked
property bool baseState: false
property bool isTiny: false
property bool propertyChangesVisible: false
property bool isChecked: false
property bool hasExtend: false
property string extendString: ""
property bool extendedState: false
property bool hasWhenCondition: false
property int visualIndex: 0
property int internalNodeId
signal focusSignal
signal defaultClicked
signal clone
signal extend
signal remove
signal stateNameFinished
signal whenConditionFinished
signal grabbing
signal letGo
property alias dragActive: dragHandler.active
function checkAnnotation() {
return statesEditorModel.hasAnnotation(root.internalNodeId)
}
onIsTinyChanged: {
if (root.isTiny) {
buttonGrid.rows = 2
buttonGrid.columns = 1
} else {
buttonGrid.columns = 2
buttonGrid.rows = 1
}
}
DragHandler {
id: dragHandler
enabled: !root.baseState && !root.extendedState
onGrabChanged: function (transition, point) {
if (transition === PointerDevice.GrabPassive
|| transition === PointerDevice.GrabExclusive)
root.grabbing()
if (transition === PointerDevice.UngrabPassive
|| transition === PointerDevice.CancelGrabPassive
|| transition === PointerDevice.UngrabExclusive
|| transition === PointerDevice.CancelGrabExclusive)
root.letGo()
}
}
onDragActiveChanged: {
if (root.dragActive)
Drag.start()
else
Drag.drop()
}
Drag.active: dragHandler.active
Drag.source: root
Drag.hotSpot.x: root.width * 0.5
Drag.hotSpot.y: root.height * 0.5
Rectangle {
id: stateBackground
color: StudioTheme.Values.themeControlBackground
border.color: StudioTheme.Values.themeInteraction
border.width: root.isChecked ? 4 : 0
anchors.fill: parent
readonly property int controlHeight: 25
readonly property int thumbPadding: 10
readonly property int thumbSpacing: 7
property int innerWidth: root.width - 2 * stateBackground.thumbPadding
property int innerHeight: root.height - 2 * stateBackground.thumbPadding - 2
* stateBackground.thumbSpacing - 2 * stateBackground.controlHeight
MouseArea {
id: mouseArea
anchors.fill: parent
enabled: true
hoverEnabled: true
propagateComposedEvents: true
onClicked: root.focusSignal()
}
Column {
padding: stateBackground.thumbPadding
spacing: stateBackground.thumbSpacing
Grid {
id: buttonGrid
columns: 2
rows: 1
spacing: stateBackground.thumbSpacing
StudioControls.AbstractButton {
id: defaultButton
width: 50
height: stateBackground.controlHeight
checkedInverted: true
buttonIcon: qsTr("Default")
iconFont: StudioTheme.Constants.font
onClicked: {
root.defaultClicked()
root.focusSignal()
}
}
StudioControls.TextField {
id: stateNameField
property string previousText
// This is the width for the "big" state
property int bigWidth: stateBackground.innerWidth - 2 * stateBackground.thumbSpacing
- defaultButton.width - menuButton.width
width: root.isTiny ? stateBackground.innerWidth : stateNameField.bigWidth
height: stateBackground.controlHeight
actionIndicatorVisible: false
translationIndicatorVisible: false
placeholderText: qsTr("State Name")
visible: !root.baseState
onActiveFocusChanged: {
if (stateNameField.activeFocus)
root.focusSignal()
}
onEditingFinished: {
if (stateNameField.previousText === stateNameField.text)
return
stateNameField.previousText = stateNameField.text
root.stateNameFinished()
}
Component.onCompleted: stateNameField.previousText = stateNameField.text
}
Text {
id: baseStateLabel
width: root.isTiny ? stateBackground.innerWidth : stateNameField.bigWidth
height: stateBackground.controlHeight
visible: root.baseState
color: StudioTheme.Values.themeTextColor
text: qsTr("Base State")
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignLeft
verticalAlignment: Text.AlignVCenter
leftPadding: 5
elide: Text.ElideRight
}
}
Item {
visible: !root.isTiny && !root.propertyChangesVisible
width: stateBackground.innerWidth
height: stateBackground.innerHeight
Image {
anchors.fill: stateImageBackground
source: "images/checkers.png"
fillMode: Image.Tile
}
Rectangle {
id: stateImageBackground
x: Math.floor(
(stateBackground.innerWidth - thumbnailImage.paintedWidth) / 2) - StudioTheme.Values.border
y: Math.floor(
(stateBackground.innerHeight - thumbnailImage.paintedHeight) / 2) - StudioTheme.Values.border
width: Math.round(thumbnailImage.paintedWidth) + 2 * StudioTheme.Values.border
height: Math.round(thumbnailImage.paintedHeight) + 2 * StudioTheme.Values.border
color: "transparent"
border.width: StudioTheme.Values.border
border.color: StudioTheme.Values.themeStatePreviewOutline
}
Image {
id: thumbnailImage
anchors.centerIn: parent
anchors.fill: parent
fillMode: Image.PreserveAspectFit
mipmap: true
}
}
PropertyChangesModel {
id: propertyChangesModel
modelNodeBackendProperty: statesEditorModel.stateModelNode(root.internalNodeId)
}
Text {
visible: !root.isTiny && root.propertyChangesVisible && !propertyChangesModel.count
width: stateBackground.innerWidth
height: stateBackground.innerHeight
text: qsTr("No Property Changes Available")
color: StudioTheme.Values.themeTextColor
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignHCenter
verticalAlignment: Text.AlignVCenter
elide: Text.ElideRight
}
ScrollView {
id: scrollView
visible: !root.isTiny && root.propertyChangesVisible && propertyChangesModel.count
width: stateBackground.innerWidth
height: stateBackground.innerHeight
clip: true
ScrollBar.horizontal: StateScrollBar {
parent: scrollView
x: scrollView.leftPadding
y: scrollView.height - height
width: scrollView.availableWidth
orientation: Qt.Horizontal
onPressedChanged: root.focusSignal()
}
ScrollBar.vertical: StateScrollBar {
parent: scrollView
x: scrollView.mirrored ? 0 : scrollView.width - width
y: scrollView.topPadding
height: scrollView.availableHeight
orientation: Qt.Vertical
onPressedChanged: root.focusSignal()
}
Flickable {
id: frame
boundsMovement: Flickable.StopAtBounds
boundsBehavior: Flickable.StopAtBounds
interactive: true
contentWidth: column.width
contentHeight: column.height
flickableDirection: {
if (frame.contentHeight <= scrollView.height)
return Flickable.HorizontalFlick
if (frame.contentWidth <= scrollView.width)
return Flickable.VerticalFlick
return Flickable.HorizontalAndVerticalFlick
}
// ScrollView needs an extra TapHandler on top in order to receive click
// events. MouseAreas below ScrollView do not let clicks through.
TapHandler {
id: tapHandler
onTapped: root.focusSignal()
}
Column {
id: column
// Grid sizes
property int gridSpacing: 20
property int gridRowSpacing: 5
property int gridPadding: 5
property int col1Width: 100 // labels
property int col2Width: stateBackground.innerWidth - column.gridSpacing - 2
* column.gridPadding - column.col1Width // controls
width: stateBackground.innerWidth
spacing: stateBackground.thumbSpacing
Repeater {
model: propertyChangesModel
delegate: Rectangle {
id: propertyChanges
required property int index
required property string target
required property bool explicit
required property bool restoreEntryValues
required property var propertyModelNode
width: column.width
height: propertyChangesColumn.height
color: StudioTheme.Values.themeBackgroundColorAlternate
PropertyModel {
id: propertyModel
modelNodeBackendProperty: propertyChanges.propertyModelNode
}
Column {
id: propertyChangesColumn
Item {
id: section
property int animationDuration: 120
property bool expanded: false
clip: true
width: stateBackground.innerWidth
height: Math.round(sectionColumn.height + header.height)
Rectangle {
id: header
anchors.left: parent.left
anchors.right: parent.right
width: stateBackground.innerWidth
height: StudioTheme.Values.sectionHeadHeight
color: StudioTheme.Values.themeSectionHeadBackground
Row {
x: column.gridPadding
anchors.verticalCenter: parent.verticalCenter
spacing: column.gridSpacing
Text {
color: StudioTheme.Values.themeTextColor
text: qsTr("Target")
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignRight
width: column.col1Width
}
Text {
color: StudioTheme.Values.themeTextColor
text: propertyChanges.target
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignLeft
elide: Text.ElideRight
width: column.col2Width
}
}
Text {
id: arrow
width: StudioTheme.Values.spinControlIconSizeMulti
height: StudioTheme.Values.spinControlIconSizeMulti
text: StudioTheme.Constants.sectionToggle
color: StudioTheme.Values.themeTextColor
renderType: Text.NativeRendering
anchors.left: parent.left
anchors.leftMargin: 4
anchors.verticalCenter: parent.verticalCenter
font.pixelSize: StudioTheme.Values.spinControlIconSizeMulti
font.family: StudioTheme.Constants.iconFont.family
Behavior on rotation {
NumberAnimation {
easing.type: Easing.OutCubic
duration: section.animationDuration
}
}
}
MouseArea {
anchors.fill: parent
onClicked: {
section.expanded = !section.expanded
if (!section.expanded)
section.forceActiveFocus()
root.focusSignal()
}
}
}
Column {
id: sectionColumn
y: header.height
padding: column.gridPadding
spacing: column.gridRowSpacing
Row {
spacing: column.gridSpacing
Text {
color: StudioTheme.Values.themeTextColor
text: qsTr("Explicit")
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignRight
verticalAlignment: Text.AlignVCenter
width: column.col1Width
height: explicitSwitch.height
}
StudioControls.Switch {
id: explicitSwitch
actionIndicatorVisible: false
checked: propertyChanges.explicit
onToggled: {
root.focusSignal()
propertyModel.setExplicit(
explicitSwitch.checked)
}
}
}
Row {
spacing: column.gridSpacing
Text {
color: StudioTheme.Values.themeTextColor
text: qsTr("Restore values")
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignRight
verticalAlignment: Text.AlignVCenter
width: column.col1Width
height: restoreSwitch.height
}
StudioControls.Switch {
id: restoreSwitch
actionIndicatorVisible: false
checked: propertyChanges.restoreEntryValues
onToggled: {
root.focusSignal()
propertyModel.setRestoreEntryValues(
restoreSwitch.checked)
}
}
}
}
Behavior on height {
NumberAnimation {
easing.type: Easing.OutCubic
duration: section.animationDuration
}
}
states: [
State {
name: "Expanded"
when: section.expanded
PropertyChanges {
target: arrow
rotation: 0
}
},
State {
name: "Collapsed"
when: !section.expanded
PropertyChanges {
target: section
height: header.height
}
PropertyChanges {
target: arrow
rotation: -90
}
}
]
}
Column {
id: propertyColumn
padding: column.gridPadding
spacing: column.gridRowSpacing
Repeater {
model: propertyModel
delegate: ItemDelegate {
id: propertyDelegate
required property string name
required property var value
required property string type
width: stateBackground.innerWidth - 2 * column.gridPadding
height: 26
hoverEnabled: true
onClicked: root.focusSignal()
background: Rectangle {
color: "transparent"
border.color: StudioTheme.Values.themeInteraction
border.width: propertyDelegate.hovered ? StudioTheme.Values.border : 0
}
Item {
id: removeItem
visible: propertyDelegate.hovered
x: propertyDelegate.width - removeItem.width
z: 10
width: removeItem.visible ? propertyDelegate.height : 0
height: removeItem.visible ? propertyDelegate.height : 0
Label {
id: removeIcon
anchors.fill: parent
text: StudioTheme.Constants.closeCross
color: StudioTheme.Values.themeTextColor
font.family: StudioTheme.Constants.iconFont.family
font.pixelSize: StudioTheme.Values.myIconFontSize
verticalAlignment: Text.AlignVCenter
horizontalAlignment: Text.AlignHCenter
scale: propertyDelegateMouseArea.containsMouse ? 1.2 : 1.0
}
MouseArea {
id: propertyDelegateMouseArea
anchors.fill: parent
hoverEnabled: true
onClicked: {
root.focusSignal()
propertyModel.removeProperty(
propertyDelegate.name)
}
}
}
Row {
anchors.verticalCenter: parent.verticalCenter
spacing: column.gridSpacing
Text {
color: StudioTheme.Values.themeTextColor
text: propertyDelegate.name
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignRight
elide: Text.ElideRight
width: column.col1Width
}
Text {
color: StudioTheme.Values.themeTextColor
text: propertyDelegate.value
font.pixelSize: StudioTheme.Values.baseFontSize
horizontalAlignment: Text.AlignLeft
elide: Text.ElideRight
width: column.col2Width - removeItem.width
}
}
}
}
}
}
}
}
}
}
}
BindingEditor {
id: bindingEditor
property string newWhenCondition
property Timer timer: Timer {
id: timer
running: false
interval: 50
repeat: false
onTriggered: statesEditorModel.setWhenCondition(root.internalNodeId,
bindingEditor.newWhenCondition)
}
stateModelNodeProperty: statesEditorModel.stateModelNode(root.internalNodeId)
stateNameProperty: root.stateName
onRejected: bindingEditor.hideWidget()
onAccepted: {
bindingEditor.newWhenCondition = bindingEditor.text.trim()
timer.start()
bindingEditor.hideWidget()
}
}
StudioControls.TextField {
id: whenCondition
property string previousCondition
width: stateBackground.innerWidth
height: stateBackground.controlHeight
visible: !root.baseState
indicatorVisible: true
indicator.icon.text: StudioTheme.Constants.edit
indicator.onClicked: {
bindingEditor.showWidget()
bindingEditor.text = whenCondition.text
bindingEditor.prepareBindings()
bindingEditor.updateWindowName()
}
actionIndicatorVisible: false
translationIndicatorVisible: false
placeholderText: qsTr("When Condition")
onActiveFocusChanged: {
if (whenCondition.activeFocus)
root.focusSignal()
}
onEditingFinished: {
if (whenCondition.previousCondition === whenCondition.text)
return
whenCondition.previousCondition = whenCondition.text
root.whenConditionFinished()
}
Component.onCompleted: whenCondition.previousCondition = whenCondition.text
}
}
MenuButton {
id: menuButton
anchors.top: parent.top
anchors.topMargin: 10
anchors.right: parent.right
anchors.rightMargin: 10
visible: !root.baseState
checked: stateMenu.opened
onPressed: {
if (!stateMenu.opened)
stateMenu.popup()
root.focusSignal()
}
}
}
StateMenu {
id: stateMenu
x: 56
isBaseState: root.baseState
isTiny: root.isTiny
hasExtend: root.hasExtend
propertyChangesVisible: root.propertyChangesVisible
hasAnnotation: root.checkAnnotation()
hasWhenCondition: root.hasWhenCondition
onClone: root.clone()
onExtend: root.extend()
onRemove: root.remove()
onToggle: root.propertyChangesVisible = !root.propertyChangesVisible
onEditAnnotation: {
statesEditorModel.setAnnotation(root.internalNodeId)
stateMenu.hasAnnotation = root.checkAnnotation()
}
onRemoveAnnotation: {
statesEditorModel.removeAnnotation(root.internalNodeId)
stateMenu.hasAnnotation = root.checkAnnotation()
}
onOpened: stateMenu.hasAnnotation = root.checkAnnotation()
}
property bool anyControlHovered: defaultButton.hovered || menuButton.hovered
|| scrollView.hovered || stateNameField.hover
|| whenCondition.hover
states: [
State {
name: "default"
when: !mouseArea.containsMouse && !root.anyControlHovered && !dragHandler.active
&& !root.baseState
PropertyChanges {
target: stateBackground
color: StudioTheme.Values.themeControlBackground
}
},
State {
name: "hover"
when: (mouseArea.containsMouse || root.anyControlHovered) && !dragHandler.active
PropertyChanges {
target: stateBackground
color: StudioTheme.Values.themeControlBackgroundHover
}
},
State {
name: "baseState"
when: root.baseState && !mouseArea.containsMouse && !root.anyControlHovered
&& !dragHandler.active
PropertyChanges {
target: stateBackground
color: StudioTheme.Values.themeStateHighlight
}
},
State {
name: "drag"
when: dragHandler.active
AnchorChanges {
target: root
anchors.horizontalCenter: undefined
anchors.verticalCenter: undefined
}
}
]
}
|