Remove pre-Qt 5.3.1 code paths from main Qt Creator pro and pri files

Change-Id: I71bee691a2b9bad7dbdb4ca9c0a938d4313305f7
Reviewed-by: hjk <hjk121@nokiamail.com>

1 files changed, 2 insertions, 64 deletions

diff --git a/qtcreator.pri b/qtcreator.pri
index 249f5cf80b..2bf06ec613 100644
--- a/qtcreator.pri
+++ b/qtcreator.pri
@@ -6,29 +6,7 @@ QTCREATOR_COMPAT_VERSION = 3.2.81
 BINARY_ARTIFACTS_BRANCH = master
 
 # enable c++11
-isEqual(QT_MAJOR_VERSION, 5) {
-    CONFIG += c++11
-} else {
-    macx {
-        !macx-clang*: error("You need to use the macx-clang or macx-clang-libc++ mkspec to compile Qt Creator (call qmake with '-spec unsupported/macx-clang')")
-        QMAKE_CFLAGS += -mmacosx-version-min=10.7
-        QMAKE_CXXFLAGS += -std=c++11 -stdlib=libc++ -mmacosx-version-min=10.7
-        QMAKE_OBJECTIVE_CXXFLAGS += -std=c++11 -stdlib=libc++ -mmacosx-version-min=10.7
-        QMAKE_LFLAGS += -stdlib=libc++ -mmacosx-version-min=10.7
-    } else:linux-g++* {
-        QMAKE_CXXFLAGS += -std=c++0x
-    } else:linux-icc* {
-        QMAKE_CXXFLAGS += -std=c++11
-    } else:linux-clang* {
-        QMAKE_CXXFLAGS += -std=c++11
-        QMAKE_LFLAGS += -stdlib=libc++ -lc++abi
-    } else:win32-g++* {
-        QMAKE_CXXFLAGS += -std=c++0x
-    }
-    # nothing to do for MSVC10+
-}
-
-isEqual(QT_MAJOR_VERSION, 5) {
+CONFIG += c++11
 
 defineReplace(cleanPath) {
     return($$clean_path($$1))
@@ -38,27 +16,6 @@ defineReplace(targetPath) {
     return($$shell_path($$1))
 }
 
-} else { # qt5
-
-defineReplace(cleanPath) {
-    win32:1 ~= s|\\\\|/|g
-    contains(1, ^/.*):pfx = /
-    else:pfx =
-    segs = $$split(1, /)
-    out =
-    for(seg, segs) {
-        equals(seg, ..):out = $$member(out, 0, -2)
-        else:!equals(seg, .):out += $$seg
-    }
-    return($$join(out, /, $$pfx))
-}
-
-defineReplace(targetPath) {
-    return($$replace(1, /, $$QMAKE_DIR_SEP))
-}
-
-} # qt5
-
 defineReplace(qtLibraryName) {
    unset(LIBRARY_NAME)
    LIBRARY_NAME = $$1
@@ -95,30 +52,11 @@ defineTest(minQtVersion) {
     return(false)
 }
 
-isEqual(QT_MAJOR_VERSION, 5) {
-
 # For use in custom compilers which just copy files
 defineReplace(stripSrcDir) {
     return($$relative_path($$absolute_path($$1, $$OUT_PWD), $$_PRO_FILE_PWD_))
 }
 
-} else { # qt5
-
-# For use in custom compilers which just copy files
-win32:i_flag = i
-defineReplace(stripSrcDir) {
-    win32 {
-        !contains(1, ^.:.*):1 = $$OUT_PWD/$$1
-    } else {
-        !contains(1, ^/.*):1 = $$OUT_PWD/$$1
-    }
-    out = $$cleanPath($$1)
-    out ~= s|^$$re_escape($$_PRO_FILE_PWD_/)||$$i_flag
-    return($$out)
-}
-
-} # qt5
-
 !isEmpty(BUILD_TESTS):TEST = 1
 
 isEmpty(TEST):CONFIG(debug, debug|release) {
@@ -208,7 +146,7 @@ win32-msvc* {
     QMAKE_LFLAGS_DEBUG += /INCREMENTAL:NO
 }
 
-qt:greaterThan(QT_MAJOR_VERSION, 4) {
+qt {
     contains(QT, core): QT += concurrent
     contains(QT, gui): QT += widgets
     DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x040900