add ts and qm build targets

this is based on patches from axasia, which are in turn an almost
literal copy from qt.

3 files changed, 42 insertions, 0 deletions

diff --git a/.gitignore b/.gitignore
index 3ced6e0c35..9487adc140 100644
--- a/.gitignore
+++ b/.gitignore
@@ -12,6 +12,7 @@
 *.so
 *_pch.h.cpp
 *_resource.rc
+*.qm
 .#*
 *.*#
 core
diff --git a/qtcreator.pro b/qtcreator.pro
index 7eadc16290..d9d0eb46c0 100644
--- a/qtcreator.pro
+++ b/qtcreator.pro
@@ -11,3 +11,11 @@ TEMPLATE  = subdirs
 CONFIG   += ordered
 
 SUBDIRS = src
+
+# for Qt Creator translations
+QTC_BUILD_ROOT = $$PWD
+QTC_INSTALL_TRANSLATIONS = $$PWD/translations
+
+include(translations/translations.pri)
+translations.path = $$QTC_INSTALL_TRANSLATIONS
+translations.files = $$QTC_INSTALL_TRANSLATIONS/*.qm
diff --git a/translations/translations.pri b/translations/translations.pri
new file mode 100644
index 0000000000..0bcd58dcc2
--- /dev/null
+++ b/translations/translations.pri
@@ -0,0 +1,33 @@
+defineReplace(prependAll) {
+    prepend = $$1
+    arglist = $$2
+    append  = $$3
+    for(a,arglist) {
+      result += $${prepend}$${a}$${append}
+    }
+    return ($$result)
+}
+
+defineReplace(fixPath) {
+WIN {
+    return ($$replace($$1, /, \))
+} ELSE {
+    return ($$1)
+}
+}
+
+LUPDATE = $$fixPath($$[QT_INSTALL_PREFIX]/bin/lupdate) -locations relative -no-ui-lines
+LRELEASE = $$fixPath($$[QT_INSTALL_PREFIX]/bin/lrelease)
+
+
+###### Qt Creator
+
+QTC_TS = de fr zh_CN untranslated ar es iw ja_JP pl pt ru sk sv uk zh_TW
+
+ts.commands = (cd $$QTC_BUILD_ROOT && \
+               $$LUPDATE share src \
+                         -ts $$prependAll($$QTC_INSTALL_TRANSLATIONS/qtcreator_,$$QTC_TS,.ts))
+
+qm.commands = $$LRELEASE $$prependAll($$QTC_INSTALL_TRANSLATIONS/qtcreator_,$$QTC_TS,.ts)
+
+QMAKE_EXTRA_TARGETS += ts qm