Modernize to current gettext, gnulib

* .gitignore, po/.gitignore: Revamp to match current source.
* README: Fix typo in file name.
* am/rmt.m4 (PU_RMT):
Modernize to use AC_PREPROC_IFELSE instead of AC_TRY_CPP.
* am/rmt.m4 (PU_RMT):
* configure.ac:
Modernize to use AS_HELP_STRING instead of AC_HELP_STRING.
* am/system.m4 (PU_SYSTEM):
* configure.ac:
Remove obsolescent AC_HEADER_STDC.  Use AC_CHECK_MEMBERS([struct
stat.st_blksize]) instead of AC_STRUCT_ST_BLKSIZE.
* am/system.m4 (PU_SYSTEM):
Use AC_CHECK_HEADERS_ONCE([sys/time.h]) instead of obsolescent
AC_HEADER_TIME.
* bootstrap: Sync from Gnulib.
* build-aux/bootstrap: Remove.
* bootstrap.conf: Simplify.  Don’t make m4, $source_base.
(bootstrap_post_import_hook):
New function, replacing a direct write.
* configure.ac: Remove calls to no-longer-needed macros
AC_ISC_POSIX, AM_STDBOOL_H, AC_HEADER_STDC, AC_TYPE_SIGNAL.
Modernize to use AC_COMPILE_ELSE instead of AC_TRY_COMPILE.
Remove MU_DEBUG_MODE, paxutils_GNULIB (not sure what those were from).
Fix quoting in warning
Remove Iconv code, as the iconv module should do this now.
Update Gettext version from 0.12.1 (2003) to 0.21 (2020).
Use AC_CONFIG_FILES.
All uses of corresponding C macros changed.
* gnulib.modules, paxlib.modules: Switch from gettext to gettext-h.
* paxlib.modules: Add iconv.

2 files changed, 17 insertions, 14 deletions

diff --git a/am/rmt.m4 b/am/rmt.m4
index eaeff95..129eb16 100644
--- a/am/rmt.m4
+++ b/am/rmt.m4
@@ -1,3 +1,8 @@
+# Configure paxutils.
+# Copyright 2009-2022 Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([PU_RMT],[
   # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
@@ -16,11 +21,14 @@ AC_DEFUN([PU_RMT],[
   enable_rmt() {
     if test $ac_cv_header_sys_mtio_h = yes; then
       AC_CACHE_CHECK(for remote tape header files, pu_cv_header_rmt,
-        [AC_TRY_CPP([
-#if HAVE_SGTTY_H
-# include <sgtty.h>
-#endif
-#include <sys/socket.h>],
+        [AC_PREPROC_IFELSE(
+	   [AC_LANG_SOURCE(
+	      [[
+		#if HAVE_SGTTY_H
+		# include <sgtty.h>
+		#endif
+		#include <sys/socket.h>
+	      ]])],
       pu_cv_header_rmt=yes,
       pu_cv_header_rmt=no)])
       test $pu_cv_header_rmt = yes && PU_RMT_PROG='rmt$(EXEEXT)'
@@ -49,7 +57,7 @@ AC_DEFUN([PU_RMT],[
 
   AC_MSG_CHECKING([whether to build rmt])
   AC_ARG_WITH([rmt],
-              AC_HELP_STRING([--with-rmt=FILE],
+              AS_HELP_STRING([--with-rmt=FILE],
                              [Use FILE as the default `rmt' program. Do not build included copy of `rmt'.]),
               [case $withval in
 	       yes|no) AC_MSG_ERROR([Invalid argument to --with-rmt]);;
diff --git a/am/system.m4 b/am/system.m4
index bafedda..2dbac5c 100644
--- a/am/system.m4
+++ b/am/system.m4
@@ -1,14 +1,12 @@
 # Configuration for paxutils/lib/system.h.
 
-# Copyright (C) 2005, 2006, 2007, 2009 Free Software Foundation, Inc.
+# Copyright (C) 2005-2022 Free Software Foundation, Inc.
 # This file is free software; the Free Software Foundation
 # gives unlimited permission to copy and/or distribute it,
 # with or without modifications, as long as this notice is preserved.
 
 AC_DEFUN([PU_SYSTEM],[
-  AC_REQUIRE([AC_HEADER_STDC])
-
-  AC_CHECK_HEADERS_ONCE([string.h memory.h fcntl.h sys/wait.h \
+  AC_CHECK_HEADERS_ONCE([string.h memory.h fcntl.h sys/time.h sys/wait.h \
  sys/gentape.h sys/tape.h sys/device.h sys/param.h sys/tprintf.h sys/mtio.h \
  sgtty.h sys/io/trioctl.h locale.h pwd.h grp.h])
 
@@ -17,11 +15,8 @@ AC_DEFUN([PU_SYSTEM],[
 #include <sys/param.h>
 #endif])
 
-  AC_REQUIRE([AC_HEADER_TIME])
-
-  AC_CHECK_MEMBERS([struct stat.st_blksize]) dnl instead of AC_STRUCT_ST_BLKSIZE
+  AC_CHECK_MEMBERS([struct stat.st_blksize])
   AC_REQUIRE([AC_STRUCT_ST_BLOCKS])
-  AC_REQUIRE([AC_STRUCT_ST_BLKSIZE])
 
   AC_CHECK_FUNCS_ONCE(lstat mkfifo setlocale)
   AC_REQUIRE([gl_INTTOSTR])