blob: 6543db4c0a3097604a76fb44faf6f62673bfc42f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# utime_h.m4 serial 5
dnl Copyright (C) 2017-2021 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
dnl From Bruno Haible.
AC_DEFUN([gl_UTIME_H],
[
AC_REQUIRE([AC_CANONICAL_HOST])
AC_REQUIRE([gl_UTIME_H_DEFAULTS])
m4_ifdef([gl_ANSI_CXX], [AC_REQUIRE([gl_ANSI_CXX])])
AC_CHECK_HEADERS_ONCE([utime.h])
gl_CHECK_NEXT_HEADERS([utime.h])
if test $ac_cv_header_utime_h = yes; then
HAVE_UTIME_H=1
else
HAVE_UTIME_H=0
fi
AC_SUBST([HAVE_UTIME_H])
dnl Check for declarations of anything we want to poison if the
dnl corresponding gnulib module is not in use.
gl_WARN_ON_USE_PREPARE([[#include <utime.h>
]],
[utime])
])
AC_DEFUN([gl_UTIME_MODULE_INDICATOR],
[
dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
AC_REQUIRE([gl_UTIME_H_DEFAULTS])
gl_MODULE_INDICATOR_SET_VARIABLE([$1])
dnl Define it also as a C macro, for the benefit of the unit tests.
gl_MODULE_INDICATOR_FOR_TESTS([$1])
])
AC_DEFUN([gl_UTIME_H_DEFAULTS],
[
GNULIB_UTIME=0; AC_SUBST([GNULIB_UTIME])
dnl Support Microsoft deprecated alias function names by default.
GNULIB_MDA_UTIME=1; AC_SUBST([GNULIB_MDA_UTIME])
dnl Assume POSIX behavior unless another module says otherwise.
HAVE_UTIME=1; AC_SUBST([HAVE_UTIME])
REPLACE_UTIME=0; AC_SUBST([REPLACE_UTIME])
])
|
