blob: 7a560d2b9b2d0f82f71f5f4ac0f741dc4ee1be8b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
/*
* Copyright (C) 2011 Alexander Larsson <alexl@redhat.com>
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
using Folks;
/**
* The SetupWindow is the window that is shown to the user when they run
* Contacts for the first time. It asks the user to setup a primary address
* book.
*/
[GtkTemplate (ui = "/org/gnome/Contacts/ui/contacts-setup-window.ui")]
public class Contacts.SetupWindow : Adw.ApplicationWindow {
[GtkChild]
private unowned Adw.Clamp clamp;
[GtkChild]
private unowned Gtk.Button setup_done_button;
private AccountsList accounts_list;
/**
* Fired after the user has successfully performed the setup proess.
*/
public signal void setup_done (Edsf.PersonaStore selected_address_book);
public SetupWindow (App app, Store store) {
Object (application: app, icon_name: Config.APP_ID);
// Setup the list of address books
this.accounts_list = new AccountsList (store);
this.clamp.set_child (this.accounts_list);
this.accounts_list.notify["selected-store"].connect ((obj, pspec) => {
this.setup_done_button.sensitive = (this.accounts_list.selected_store != null);
});
// In case of a badly configured system, there will be 0 address books and
// as a user there's no way to know why that might happen, so at least put
// a warning log message. Make sure we do give Backends some time to come
// up
Timeout.add_seconds (5, () => {
if (store.address_books.get_n_items () == 0)
warning ("No address books were found on the system. Are you sure evolution-data-server is running?");
return Source.REMOVE;
});
// Make sure we emit a signal when setup is complete
this.setup_done_button.clicked.connect (() => {
setup_done ((Edsf.PersonaStore) this.accounts_list.selected_store);
});
// Make visible when we're using a nightly build
if (Config.PROFILE == "development")
get_style_context ().add_class ("devel");
}
}
|
