1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
|
project(
'gnome-bluetooth', 'c',
version: '42.alpha.2',
license: 'GPL2+',
default_options: 'buildtype=debugoptimized',
meson_version: '>= 0.53.0',
)
gnomebt_version = meson.project_version()
version_array = gnomebt_version.split('.')
gnomebt_major_version = version_array[0].to_int()
gnomebt_api_version = '3.0'
gnomebt_api_name = '@0@-@1@'.format(meson.project_name(), gnomebt_api_version)
gnomebt_ui_api_name = '@0@-ui-@1@'.format(meson.project_name(), gnomebt_api_version)
gnomebt_gettext_package = gnomebt_api_name
gnomebt_gir_ns = 'GnomeBluetooth'
gnomebt_prefix = get_option('prefix')
gnomebt_datadir = get_option('datadir')
gnomebt_localedir = get_option('localedir')
gnomebt_pkgdatadir = gnomebt_datadir / gnomebt_api_name
# options
enable_gtk_doc = get_option('gtk_doc')
enable_gir = get_option('introspection')
# Before making a release, the GNOMEBT_LT_VERSION string should be modified.
# The string is of the form C:R:A.
# - If interfaces have been changed or added, but binary compatibility has
# been preserved, change to C+1:0:A+1
# - If binary compatibility has been broken (eg removed or changed interfaces)
# change to C+1:0:0
# - If the interface is the same as the previous version, change to C:R+1:A
current = 14
revision = 0
age = 1
lt_soversion = current - age
libversion = '@0@.@1@.@2@'.format(lt_soversion, age, revision)
gnome = import('gnome')
i18n = import('i18n')
pkg = import('pkgconfig')
po_dir = meson.current_source_dir() / 'po'
top_inc = include_directories('.')
cc = meson.get_compiler('c')
config_h = configuration_data()
#i18n
config_h.set_quoted('GETTEXT_PACKAGE', gnomebt_gettext_package)
config_h.set_quoted('LOCALEDIR', gnomebt_prefix / gnomebt_localedir)
# compiler flags
common_flags = [
'-DHAVE_CONFIG_H',
'-DBONOBO_DISABLE_DEPRECATED',
'-DBONOBO_DISABLE_SINGLE_INCLUDES',
'-DBONOBO_UI_DISABLE_DEPRECATED',
'-DBONOBO_UI_DISABLE_SINGLE_INCLUDES',
'-DGCONF_DISABLE_DEPRECATED',
'-DGCONF_DISABLE_SINGLE_INCLUDES',
'-DGNOME_DISABLE_DEPRECATED',
'-DGNOME_DISABLE_SINGLE_INCLUDES',
'-DGNOME_VFS_DISABLE_DEPRECATED',
'-DGNOME_VFS_DISABLE_SINGLE_INCLUDES',
'-DLIBGLADE_DISABLE_DEPRECATED',
'-DLIBGLADE_DISABLE_SINGLE_INCLUDES',
'-DLIBSOUP_DISABLE_DEPRECATED',
'-DLIBSOUP_DISABLE_SINGLE_INCLUDES',
'-DWNCK_DISABLE_DEPRECATED',
'-DWNCK_DISABLE_SINGLE_INCLUDES',
]
compiler_flags = []
if get_option('buildtype').contains('debug')
compiler_flags += cc.get_supported_arguments([
'-Werror=format=2',
'-Werror=implicit-function-declaration',
'-Werror=init-self',
'-Werror=missing-prototypes',
'-Werror=missing-include-dirs',
'-Werror=pointer-arith',
'-Werror=return-type',
'-Wnested-externs',
'-Wstrict-prototypes',
])
endif
add_project_arguments(common_flags + compiler_flags, language: 'c')
gio_dep = dependency('gio-2.0', version: '>= 2.44')
gio_unix_dep = dependency('gio-unix-2.0')
gtk_dep = dependency('gtk4', version: '>= 4.4')
gsound_dep = dependency('gsound')
libadwaita_dep = dependency(
'libadwaita-1',
version: '>= 1.1',
fallback: ['libadwaita', 'libadwaita_dep'],
default_options: ['examples=false', 'introspection=disabled', 'tests=false', 'vapi=false'],
)
libnotify_dep = dependency('libnotify', version: '>= 0.7.0')
libudev_dep = dependency('libudev')
upower_dep = dependency('upower-glib', version: '>= 0.99.14')
m_dep = cc.find_library('m')
subdir('lib')
if get_option('sendto')
subdir('sendto')
endif
if enable_gtk_doc
subdir('docs/reference/libgnome-bluetooth')
endif
subdir('po')
python = import('python')
python3 = python.find_installation('python3')
has_dbusmock = false
script = 'import dbusmock'
if run_command(python3, '-c', script, check: false).returncode() == 0
has_dbusmock = true
endif
subdir('tests')
configure_file(
output: 'config.h',
configuration: config_h,
)
meson.add_install_script(
'meson_post_install.py',
get_option('icon_update') ? 'icon_update' : '',
gnomebt_datadir,
)
summary({'Documentation': enable_gtk_doc,
'Introspection': enable_gir,
'Dbusmock tests': has_dbusmock,
'Send-to': get_option('sendto'),
'Run gtk-update-icon-cache': get_option('icon_update')},
section: 'General')
meson.add_dist_script(
find_program('check-news.sh').path(),
'@0@'.format(meson.project_version()),
'NEWS',
)
|