g-stsifd-sockets.adb: New file.

2007-04-06  Thomas Quinot  <quinot@adacore.com>
	    Pat Rogers  <rogers@adacore.com>
	    Pascal Obry  <obry@adacore.com>

	* g-stsifd-sockets.adb: New file.

	* g-socthi.ads, g-socket.adb, g-socthi-vxworks.adb,
	g-socthi-vxworks.ads, g-socthi-mingw.ads, g-socthi-vms.ads,
	g-socthi-vms.adb: Move signalling
	fd management to a nested package, so that they can conveniently be
	moved to a subunit that is shared across Windows, VMS, and VxWorks
	(Ada implementation) or completed with imported bodies from socket.c
	(UNIX case).
	(Read_Signalling_Fd, Write_Signalling_Fd, Create_Signalling_Fds): New
	subprograms.
	(Check_Selector): Use Read_Signalling_Fd to read and discard data from
	the signalling file descriptor.
	(Abort_Selector): Use Write_Signalling_Fd to write dummy data to the
	signalling file descriptor.
	(Create_Selector): Use new C-imported subprogram Create_Signalling_Fds
	instead of creating a pair of sockets for signalling here.

	* g-socthi.adb: Ditto.
	Set the runtime process to ignore SIGPIPEs on platforms that support
	neither SO_NOSIGPIPE nor MSG_NOSIGNAL functionality.

	* g-socthi-mingw.adb: Ditto.
	(WS_Version): Use Windows 2.2.
	Use Winsock 2.2 (instead of 1.1) for the GNAT.Socket API.

	* g-soliop-mingw.ads: Link with ws2_32 for Windows 2.x support.
	Use Winsock 2.2 (instead of 1.1) for the GNAT.Socket API.

	* Makefile.in: New libgnat pair g-stsifd.adb<g-stsifd-sockets.adb.
	added GNAT byte swapping facility
	Update FreeBSD THREADSLIB from -lc_r to -lpthread, for FreeBSD 6.

	* g-bytswa.adb, g-bytswa-x86.adb, g-bytswa.ads: New files.

	* socket.c (__gnat_read_signalling_fd, __gnat_write_controlling_fd):
	New subprograms.
	(__gnat_create_signalling_fds): New subprogram.
	Set the runtime process to ignore SIGPIPEs on platforms that support
	neither SO_NOSIGPIPE nor MSG_NOSIGNAL functionality.

From-SVN: r123542

1 files changed, 194 insertions, 0 deletions

diff --git a/gcc/ada/g-bytswa-x86.adb b/gcc/ada/g-bytswa-x86.adb
new file mode 100644
index 00000000000..1ec8a0f1be7
--- /dev/null
+++ b/gcc/ada/g-bytswa-x86.adb
@@ -0,0 +1,194 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                         GNAT RUN-TIME COMPONENTS                         --
+--                                                                          --
+--                    G N A T . B Y T E _ S W A P P I N G                   --
+--                                                                          --
+--                                 B o d y                                  --
+--                                                                          --
+--                      Copyright (C) 2006, AdaCore                         --
+--                                                                          --
+-- GNAT is free software;  you can  redistribute it  and/or modify it under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 2,  or (at your option) any later ver- --
+-- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
+-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
+-- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
+-- for  more details.  You should have  received  a copy of the GNU General --
+-- Public License  distributed with GNAT;  see file COPYING.  If not, write --
+-- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
+-- Boston, MA 02110-1301, USA.                                              --
+--                                                                          --
+-- As a special exception,  if other files  instantiate  generics from this --
+-- unit, or you link  this unit with other files  to produce an executable, --
+-- this  unit  does not  by itself cause  the resulting  executable  to  be --
+-- covered  by the  GNU  General  Public  License.  This exception does not --
+-- however invalidate  any other reasons why  the executable file  might be --
+-- covered by the  GNU Public License.                                      --
+--                                                                          --
+-- GNAT was originally developed  by the GNAT team at  New York University. --
+-- Extensive contributions were provided by Ada Core Technologies Inc.      --
+--                                                                          --
+------------------------------------------------------------------------------
+
+--  This is a machine-specific version of this package.
+--  It uses instructions available on Intel 486 processors (or later).
+
+with Interfaces;          use Interfaces;
+with System.Machine_Code; use System.Machine_Code;
+with Ada.Unchecked_Conversion;
+
+package body GNAT.Byte_Swapping is
+
+   -----------------------
+   -- Local Subprograms --
+   -----------------------
+
+   function Swapped32 (Value : Unsigned_32) return Unsigned_32;
+   pragma Inline_Always (Swapped32);
+
+   --------------
+   -- Swapped2 --
+   --------------
+
+   function Swapped2 (Input : Item) return Item is
+
+      function As_U16 is new Ada.Unchecked_Conversion
+         (Source => Item, Target => Unsigned_16);
+
+      function As_Item is new Ada.Unchecked_Conversion
+         (Source => Unsigned_16, Target => Item);
+
+      X : Unsigned_16 := As_U16 (Input);
+
+   begin
+      Asm ("xchgb %b0,%h0",
+           Unsigned_16'Asm_Output ("=q", X),
+           Unsigned_16'Asm_Input ("0", X));
+      return As_Item (X);
+   end Swapped2;
+
+   --------------
+   -- Swapped4 --
+   --------------
+
+   function Swapped4 (Input : Item) return Item is
+
+      function As_U32 is new Ada.Unchecked_Conversion
+         (Source => Item, Target => Unsigned_32);
+
+      function As_Item is new Ada.Unchecked_Conversion
+         (Source => Unsigned_32, Target => Item);
+
+      X : Unsigned_32 := As_U32 (Input);
+
+   begin
+      Asm ("bswap %0",
+           Unsigned_32'Asm_Output ("=r", X),
+           Unsigned_32'Asm_Input ("0", X));
+      return As_Item (X);
+   end Swapped4;
+
+   --------------
+   -- Swapped8 --
+   --------------
+
+   function Swapped8 (Input : Item) return Item is
+
+      function As_U64 is new Ada.Unchecked_Conversion
+         (Source => Item, Target => Unsigned_64);
+
+      X : Unsigned_64 renames As_U64 (Input);
+
+      type Two_Words is array (0 .. 1) of Unsigned_32;
+      for Two_Words'Component_Size use Unsigned_32'Size;
+
+      function As_Item is new Ada.Unchecked_Conversion
+        (Source => Two_Words, Target => Item);
+
+      Result : Two_Words;
+
+   begin
+      Asm ("xchgl %0,%1",
+         Outputs =>
+            (Unsigned_32'Asm_Output ("=r", Result (0)),
+             Unsigned_32'Asm_Output ("=r", Result (1))),
+         Inputs =>
+            (Unsigned_32'Asm_Input ("0",
+                Swapped32 (Unsigned_32 (X and 16#0000_0000_FFFF_FFFF#))),
+             Unsigned_32'Asm_Input ("1",
+                Swapped32 (Unsigned_32 (Shift_Right (X, 32))))));
+      return As_Item (Result);
+   end Swapped8;
+
+   -----------
+   -- Swap2 --
+   -----------
+
+   procedure Swap2 (Location : in System.Address) is
+
+      X : Unsigned_16;
+      for X'Address use Location;
+
+   begin
+      Asm ("xchgb %b0,%h0",
+           Unsigned_16'Asm_Output ("=q", X),
+           Unsigned_16'Asm_Input ("0", X));
+   end Swap2;
+
+   -----------
+   -- Swap4 --
+   -----------
+
+   procedure Swap4 (Location : in System.Address) is
+
+      X : Unsigned_32;
+      for X'Address use Location;
+
+   begin
+      Asm ("bswap %0",
+           Unsigned_32'Asm_Output ("=r", X),
+           Unsigned_32'Asm_Input ("0", X));
+   end Swap4;
+
+   ---------------
+   -- Swapped32 --
+   ---------------
+
+   function Swapped32 (Value : Unsigned_32) return Unsigned_32 is
+      X : Unsigned_32 := Value;
+   begin
+      Asm ("bswap %0",
+           Unsigned_32'Asm_Output ("=r", X),
+           Unsigned_32'Asm_Input ("0", X));
+      return X;
+   end Swapped32;
+
+   -----------
+   -- Swap8 --
+   -----------
+
+   procedure Swap8 (Location : in System.Address) is
+
+      X : Unsigned_64;
+      for X'Address use Location;
+
+      type Two_Words is array (0 .. 1) of Unsigned_32;
+      for Two_Words'Component_Size use Unsigned_32'Size;
+
+      Words : Two_Words;
+      for Words'Address use Location;
+
+   begin
+      Asm ("xchgl %0,%1",
+         Outputs =>
+            (Unsigned_32'Asm_Output ("=r", Words (0)),
+             Unsigned_32'Asm_Output ("=r", Words (1))),
+         Inputs =>
+            (Unsigned_32'Asm_Input ("0",
+                Swapped32 (Unsigned_32 (X and 16#0000_0000_FFFF_FFFF#))),
+             Unsigned_32'Asm_Input ("1",
+                Swapped32 (Unsigned_32 (Shift_Right (X, 32))))));
+   end Swap8;
+
+end GNAT.Byte_Swapping;