Rename all test files to reflect source layout.

 * CONTRIBUTE,Makefile.in,configure.ac: Update to reflect
   test directory moves.
 * test/file-organisation.org: New file.
 * test/automated/Makefile.in
   test/automated/data/decompress/foo.gz
   test/automated/data/epg/pubkey.asc
   test/automated/data/epg/seckey.asc
   test/automated/data/files-bug18141.el.gz
   test/automated/data/flymake/test.c
   test/automated/data/flymake/test.pl
   test/automated/data/package/archive-contents
   test/automated/data/package/key.pub
   test/automated/data/package/key.sec
   test/automated/data/package/multi-file-0.2.3.tar
   test/automated/data/package/multi-file-readme.txt
   test/automated/data/package/newer-versions/archive-contents
   test/automated/data/package/newer-versions/new-pkg-1.0.el
   test/automated/data/package/newer-versions/simple-single-1.4.el
   test/automated/data/package/package-test-server.py
   test/automated/data/package/signed/archive-contents
   test/automated/data/package/signed/archive-contents.sig
   test/automated/data/package/signed/signed-bad-1.0.el
   test/automated/data/package/signed/signed-bad-1.0.el.sig
   test/automated/data/package/signed/signed-good-1.0.el
   test/automated/data/package/signed/signed-good-1.0.el.sig
   test/automated/data/package/simple-depend-1.0.el
   test/automated/data/package/simple-single-1.3.el
   test/automated/data/package/simple-single-readme.txt
   test/automated/data/package/simple-two-depend-1.1.el
   test/automated/abbrev-tests.el
   test/automated/auto-revert-tests.el
   test/automated/calc-tests.el
   test/automated/icalendar-tests.el
   test/automated/character-fold-tests.el
   test/automated/comint-testsuite.el
   test/automated/descr-text-test.el
   test/automated/electric-tests.el
   test/automated/cl-generic-tests.el
   test/automated/cl-lib-tests.el
   test/automated/eieio-test-methodinvoke.el
   test/automated/eieio-test-persist.el
   test/automated/eieio-tests.el
   test/automated/ert-tests.el
   test/automated/ert-x-tests.el
   test/automated/generator-tests.el
   test/automated/let-alist.el
   test/automated/map-tests.el
   test/automated/advice-tests.el
   test/automated/package-test.el
   test/automated/pcase-tests.el
   test/automated/regexp-tests.el
   test/automated/seq-tests.el
   test/automated/subr-x-tests.el
   test/automated/tabulated-list-test.el
   test/automated/thunk-tests.el
   test/automated/timer-tests.el
   test/automated/epg-tests.el
   test/automated/eshell.el
   test/automated/faces-tests.el
   test/automated/file-notify-tests.el
   test/automated/auth-source-tests.el
   test/automated/gnus-tests.el
   test/automated/message-mode-tests.el
   test/automated/help-fns.el
   test/automated/imenu-test.el
   test/automated/info-xref.el
   test/automated/mule-util.el
   test/automated/isearch-tests.el
   test/automated/json-tests.el
   test/automated/bytecomp-tests.el
   test/automated/coding-tests.el
   test/automated/core-elisp-tests.el
   test/automated/decoder-tests.el
   test/automated/files.el
   test/automated/font-parse-tests.el
   test/automated/lexbind-tests.el
   test/automated/occur-tests.el
   test/automated/process-tests.el
   test/automated/syntax-tests.el
   test/automated/textprop-tests.el
   test/automated/undo-tests.el
   test/automated/man-tests.el
   test/automated/completion-tests.el
   test/automated/dbus-tests.el
   test/automated/newsticker-tests.el
   test/automated/sasl-scram-rfc-tests.el
   test/automated/tramp-tests.el
   test/automated/obarray-tests.el
   test/automated/compile-tests.el
   test/automated/elisp-mode-tests.el
   test/automated/f90.el
   test/automated/flymake-tests.el
   test/automated/python-tests.el
   test/automated/ruby-mode-tests.el
   test/automated/subword-tests.el
   test/automated/replace-tests.el
   test/automated/simple-test.el
   test/automated/sort-tests.el
   test/automated/subr-tests.el
   test/automated/reftex-tests.el
   test/automated/sgml-mode-tests.el
   test/automated/tildify-tests.el
   test/automated/thingatpt.el
   test/automated/url-future-tests.el
   test/automated/url-util-tests.el
   test/automated/add-log-tests.el
   test/automated/vc-bzr.el
   test/automated/vc-tests.el
   test/automated/xml-parse-tests.el
   test/BidiCharacterTest.txt
   test/biditest.el
   test/cedet/cedet-utests.el
   test/cedet/ede-tests.el
   test/cedet/semantic-ia-utest.el
   test/cedet/semantic-tests.el
   test/cedet/semantic-utest-c.el
   test/cedet/semantic-utest.el
   test/cedet/srecode-tests.el
   test/cedet/tests/test.c
   test/cedet/tests/test.el
   test/cedet/tests/test.make
   test/cedet/tests/testdoublens.cpp
   test/cedet/tests/testdoublens.hpp
   test/cedet/tests/testfriends.cpp
   test/cedet/tests/testjavacomp.java
   test/cedet/tests/testnsp.cpp
   test/cedet/tests/testpolymorph.cpp
   test/cedet/tests/testspp.c
   test/cedet/tests/testsppcomplete.c
   test/cedet/tests/testsppreplace.c
   test/cedet/tests/testsppreplaced.c
   test/cedet/tests/testsubclass.cpp
   test/cedet/tests/testsubclass.hh
   test/cedet/tests/testtypedefs.cpp
   test/cedet/tests/testvarnames.c
   test/etags/CTAGS.good
   test/etags/ETAGS.good_1
   test/etags/ETAGS.good_2
   test/etags/ETAGS.good_3
   test/etags/ETAGS.good_4
   test/etags/ETAGS.good_5
   test/etags/ETAGS.good_6
   test/etags/a-src/empty.zz
   test/etags/a-src/empty.zz.gz
   test/etags/ada-src/2ataspri.adb
   test/etags/ada-src/2ataspri.ads
   test/etags/ada-src/etags-test-for.ada
   test/etags/ada-src/waroquiers.ada
   test/etags/c-src/a/b/b.c
   test/etags/c-src/abbrev.c
   test/etags/c-src/c.c
   test/etags/c-src/dostorture.c
   test/etags/c-src/emacs/src/gmalloc.c
   test/etags/c-src/emacs/src/keyboard.c
   test/etags/c-src/emacs/src/lisp.h
   test/etags/c-src/emacs/src/regex.h
   test/etags/c-src/etags.c
   test/etags/c-src/exit.c
   test/etags/c-src/exit.strange_suffix
   test/etags/c-src/fail.c
   test/etags/c-src/getopt.h
   test/etags/c-src/h.h
   test/etags/c-src/machsyscalls.c
   test/etags/c-src/machsyscalls.h
   test/etags/c-src/sysdep.h
   test/etags/c-src/tab.c
   test/etags/c-src/torture.c
   test/etags/cp-src/MDiagArray2.h
   test/etags/cp-src/Range.h
   test/etags/cp-src/burton.cpp
   test/etags/cp-src/c.C
   test/etags/cp-src/clheir.cpp.gz
   test/etags/cp-src/clheir.hpp
   test/etags/cp-src/conway.cpp
   test/etags/cp-src/conway.hpp
   test/etags/cp-src/fail.C
   test/etags/cp-src/functions.cpp
   test/etags/cp-src/screen.cpp
   test/etags/cp-src/screen.hpp
   test/etags/cp-src/x.cc
   test/etags/el-src/TAGTEST.EL
   test/etags/el-src/emacs/lisp/progmodes/etags.el
   test/etags/erl-src/gs_dialog.erl
   test/etags/f-src/entry.for
   test/etags/f-src/entry.strange.gz
   test/etags/f-src/entry.strange_suffix
   test/etags/forth-src/test-forth.fth
   test/etags/html-src/algrthms.html
   test/etags/html-src/index.shtml
   test/etags/html-src/software.html
   test/etags/html-src/softwarelibero.html
   test/etags/lua-src/allegro.lua
   test/etags/objc-src/PackInsp.h
   test/etags/objc-src/PackInsp.m
   test/etags/objc-src/Subprocess.h
   test/etags/objc-src/Subprocess.m
   test/etags/objcpp-src/SimpleCalc.H
   test/etags/objcpp-src/SimpleCalc.M
   test/etags/pas-src/common.pas
   test/etags/perl-src/htlmify-cystic
   test/etags/perl-src/kai-test.pl
   test/etags/perl-src/yagrip.pl
   test/etags/php-src/lce_functions.php
   test/etags/php-src/ptest.php
   test/etags/php-src/sendmail.php
   test/etags/prol-src/natded.prolog
   test/etags/prol-src/ordsets.prolog
   test/etags/ps-src/rfc1245.ps
   test/etags/pyt-src/server.py
   test/etags/tex-src/gzip.texi
   test/etags/tex-src/nonewline.tex
   test/etags/tex-src/testenv.tex
   test/etags/tex-src/texinfo.tex
   test/etags/y-src/atest.y
   test/etags/y-src/cccp.c
   test/etags/y-src/cccp.y
   test/etags/y-src/parse.c
   test/etags/y-src/parse.y
   test/indent/css-mode.css
   test/indent/js-indent-init-dynamic.js
   test/indent/js-indent-init-t.js
   test/indent/js-jsx.js
   test/indent/js.js
   test/indent/latex-mode.tex
   test/indent/modula2.mod
   test/indent/nxml.xml
   test/indent/octave.m
   test/indent/pascal.pas
   test/indent/perl.perl
   test/indent/prolog.prolog
   test/indent/ps-mode.ps
   test/indent/ruby.rb
   test/indent/scheme.scm
   test/indent/scss-mode.scss
   test/indent/sgml-mode-attribute.html
   test/indent/shell.rc
   test/indent/shell.sh
   test/redisplay-testsuite.el
   test/rmailmm.el
   test/automated/buffer-tests.el
   test/automated/cmds-tests.el
   test/automated/data-tests.el
   test/automated/finalizer-tests.el
   test/automated/fns-tests.el
   test/automated/inotify-test.el
   test/automated/keymap-tests.el
   test/automated/print-tests.el
   test/automated/libxml-tests.el
   test/automated/zlib-tests.el: Files Moved.

1 files changed, 331 insertions, 0 deletions

diff --git a/test/lisp/emacs-lisp/map-tests.el b/test/lisp/emacs-lisp/map-tests.el
new file mode 100644
index 00000000000..2a7fcc39d41
--- /dev/null
+++ b/test/lisp/emacs-lisp/map-tests.el
@@ -0,0 +1,331 @@
+;;; map-tests.el --- Tests for map.el  -*- lexical-binding:t -*-
+
+;; Copyright (C) 2015 Free Software Foundation, Inc.
+
+;; Author: Nicolas Petton <nicolas@petton.fr>
+;; Maintainer: emacs-devel@gnu.org
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Tests for map.el
+
+;;; Code:
+
+(require 'ert)
+(require 'map)
+
+(defmacro with-maps-do (var &rest body)
+  "Successively bind VAR to an alist, vector and hash-table.
+Each map is built from the following alist data:
+'((0 . 3) (1 . 4) (2 . 5)).
+Evaluate BODY for each created map.
+
+\(fn (var map) body)"
+  (declare (indent 1) (debug t))
+  (let ((alist (make-symbol "alist"))
+        (vec (make-symbol "vec"))
+        (ht (make-symbol "ht")))
+   `(let ((,alist (list (cons 0 3)
+                        (cons 1 4)
+                        (cons 2 5)))
+          (,vec (vector 3 4 5))
+          (,ht (make-hash-table)))
+      (puthash 0 3 ,ht)
+      (puthash 1 4 ,ht)
+      (puthash 2 5 ,ht)
+      (dolist (,var (list ,alist ,vec ,ht))
+        ,@body))))
+
+(ert-deftest test-map-elt ()
+  (with-maps-do map
+    (should (= 3 (map-elt map 0)))
+    (should (= 4 (map-elt map 1)))
+    (should (= 5 (map-elt map 2)))
+    (should (null (map-elt map -1)))
+    (should (null (map-elt map 4)))))
+
+(ert-deftest test-map-elt-default ()
+  (with-maps-do map
+    (should (= 5 (map-elt map 7 5)))))
+
+(ert-deftest test-map-elt-with-nil-value ()
+  (should (null (map-elt '((a . 1)
+                           (b))
+                         'b
+                         '2))))
+
+(ert-deftest test-map-put ()
+  (with-maps-do map
+    (setf (map-elt map 2) 'hello)
+    (should (eq (map-elt map 2) 'hello)))
+  (with-maps-do map
+    (map-put map 2 'hello)
+    (should (eq (map-elt map 2) 'hello)))
+  (let ((ht (make-hash-table)))
+    (setf (map-elt ht 2) 'a)
+    (should (eq (map-elt ht 2)
+                'a)))
+  (let ((alist '((0 . a) (1 . b) (2 . c))))
+    (setf (map-elt alist 2) 'a)
+    (should (eq (map-elt alist 2)
+                'a)))
+  (let ((vec [3 4 5]))
+   (should-error (setf (map-elt vec 3) 6))))
+
+(ert-deftest test-map-put-return-value ()
+  (let ((ht (make-hash-table)))
+    (should (eq (map-put ht 'a 'hello) ht))))
+
+(ert-deftest test-map-delete ()
+  (with-maps-do map
+    (map-delete map 1)
+    (should (null (map-elt map 1))))
+  (with-maps-do map
+    (map-delete map -2)
+    (should (null (map-elt map -2)))))
+
+(ert-deftest test-map-delete-return-value ()
+  (let ((ht (make-hash-table)))
+    (should (eq (map-delete ht 'a) ht))))
+
+(ert-deftest test-map-nested-elt ()
+  (let ((vec [a b [c d [e f]]]))
+    (should (eq (map-nested-elt vec '(2 2 0)) 'e)))
+  (let ((alist '((a . 1)
+                 (b . ((c . 2)
+                       (d . 3)
+                       (e . ((f . 4)
+                             (g . 5))))))))
+    (should (eq (map-nested-elt alist '(b e f))
+                4)))
+  (let ((ht (make-hash-table)))
+    (setf (map-elt ht 'a) 1)
+    (setf (map-elt ht 'b) (make-hash-table))
+    (setf (map-elt (map-elt ht 'b) 'c) 2)
+    (should (eq (map-nested-elt ht '(b c))
+                2))))
+
+(ert-deftest test-map-nested-elt-default ()
+  (let ((vec [a b [c d]]))
+    (should (null (map-nested-elt vec '(2 3))))
+    (should (null (map-nested-elt vec '(2 1 1))))
+    (should (= 4 (map-nested-elt vec '(2 1 1) 4)))))
+
+(ert-deftest test-mapp ()
+  (should (mapp nil))
+  (should (mapp '((a . b) (c . d))))
+  (should (mapp '(a b c d)))
+  (should (mapp []))
+  (should (mapp [1 2 3]))
+  (should (mapp (make-hash-table)))
+  (should (mapp "hello"))
+  (should (not (mapp 1)))
+  (should (not (mapp 'hello))))
+
+(ert-deftest test-map-keys ()
+  (with-maps-do map
+    (should (equal (map-keys map) '(0 1 2))))
+  (should (null (map-keys nil)))
+  (should (null (map-keys []))))
+
+(ert-deftest test-map-values ()
+  (with-maps-do map
+    (should (equal (map-values map) '(3 4 5)))))
+
+(ert-deftest test-map-pairs ()
+  (with-maps-do map
+    (should (equal (map-pairs map) '((0 . 3)
+                                     (1 . 4)
+                                     (2 . 5))))))
+
+(ert-deftest test-map-length ()
+  (let ((ht (make-hash-table)))
+    (puthash 'a 1 ht)
+    (puthash 'b 2 ht)
+    (puthash 'c 3 ht)
+    (puthash 'd 4 ht)
+    (should (= 0 (map-length nil)))
+    (should (= 0 (map-length [])))
+    (should (= 0 (map-length (make-hash-table))))
+    (should (= 5 (map-length [0 1 2 3 4])))
+    (should (= 2 (map-length '((a . 1) (b . 2)))))
+    (should (= 4 (map-length ht)))))
+
+(ert-deftest test-map-copy ()
+  (with-maps-do map
+    (let ((copy (map-copy map)))
+      (should (equal (map-keys map) (map-keys copy)))
+      (should (equal (map-values map) (map-values copy)))
+      (should (not (eq map copy))))))
+
+(ert-deftest test-map-apply ()
+  (with-maps-do map
+    (should (equal (map-apply (lambda (k v) (cons (int-to-string k) v))
+                              map)
+                   '(("0" . 3) ("1" . 4) ("2" . 5)))))
+  (let ((vec [a b c]))
+    (should (equal (map-apply (lambda (k v) (cons (1+ k) v))
+                              vec)
+                   '((1 . a)
+                     (2 . b)
+                     (3 . c))))))
+
+(ert-deftest test-map-keys-apply ()
+  (with-maps-do map
+    (should (equal (map-keys-apply (lambda (k) (int-to-string k))
+                                   map)
+                   '("0" "1" "2"))))
+  (let ((vec [a b c]))
+    (should (equal (map-keys-apply (lambda (k) (1+ k))
+                                   vec)
+                   '(1 2 3)))))
+
+(ert-deftest test-map-values-apply ()
+  (with-maps-do map
+    (should (equal (map-values-apply (lambda (v) (1+ v))
+                                     map)
+                   '(4 5 6))))
+  (let ((vec [a b c]))
+    (should (equal (map-values-apply (lambda (v) (symbol-name v))
+                                     vec)
+                   '("a" "b" "c")))))
+
+(ert-deftest test-map-filter ()
+  (with-maps-do map
+    (should (equal (map-keys (map-filter (lambda (_k v)
+                                           (<= 4 v))
+                                         map))
+                   '(1 2)))
+    (should (null (map-filter (lambda (k _v)
+                                (eq 'd k))
+                              map))))
+  (should (null (map-filter (lambda (_k v)
+                              (eq 3 v))
+                            [1 2 4 5])))
+  (should (equal (map-filter (lambda (k _v)
+                               (eq 3 k))
+                             [1 2 4 5])
+                 '((3 . 5)))))
+
+(ert-deftest test-map-remove ()
+  (with-maps-do map
+    (should (equal (map-keys (map-remove (lambda (_k v)
+                                           (>= v 4))
+                                         map))
+                   '(0)))
+    (should (equal (map-keys (map-remove (lambda (k _v)
+                                           (eq 'd k))
+                                         map))
+                   (map-keys map))))
+  (should (equal (map-remove (lambda (_k v)
+                               (eq 3 v))
+                             [1 2 4 5])
+                 '((0 . 1)
+                   (1 . 2)
+                   (2 . 4)
+                   (3 . 5))))
+  (should (null (map-remove (lambda (k _v)
+                              (>= k 0))
+                            [1 2 4 5]))))
+
+(ert-deftest test-map-empty-p ()
+  (should (map-empty-p nil))
+  (should (not (map-empty-p '((a . b) (c . d)))))
+  (should (map-empty-p []))
+  (should (not (map-empty-p [1 2 3])))
+  (should (map-empty-p (make-hash-table)))
+  (should (not (map-empty-p "hello")))
+  (should (map-empty-p "")))
+
+(ert-deftest test-map-contains-key ()
+  (should (map-contains-key '((a . 1) (b . 2)) 'a))
+  (should (not (map-contains-key '((a . 1) (b . 2)) 'c)))
+  (should (map-contains-key '(("a" . 1)) "a"))
+  (should (not (map-contains-key '(("a" . 1)) "a" #'eq)))
+  (should (map-contains-key [a b c] 2))
+  (should (not (map-contains-key [a b c] 3))))
+
+(ert-deftest test-map-some ()
+  (with-maps-do map
+    (should (map-some (lambda (k _v)
+                        (eq 1 k))
+                      map))
+    (should-not (map-some (lambda (k _v)
+                            (eq 'd k))
+                          map)))
+  (let ((vec [a b c]))
+    (should (map-some (lambda (k _v)
+                        (> k 1))
+                      vec))
+    (should-not (map-some (lambda (k _v)
+                            (> k 3))
+                          vec))))
+
+(ert-deftest test-map-every-p ()
+  (with-maps-do map
+    (should (map-every-p (lambda (k _v)
+                           k)
+                         map))
+    (should (not (map-every-p (lambda (_k _v)
+                                nil)
+                              map))))
+  (let ((vec [a b c]))
+    (should (map-every-p (lambda (k _v)
+                           (>= k 0))
+                         vec))
+    (should (not (map-every-p (lambda (k _v)
+                                (> k 3))
+                              vec)))))
+
+(ert-deftest test-map-into ()
+  (let* ((alist '((a . 1) (b . 2)))
+         (ht (map-into alist 'hash-table)))
+    (should (hash-table-p ht))
+    (should (equal (map-into (map-into alist 'hash-table) 'list)
+                   alist))
+    (should (listp (map-into ht 'list)))
+    (should (equal (map-keys (map-into (map-into ht 'list) 'hash-table))
+                   (map-keys ht)))
+    (should (equal (map-values (map-into (map-into ht 'list) 'hash-table))
+                   (map-values ht)))
+    (should (null (map-into nil 'list)))
+    (should (map-empty-p (map-into nil 'hash-table)))
+    (should-error (map-into [1 2 3] 'string))))
+
+(ert-deftest test-map-let ()
+  (map-let (foo bar baz) '((foo . 1) (bar . 2))
+    (should (= foo 1))
+    (should (= bar 2))
+    (should (null baz)))
+  (map-let (('foo a)
+            ('bar b)
+            ('baz c))
+      '((foo . 1) (bar . 2))
+    (should (= a 1))
+    (should (= b 2))
+    (should (null c))))
+
+(ert-deftest test-map-merge-with ()
+  (should (equal (map-merge-with 'list #'+
+                                 '((1 . 2))
+                                 '((1 . 3) (2 . 4))
+                                 '((1 . 1) (2 . 5) (3 . 0)))
+                 '((3 . 0) (2 . 9) (1 . 6)))))
+
+(provide 'map-tests)
+;;; map-tests.el ends here