build: don't accept a broken standard lib for C++

On the CI, we had failures such as:

    ./c++.at:401:  $PREPARSER ./list
    stderr:
    ./list: error while loading shared libraries: libc++.so.1:
            cannot open shared object file: No such file or directory

because we accepted `-std=c++ -stdlib=libc++` although libc++ is not
installed on the machine.

* m4/ax_check_compile_flag.m4 (AX_CHECK_COMPILE_FLAG): Rewrite as...
* m4/bison-check-compile-flag.m4 (BISON_CHECK_COMPILE_FLAG): this, so
that we use AC_LINK_IFELSE to check the compiler (and its std lib)
instead of AC_COMPILE_IFELSE.

3 files changed, 69 insertions, 86 deletions

diff --git a/m4/ax_check_compile_flag.m4 b/m4/ax_check_compile_flag.m4
deleted file mode 100644
index 71d4f365..00000000
--- a/m4/ax_check_compile_flag.m4
+++ /dev/null
@@ -1,70 +0,0 @@
-# ===========================================================================
-#   http://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
-# ===========================================================================
-#
-# SYNOPSIS
-#
-#   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS])
-#
-# DESCRIPTION
-#
-#   Check whether the given FLAG works with the current language's compiler
-#   or gives an error.  (Warnings, however, are ignored)
-#
-#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
-#   success/failure.
-#
-#   If EXTRA-FLAGS is defined, it is added to the current language's default
-#   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
-#   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
-#   force the compiler to issue an error when a bad flag is given.
-#
-#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
-#   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
-#
-# LICENSE
-#
-#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
-#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
-#
-#   This program is free software: you can redistribute it and/or modify it
-#   under the terms of the GNU General Public License as published by the
-#   Free Software Foundation, either version 3 of the License, or (at your
-#   option) any later version.
-#
-#   This program is distributed in the hope that it will be useful, but
-#   WITHOUT ANY WARRANTY; without even the implied warranty of
-#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
-#   Public License for more details.
-#
-#   You should have received a copy of the GNU General Public License along
-#   with this program. If not, see <http://www.gnu.org/licenses/>.
-#
-#   As a special exception, the respective Autoconf Macro's copyright owner
-#   gives unlimited permission to copy, distribute and modify the configure
-#   scripts that are the output of Autoconf when processing the Macro. You
-#   need not follow the terms of the GNU General Public License when using
-#   or distributing such scripts, even though portions of the text of the
-#   Macro appear in them. The GNU General Public License (GPL) does govern
-#   all other use of the material that constitutes the Autoconf Macro.
-#
-#   This special exception to the GPL applies to versions of the Autoconf
-#   Macro released by the Autoconf Archive. When you make and distribute a
-#   modified version of the Autoconf Macro, you may extend this special
-#   exception to the GPL to apply to your modified version as well.
-
-#serial 2
-
-AC_DEFUN([AX_CHECK_COMPILE_FLAG],
-[AC_PREREQ(2.59)dnl for _AC_LANG_PREFIX
-AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
-AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
-  ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
-  _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
-  AC_COMPILE_IFELSE([m4_default([$5], [AC_LANG_PROGRAM()])],
-    [AS_VAR_SET(CACHEVAR,[yes])],
-    [AS_VAR_SET(CACHEVAR,[no])])
-  _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
-AS_IF([test x"AS_VAR_GET(CACHEVAR)" = xyes], [$2], [$3])
-AS_VAR_POPDEF([CACHEVAR])dnl
-])dnl AX_CHECK_COMPILE_FLAGS
diff --git a/m4/ax_check_link_flag.m4 b/m4/ax_check_link_flag.m4
new file mode 100644
index 00000000..03a30ce4
--- /dev/null
+++ b/m4/ax_check_link_flag.m4
@@ -0,0 +1,53 @@
+# ===========================================================================
+#    https://www.gnu.org/software/autoconf-archive/ax_check_link_flag.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_CHECK_LINK_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
+#
+# DESCRIPTION
+#
+#   Check whether the given FLAG works with the linker or gives an error.
+#   (Warnings, however, are ignored)
+#
+#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
+#   success/failure.
+#
+#   If EXTRA-FLAGS is defined, it is added to the linker's default flags
+#   when the check is done.  The check is thus made with the flags: "LDFLAGS
+#   EXTRA-FLAGS FLAG".  This can for example be used to force the linker to
+#   issue an error when a bad flag is given.
+#
+#   INPUT gives an alternative input source to AC_LINK_IFELSE.
+#
+#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
+#   macro in sync with AX_CHECK_{PREPROC,COMPILE}_FLAG.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
+#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved.  This file is offered as-is, without any
+#   warranty.
+
+#serial 6
+
+AC_DEFUN([AX_CHECK_LINK_FLAG],
+[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
+AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_ldflags_$4_$1])dnl
+AC_CACHE_CHECK([whether the linker accepts $1], CACHEVAR, [
+  ax_check_save_flags=$LDFLAGS
+  LDFLAGS="$LDFLAGS $4 $1"
+  AC_LINK_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
+    [AS_VAR_SET(CACHEVAR,[yes])],
+    [AS_VAR_SET(CACHEVAR,[no])])
+  LDFLAGS=$ax_check_save_flags])
+AS_VAR_IF(CACHEVAR,yes,
+  [m4_default([$2], :)],
+  [m4_default([$3], :)])
+AS_VAR_POPDEF([CACHEVAR])dnl
+])dnl AX_CHECK_LINK_FLAGS
diff --git a/m4/bison-cxx-std.m4 b/m4/bison-cxx-std.m4
index 4e293a57..8c043e80 100644
--- a/m4/bison-cxx-std.m4
+++ b/m4/bison-cxx-std.m4
@@ -116,10 +116,10 @@ AC_DEFUN([BISON_CXX_COMPILE_STDCXX_11],
 AC_LANG_PUSH([C++])
 for f in '-std=c++11' '-std=c++11 -stdlib=libc++'
 do
-  AX_CHECK_COMPILE_FLAG([$f],
-                        [AC_SUBST([CXX11_CXXFLAGS], [$f]) break],
-                        [], [],
-                        [_BISON_CXX_COMPILE_STDCXX_11_testbody])
+  AX_CHECK_LINK_FLAG([$f],
+                     [AC_SUBST([CXX11_CXXFLAGS], [$f]) break],
+                     [], [],
+                     [_BISON_CXX_COMPILE_STDCXX_11_testbody])
 done
 AC_LANG_POP([C++])
 ])
@@ -130,10 +130,10 @@ AC_DEFUN([BISON_CXX_COMPILE_STDCXX_14],
 AC_LANG_PUSH([C++])
 for f in '-std=c++14' '-std=c++14 -stdlib=libc++'
 do
-  AX_CHECK_COMPILE_FLAG([$f],
-                        [AC_SUBST([CXX14_CXXFLAGS], [$f]) break],
-                        [], [],
-                        [_BISON_CXX_COMPILE_STDCXX_14_testbody])
+  AX_CHECK_LINK_FLAG([$f],
+                     [AC_SUBST([CXX14_CXXFLAGS], [$f]) break],
+                     [], [],
+                     [_BISON_CXX_COMPILE_STDCXX_14_testbody])
 done
 AC_LANG_POP([C++])
 ])
@@ -144,10 +144,10 @@ AC_DEFUN([BISON_CXX_COMPILE_STDCXX_17],
 AC_LANG_PUSH([C++])
 for f in '-std=c++17' '-std=c++17 -stdlib=libc++'
 do
-  AX_CHECK_COMPILE_FLAG([$f],
-                        [AC_SUBST([CXX17_CXXFLAGS], [$f]) break],
-                        [], [],
-                        [_BISON_CXX_COMPILE_STDCXX_17_testbody])
+  AX_CHECK_LINK_FLAG([$f],
+                     [AC_SUBST([CXX17_CXXFLAGS], [$f]) break],
+                     [], [],
+                     [_BISON_CXX_COMPILE_STDCXX_17_testbody])
 done
 AC_LANG_POP([C++])
 ])
@@ -158,10 +158,10 @@ AC_DEFUN([BISON_CXX_COMPILE_STDCXX_2A],
 AC_LANG_PUSH([C++])
 for f in '-std=c++2a' '-std=c++2a -stdlib=libc++'
 do
-  AX_CHECK_COMPILE_FLAG([$f],
-                        [AC_SUBST([CXX2A_CXXFLAGS], [$f]) break],
-                        [], [],
-                        [_BISON_CXX_COMPILE_STDCXX_2A_testbody])
+  AX_CHECK_LINK_FLAG([$f],
+                     [AC_SUBST([CXX2A_CXXFLAGS], [$f]) break],
+                     [], [],
+                     [_BISON_CXX_COMPILE_STDCXX_2A_testbody])
 done
 AC_LANG_POP([C++])
 ])