1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
|
dnl --------------------------------------------------------------------
dnl configure.ac --- GNU autoconf source for toplevel directory.
dnl
dnl Time-stamp: "2012-05-13 13:43:24 bkorb"
dnl Author: Bruce Korb <bkorb@gnu.org>
dnl
dnl This file is part of AutoGen.
dnl AutoGen Copyright (c) 1992-2012 by Bruce Korb - all rights reserved
dnl
dnl AutoGen is free software: you can redistribute it and/or modify it
dnl under the terms of the GNU General Public License as published by the
dnl Free Software Foundation, either version 3 of the License, or
dnl (at your option) any later version.
dnl
dnl AutoGen is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
dnl See the GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License along
dnl with this program. If not, see <http://www.gnu.org/licenses/>.
dnl
AC_INIT([GNU AutoGen],[5.16.2],[autogen-users@lists.sourceforge.net])
AC_CONFIG_SRCDIR(agen5/autogen.c)
AC_CONFIG_AUX_DIR(config)
AC_CANONICAL_TARGET
[. $srcdir/VERSION
d=`dirname $0`
ag_top_srcdir=`cd $d && pwd`
ag_top_builddir=`pwd`]
AM_INIT_AUTOMAKE([gnu check-news 1.5 dist-xz])
AC_USE_SYSTEM_EXTENSIONS
AC_LIBTOOL_WIN32_DLL m4_define(AC_PROVIDE_AC_LIBTOOL_WIN32_DLL)
AC_PROG_LIBTOOL
ifdef([AC_REVISION],AC_REVISION($Revision: 4.34 $),)dnl
[config_start_time=`date +%s 2>/dev/null`]
# ----------------------------------------------------------------------
# Substitute VERSION vars here, so that they can be used by the Makefile
# ----------------------------------------------------------------------
AC_SUBST(AG_VERSION)
AC_SUBST(AG_MAJOR_VERSION)
AC_SUBST(AG_MINOR_VERSION)
AC_SUBST(AO_CURRENT)
AC_SUBST(AO_REVISION)
AC_SUBST(AO_AGE)
[AO_TEMPLATE_VERSION=`expr '(' $AO_CURRENT '*' 4096 ')' + $AO_REVISION`
]dnl
AC_SUBST(AO_TEMPLATE_VERSION)
AC_SUBST(GO_CURRENT)
AC_SUBST(GO_REVISION)
AC_SUBST(GO_AGE)
AC_DEFINE_UNQUOTED(AO_CURRENT,$AO_CURRENT,
[Define this to the autoopts current interface number])
AC_DEFINE_UNQUOTED(AO_REVISION,$AO_REVISION,
[Define this to the autoopts interface revision number])
AC_DEFINE_UNQUOTED(AO_AGE,$AO_AGE,
[Define this to the autoopts interface age number])
# ----------------------------------------------------------------------
# Set up the environment to configure the snprintv subpackage using
# this version of AutoGen (as opposed to any installed version).
# ----------------------------------------------------------------------
[ag_srcdir=`\cd $srcdir && pwd`
if test x$ag_srcdir != x && test -d $ag_srcdir; then
:
else
ag_srcdir=..
fi
# ----------------------------------------------------------------------
# If `configure' is invoked (in)directly via `make', ensure that it
# encounters no `make' conflicts. Ignore error if shell does not have
# unset, but at least set these to empty values.
# ----------------------------------------------------------------------
MFLAGS=
MAKEFLAGS=
MAKELEVEL=
unset MFLAGS MAKEFLAGS MAKELEVEL 2>/dev/null]
AM_WITH_DMALLOC
# ----------------------------------------------------------------------
# check for various programs used during the build.
# ----------------------------------------------------------------------
AM_PROG_CC_C_O
AC_PROG_CC_STDC
gl_FUNC_GLIBC_UNLOCKED_IO
AC_EXEEXT
AC_PROG_INSTALL
AC_PROG_LIBTOOL
AC_CHECK_PROG(TEXI2HTML, texi2html, texi2html, :)
AC_C_CONST
AC_C_INLINE
# ----------------------------------------------------------------------
AC_CHECK_LIB(dl, dlopen)
# ----------------------------------------------------------------------
AC_TYPE_MODE_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_UID_T
AC_C_LONG_DOUBLE
[if test x$ac_cv_type_long_double = xno; then
snv_long_double=double
else
snv_long_double='long double'
fi]
AC_DEFINE_UNQUOTED([SNV_LONG_DOUBLE],$snv_long_double,
[Define this to the long+double type])
AC_CHECK_TYPES([long long, uintmax_t, size_t, wchar_t])
AC_CHECK_SIZEOF(char*, 4)
AC_CHECK_SIZEOF(int, 4)
AC_CHECK_SIZEOF(long, 4)
AC_CHECK_SIZEOF(short, 2)
# ----------------------------------------------------------------------
AC_CHECK_FUNCS(strchr strlcpy snprintf dlopen)
AC_SEARCH_LIBS(copysign, [m],
[AC_DEFINE(HAVE_COPYSIGN, 1,
[Define to 1 if you have the `copysign' function.])])
AC_SEARCH_LIBS(copysignl, [m],
[AC_DEFINE(HAVE_COPYSIGNL, 1,
[Define to 1 if you have the `copysignl' function.])])
AC_SEARCH_LIBS(modfl, [m],
[AC_DEFINE(HAVE_MODFL, 1,
[Define to 1 if you have the `modfl' function.])])
# ----------------------------------------------------------------------
# Check for the functions needed from libgen and libdl
# ----------------------------------------------------------------------
AM_CONDITIONAL([NEED_PATHFIND], [test X$ac_cv_func_pathfind = Xyes])
[if test X$ac_cv_func_dlopen = Xyes
then DYNAMIC_AG=-export-dynamic
else DYNAMIC_AG=""
fi]
AC_SUBST(DYNAMIC_AG)
# ----------------------------------------------------------------------
# Do all our own macros
# ----------------------------------------------------------------------
INVOKE_AG_MACROS
[
if ! test x$ag_cv_sys_siglist = xyes
then
if ! test x$ac_cv_func_strsignal = xyes
then
echo "WARNING: strsignal will use POSIX names and Linux signal numbers"
fi
fi >&2
if test "X${ag_cv_link_sigsetjmp}" = Xno
then]
AC_MSG_ERROR([AutoGen requires sigsetjmp(3)])[
fi
]
# ----------------------------------------------------------------------
# Do SNPRINTFV macros
# ----------------------------------------------------------------------
INVOKE_SNPRINTFV_MACROS
# ----------------------------------------------------------------------
# Generate the make files.
# ----------------------------------------------------------------------
AC_PROG_LN_S
[
test -f ./snprintfv/snprintfv/snprintfv.h \
&& rm -f ./snprintfv/snprintfv.h \
&& ${LN_S} `pwd`/snprintfv/snprintfv/snprintfv.h ./snprintfv/
AGnam=autogen${ac_exeext}
GDnam=getdefs${ac_exeext}
CLnam=columns${ac_exeext}
AGexe=${ag_top_builddir}/agen5/${AGnam}
GDexe=${ag_top_builddir}/getdefs/${GDnam}
CLexe=${ag_top_builddir}/columns/${CLnam}
M4_SRC=`cd $srcdir/config ; echo [a-z]*.m4`
ENABLE_STATIC=${enable_static}
config_end_time=`date +%s 2>/dev/null`
time_delta=`expr ${config_end_time} - ${config_start_time} 2>/dev/null`
if test -z "${time_delta}"
then time_delta=10
elif test ${time_delta} -lt 5
then time_delta=5 ; fi
AG_TIMEOUT=${time_delta}
]
AC_DEFINE_UNQUOTED(AG_DEFAULT_TIMEOUT, ${time_delta},
[define to suitable timeout limit for shell command])
AC_SUBST(M4_SRC)
AC_SUBST(AGnam)
AC_SUBST(GDnam)
AC_SUBST(CLnam)
AC_SUBST(AGexe)
AC_SUBST(GDexe)
AC_SUBST(CLexe)
AC_SUBST(AG_TIMEOUT)
AC_SUBST(ac_aux_dir)
AC_SUBST(LIBS)
AC_SUBST(DEBUG_ENABLED)
AC_SUBST(ENABLE_STATIC)
[
if test "$ag_top_srcdir" = "$ag_top_builddir"
then
INCLIST='-I${top_builddir} -I${top_srcdir}/autoopts'
else
INCLIST='-I${top_builddir} -I${top_srcdir}'
INCLIST="${INCLIST} -I\${top_builddir}/autoopts -I\${top_srcdir}/autoopts"
fi
]
AC_SUBST(INCLIST)
[
test ${GUILE_VERSION} -ge 108000 \
-a "X${WERROR}" = Xyes \
-a "X${GCC}" = Xyes && \
CFLAGS=`echo $CFLAGS -Wall -Werror -Wcast-align -Wmissing-prototypes \
-Wpointer-arith -Wshadow -Wstrict-prototypes -Wwrite-strings \
-Wno-format-contains-nul -fno-strict-aliasing -Wstrict-aliasing=2 `
]
AM_CONFIG_HEADER(config.h:config-h.in)
AH_TOP([#ifndef AUTOGEN_CONFIG_H])
AH_TOP([#define AUTOGEN_CONFIG_H 1])
AH_BOTTOM([#endif /* AUTOGEN_CONFIG_H */])
AC_CONFIG_FILES([autoopts/mk-autoopts-pc],
[chmod +x autoopts/mk-autoopts-pc])
AC_CONFIG_FILES([autoopts/autoopts-config],
[chmod +x autoopts/autoopts-config])
AC_CONFIG_FILES([autoopts/tpl/tpl-config.tlib:autoopts/tpl/tpl-config-tlib.in])
AC_CONFIG_FILES([doc/auto_gen.tpl:doc/auto_gen-tpl.in])
AC_CONFIG_FILES([
autoopts/test/defs config/mk-shdefs pkg/pkg-env
Makefile agen5/Makefile agen5/test/Makefile
autoopts/Makefile autoopts/test/Makefile columns/Makefile
compat/Makefile doc/Makefile getdefs/Makefile
getdefs/test/Makefile pkg/Makefile snprintfv/Makefile
xml2ag/Makefile xml2ag/test/Makefile])
AC_CONFIG_COMMANDS([stamp-h],
[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])
[CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}]
AC_SUBST(CONFIG_SHELL)
AC_DEFINE_UNQUOTED(CONFIG_SHELL,$CONFIG_SHELL,
[Define this to a working Bourne shell])
AC_OUTPUT
echo \
"------------------------------------------------------------------------
Configuration:
Source code location: ${srcdir}
Compiler: ${CC}
Compiler flags: ${CFLAGS}
Host System Type: ${host}
Install path: ${prefix}
See config.h for further configuration information.
------------------------------------------------------------------------"
|
