blob: 156740f80be56841ddbf9945cfb657db5701b04f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
/* valaswitchsection.vala
*
* Copyright (C) 2006-2010 Jürg Billeter
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Jürg Billeter <j@bitron.ch>
*/
using GLib;
/**
* Represents a switch section in the source code.
*/
public class Vala.SwitchSection : Block {
private List<SwitchLabel> labels = new ArrayList<SwitchLabel> ();
/**
* Creates a new switch section.
*
* @param source_reference reference to source code
* @return newly created switch section
*/
public SwitchSection (SourceReference? source_reference) {
base (source_reference);
}
/**
* Appends the specified label to the list of switch labels.
*
* @param label a switch label
*/
public void add_label (SwitchLabel label) {
if (labels.size == 0) {
this.source_reference = label.source_reference;
}
labels.add (label);
label.section = this;
}
/**
* Returns a copy of the list of switch labels.
*
* @return switch label list
*/
public List<SwitchLabel> get_labels () {
return labels;
}
public bool has_default_label () {
foreach (SwitchLabel label in labels) {
if (label.expression == null) {
return true;
}
}
return false;
}
public override void accept (CodeVisitor visitor) {
visitor.visit_switch_section (this);
}
public override void accept_children (CodeVisitor visitor) {
foreach (SwitchLabel label in labels) {
label.accept (visitor);
}
foreach (Statement st in get_statements ()) {
st.accept (visitor);
}
}
public override bool check (CodeContext context) {
if (checked) {
return !error;
}
checked = true;
foreach (SwitchLabel label in get_labels ()) {
label.check (context);
}
owner = context.analyzer.current_symbol.scope;
var old_symbol = context.analyzer.current_symbol;
var old_insert_block = context.analyzer.insert_block;
context.analyzer.current_symbol = this;
context.analyzer.insert_block = this;
foreach (Statement st in get_statements ()) {
st.check (context);
}
foreach (LocalVariable local in get_local_variables ()) {
local.active = false;
}
// use get_statements () instead of statement_list to not miss errors within StatementList objects
foreach (Statement stmt in get_statements ()) {
add_error_types (stmt.get_error_types ());
}
context.analyzer.current_symbol = old_symbol;
context.analyzer.insert_block = old_insert_block;
return !error;
}
public override void emit (CodeGenerator codegen) {
foreach (SwitchLabel label in labels) {
label.emit (codegen);
}
base.emit (codegen);
}
}
|
