1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
|
/* valareport.vala
*
* Copyright (C) 2006-2010 Jürg Billeter
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Jürg Billeter <j@bitron.ch>
*/
using GLib;
/**
* Namespace to centralize reporting warnings and errors.
*/
public class Vala.Report : Object {
int warnings;
int errors;
bool verbose_errors;
public bool enable_warnings { get; set; default = true; }
/**
* Set the error verbosity.
*/
public void set_verbose_errors (bool verbose) {
verbose_errors = verbose;
}
/**
* Returns the total number of warnings reported.
*/
public int get_warnings () {
return warnings;
}
/**
* Returns the total number of errors reported.
*/
public int get_errors () {
return errors;
}
/**
* Pretty-print the actual line of offending code if possible.
*/
static void report_source (SourceReference source) {
if (source.first_line != source.last_line) {
// FIXME Cannot report multi-line issues currently
return;
}
string offending_line = source.file.get_source_line (source.first_line);
if (offending_line != null) {
stderr.printf ("%s\n", offending_line);
int idx;
/* We loop in this manner so that we don't fall over on differing
* tab widths. This means we get the ^s in the right places.
*/
for (idx = 1; idx < source.first_column; ++idx) {
if (offending_line[idx - 1] == '\t') {
stderr.printf ("\t");
} else {
stderr.printf (" ");
}
}
for (idx = source.first_column; idx <= source.last_column; ++idx) {
if (offending_line[idx - 1] == '\t') {
stderr.printf ("\t");
} else {
stderr.printf ("^");
}
}
stderr.printf ("\n");
}
}
/**
* Reports the specified message as note.
*
* @param source reference to source code
* @param message note message
*/
public virtual void note (SourceReference? source, string message) {
if (!enable_warnings) {
return;
}
if (source == null) {
stderr.printf ("note: %s\n", message);
} else {
stderr.printf ("%s: note: %s\n", source.to_string (), message);
if (verbose_errors) {
report_source (source);
}
}
}
/**
* Reports the specified message as warning.
*
* @param source reference to source code
* @param message warning message
*/
public virtual void warn (SourceReference? source, string message) {
if (!enable_warnings) {
return;
}
warnings++;
if (source == null) {
stderr.printf ("warning: %s\n", message);
} else {
stderr.printf ("%s: warning: %s\n", source.to_string (), message);
if (verbose_errors) {
report_source (source);
}
}
}
/**
* Reports the specified message as error.
*
* @param source reference to source code
* @param message error message
*/
public virtual void err (SourceReference? source, string message) {
errors++;
if (source == null) {
stderr.printf ("error: %s\n", message);
} else {
stderr.printf ("%s: error: %s\n", source.to_string (), message);
if (verbose_errors) {
report_source (source);
}
}
}
/* Convenience methods calling warn and err on correct instance */
public static void notice (SourceReference? source, string message) {
CodeContext.get ().report.note (source, message);
}
public static void warning (SourceReference? source, string message) {
CodeContext.get ().report.warn (source, message);
}
public static void error (SourceReference? source, string message) {
CodeContext.get ().report.err (source, message);
}
}
|
