1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
|
/* valaelementaccess.vala
*
* Copyright (C) 2006-2009 Jürg Billeter
* Copyright (C) 2006-2008 Raffaele Sandrini
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Raffaele Sandrini <raffaele@sandrini.ch>
* Jürg Billeter <j@bitron.ch>
*/
using GLib;
/**
* Represents an array access expression e.g. "a[1,2]".
*/
public class Vala.ElementAccess : Expression {
/**
* Expression representing the container on wich we want to access.
*/
public Expression container {
get {
return _container;
}
set {
_container = value;
_container.parent_node = this;
}
}
/**
* Expressions representing the indices we want to access inside the container.
*/
private List<Expression> indices = new ArrayList<Expression> ();
Expression _container;
public void append_index (Expression index) {
indices.add (index);
index.parent_node = this;
}
public List<Expression> get_indices () {
return new ReadOnlyList<Expression> (indices);
}
public ElementAccess (Expression container, SourceReference source_reference) {
this.source_reference = source_reference;
this.container = container;
}
public override void accept (CodeVisitor visitor) {
visitor.visit_element_access (this);
visitor.visit_expression (this);
}
public override void accept_children (CodeVisitor visitor) {
container.accept (visitor);
foreach (Expression e in indices) {
e.accept (visitor);
}
}
public override void replace_expression (Expression old_node, Expression new_node) {
if (container == old_node) {
container = new_node;
}
int index = indices.index_of (old_node);
if (index >= 0 && new_node.parent_node == null) {
indices[index] = new_node;
new_node.parent_node = this;
}
}
public override bool is_pure () {
foreach (Expression index in indices) {
if (!index.is_pure ()) {
return false;
}
}
return container.is_pure ();
}
public override bool check (SemanticAnalyzer analyzer) {
if (checked) {
return !error;
}
checked = true;
if (!container.check (analyzer)) {
/* don't proceed if a child expression failed */
error = true;
return false;
}
if (container.value_type == null) {
error = true;
Report.error (container.source_reference, "Invalid container expression");
return false;
}
var container_type = container.value_type.data_type;
if (container is MemberAccess && container.symbol_reference is Signal) {
// signal detail access
if (get_indices ().size != 1) {
error = true;
Report.error (source_reference, "Element access with more than one dimension is not supported for signals");
return false;
}
get_indices ().get (0).target_type = analyzer.string_type.copy ();
}
foreach (Expression index in get_indices ()) {
index.check (analyzer);
}
bool index_int_type_check = true;
var pointer_type = container.value_type as PointerType;
/* assign a value_type when possible */
if (container.value_type is ArrayType) {
var array_type = (ArrayType) container.value_type;
value_type = array_type.element_type.copy ();
if (!lvalue) {
value_type.value_owned = false;
}
} else if (pointer_type != null && !pointer_type.base_type.is_reference_type_or_type_parameter ()) {
value_type = pointer_type.base_type.copy ();
} else if (container_type == analyzer.string_type.data_type) {
if (get_indices ().size != 1) {
error = true;
Report.error (source_reference, "Element access with more than one dimension is not supported for strings");
return false;
}
value_type = analyzer.unichar_type;
} else if (container is MemberAccess && container.symbol_reference is Signal) {
index_int_type_check = false;
symbol_reference = container.symbol_reference;
value_type = container.value_type;
} else {
if (lvalue) {
var set_method = container.value_type.get_member ("set") as Method;
var assignment = parent_node as Assignment;
if (set_method != null && assignment != null) {
return !error;
}
} else {
var get_method = container.value_type.get_member ("get") as Method;
if (get_method != null) {
var get_call = new MethodCall (new MemberAccess (container, "get"));
foreach (Expression e in get_indices ()) {
get_call.add_argument (e);
}
get_call.target_type = this.target_type;
parent_node.replace_expression (this, get_call);
return get_call.check (analyzer);
}
}
error = true;
Report.error (source_reference, "The expression `%s' does not denote an array".printf (container.value_type.to_string ()));
}
if (index_int_type_check) {
/* check if the index is of type integer */
foreach (Expression e in get_indices ()) {
/* don't proceed if a child expression failed */
if (e.value_type == null) {
return false;
}
/* check if the index is of type integer */
if (!(e.value_type is IntegerType || e.value_type is EnumValueType)) {
error = true;
Report.error (e.source_reference, "Expression of integer type expected");
}
}
}
return !error;
}
public override void get_defined_variables (Collection<LocalVariable> collection) {
container.get_defined_variables (collection);
foreach (Expression index in indices) {
index.get_defined_variables (collection);
}
}
public override void get_used_variables (Collection<LocalVariable> collection) {
container.get_used_variables (collection);
foreach (Expression index in indices) {
index.get_used_variables (collection);
}
}
}
|