1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
|
/* valacatchclause.vala
*
* Copyright (C) 2007-2010 Jürg Billeter
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Jürg Billeter <j@bitron.ch>
*/
/**
* Represents a catch clause in a try statement in the source code.
*/
public class Vala.CatchClause : CodeNode {
/**
* Specifies the error type.
*/
public DataType? error_type {
get { return _data_type; }
set {
_data_type = value;
if (_data_type != null) {
_data_type.parent_node = this;
}
}
}
/**
* Specifies the error variable name.
*/
public string? variable_name { get; set; }
/**
* Specifies the error handler body.
*/
public Block body {
get { return _body; }
set {
_body = value;
_body.parent_node = this;
}
}
/**
* Specifies the declarator for the generated error variable.
*/
public LocalVariable error_variable {
get { return _error_variable; }
set {
_error_variable = value;
_error_variable.parent_node = this;
}
}
/**
* Specifies the label used for this catch clause in the C code.
*/
public string? clabel_name { get; set; }
private DataType _data_type;
private Block _body;
private LocalVariable _error_variable;
/**
* Creates a new catch
*
* @param error_type error type
* @param variable_name error variable name
* @param body error handler body
* @param source_reference reference to source code
* @return newly created catch clause
*/
public CatchClause (DataType? error_type, string? variable_name, Block body, SourceReference? source_reference = null) {
this.error_type = error_type;
this.variable_name = variable_name;
this.body = body;
this.source_reference = source_reference;
}
public override void accept (CodeVisitor visitor) {
visitor.visit_catch_clause (this);
}
public override void accept_children (CodeVisitor visitor) {
if (error_type != null) {
error_type.accept (visitor);
}
body.accept (visitor);
}
public override void replace_type (DataType old_type, DataType new_type) {
if (error_type == old_type) {
error_type = new_type;
}
}
public override bool check (CodeContext context) {
if (checked) {
return !error;
}
checked = true;
if (error_type != null) {
if (!(error_type is ErrorType)) {
Report.error (source_reference, "clause must catch a valid error type, found `%s' instead".printf (error_type.to_string ()));
error = true;
}
if (variable_name != null) {
error_variable = new LocalVariable (error_type.copy (), variable_name);
body.scope.add (variable_name, error_variable);
body.add_local_variable (error_variable);
error_variable.checked = true;
}
} else {
// generic catch clause
error_type = new ErrorType (null, null, source_reference);
}
error_type.check (context);
body.check (context);
return !error;
}
public override void emit (CodeGenerator codegen) {
if (error_variable != null) {
error_variable.active = true;
}
codegen.visit_catch_clause (this);
}
public override void get_defined_variables (Collection<Variable> collection) {
if (error_variable != null) {
collection.add (error_variable);
}
}
}
|
