Add a check for PCRE library to configure.

We use standard AX_PATH_GENERIC() macro from Autoconf archive to do the check
to keep our own code as simple as possible. Notice that this script must be
used, just adding the include and library directories to {C,LD}FLAGS is not
enough, notably -DPCRE_STATIC which is output by pcre-config for static builds
only is crucial. Also use LIBS instead of LDFLAGS to fix linking when using
static libraries.

Also note that this allows to pass PCRE_CONFIG variable value to configure to
force the use of the specified script (and not the one first found in PATH),
which is especially important when cross-compiling.

Finally, PCRE is required by default now, --without-pcre must be explicitly
used to build without it.

git-svn-id: https://swig.svn.sourceforge.net/svnroot/swig/trunk@12169 626c5289-ae23-0410-ae9c-e8d60b6d4f22

2 files changed, 319 insertions, 0 deletions

diff --git a/Tools/config/ax_compare_version.m4 b/Tools/config/ax_compare_version.m4
new file mode 100644
index 000000000..74dc0fdd9
--- /dev/null
+++ b/Tools/config/ax_compare_version.m4
@@ -0,0 +1,177 @@
+# ===========================================================================
+#    http://www.gnu.org/software/autoconf-archive/ax_compare_version.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+#
+# DESCRIPTION
+#
+#   This macro compares two version strings. Due to the various number of
+#   minor-version numbers that can exist, and the fact that string
+#   comparisons are not compatible with numeric comparisons, this is not
+#   necessarily trivial to do in a autoconf script. This macro makes doing
+#   these comparisons easy.
+#
+#   The six basic comparisons are available, as well as checking equality
+#   limited to a certain number of minor-version levels.
+#
+#   The operator OP determines what type of comparison to do, and can be one
+#   of:
+#
+#    eq  - equal (test A == B)
+#    ne  - not equal (test A != B)
+#    le  - less than or equal (test A <= B)
+#    ge  - greater than or equal (test A >= B)
+#    lt  - less than (test A < B)
+#    gt  - greater than (test A > B)
+#
+#   Additionally, the eq and ne operator can have a number after it to limit
+#   the test to that number of minor versions.
+#
+#    eq0 - equal up to the length of the shorter version
+#    ne0 - not equal up to the length of the shorter version
+#    eqN - equal up to N sub-version levels
+#    neN - not equal up to N sub-version levels
+#
+#   When the condition is true, shell commands ACTION-IF-TRUE are run,
+#   otherwise shell commands ACTION-IF-FALSE are run. The environment
+#   variable 'ax_compare_version' is always set to either 'true' or 'false'
+#   as well.
+#
+#   Examples:
+#
+#     AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
+#
+#   would both be true.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
+#
+#   would both be false.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
+#
+#   would be true because it is only comparing two minor versions.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
+#
+#   would be true because it is only comparing the lesser number of minor
+#   versions of the two values.
+#
+#   Note: The characters that separate the version numbers do not matter. An
+#   empty string is the same as version 0. OP is evaluated by autoconf, not
+#   configure, so must be a string, not a variable.
+#
+#   The author would like to acknowledge Guido Draheim whose advice about
+#   the m4_case and m4_ifvaln functions make this macro only include the
+#   portions necessary to perform the specific comparison specified by the
+#   OP argument in the final configure script.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Tim Toolan <toolan@ele.uri.edu>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 11
+
+dnl #########################################################################
+AC_DEFUN([AX_COMPARE_VERSION], [
+  AC_REQUIRE([AC_PROG_AWK])
+
+  # Used to indicate true or false condition
+  ax_compare_version=false
+
+  # Convert the two version strings to be compared into a format that
+  # allows a simple string comparison.  The end result is that a version
+  # string of the form 1.12.5-r617 will be converted to the form
+  # 0001001200050617.  In other words, each number is zero padded to four
+  # digits, and non digits are removed.
+  AS_VAR_PUSHDEF([A],[ax_compare_version_A])
+  A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  AS_VAR_PUSHDEF([B],[ax_compare_version_B])
+  B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
+  dnl # then the first line is used to determine if the condition is true.
+  dnl # The sed right after the echo is to remove any indented white space.
+  m4_case(m4_tolower($2),
+  [lt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [gt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [le],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],
+  [ge],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],[
+    dnl Split the operator from the subversion count if present.
+    m4_bmatch(m4_substr($2,2),
+    [0],[
+      # A count of zero means use the length of the shorter version.
+      # Determine the number of characters in A and B.
+      ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'`
+      ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'`
+
+      # Set A to no more than B's length and B to no more than A's length.
+      A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
+    ],
+    [[0-9]+],[
+      # A count greater than zero means use only that many subversions
+      A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+    ],
+    [.+],[
+      AC_WARNING(
+        [illegal OP numeric parameter: $2])
+    ],[])
+
+    # Pad zeros at end of numbers to make same length.
+    ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
+    B="$B`echo $A | sed 's/./0/g'`"
+    A="$ax_compare_version_tmp_A"
+
+    # Check for equality or inequality as necessary.
+    m4_case(m4_tolower(m4_substr($2,0,2)),
+    [eq],[
+      test "x$A" = "x$B" && ax_compare_version=true
+    ],
+    [ne],[
+      test "x$A" != "x$B" && ax_compare_version=true
+    ],[
+      AC_WARNING([illegal OP parameter: $2])
+    ])
+  ])
+
+  AS_VAR_POPDEF([A])dnl
+  AS_VAR_POPDEF([B])dnl
+
+  dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
+  if test "$ax_compare_version" = "true" ; then
+    m4_ifvaln([$4],[$4],[:])dnl
+    m4_ifvaln([$5],[else $5])dnl
+  fi
+]) dnl AX_COMPARE_VERSION
diff --git a/Tools/config/ax_path_generic.m4 b/Tools/config/ax_path_generic.m4
new file mode 100644
index 000000000..4db2da11b
--- /dev/null
+++ b/Tools/config/ax_path_generic.m4
@@ -0,0 +1,142 @@
+# ===========================================================================
+#      http://www.gnu.org/software/autoconf-archive/ax_path_generic.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_PATH_GENERIC(LIBRARY,[MINIMUM-VERSION,[SED-EXPR-EXTRACTOR]],[ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND],[CONFIG-SCRIPTS],[CFLAGS-ARG],[LIBS-ARG])
+#
+# DESCRIPTION
+#
+#   Runs the LIBRARY-config script and defines LIBRARY_CFLAGS and
+#   LIBRARY_LIBS
+#
+#   The script must support `--cflags' and `--libs' args. If MINIMUM-VERSION
+#   is specified, the script must also support the `--version' arg. If the
+#   `--with-library-[exec-]prefix' arguments to ./configure are given, it
+#   must also support `--prefix' and `--exec-prefix'. Prefereable use
+#   CONFIG-SCRIPTS as config script, CFLAGS-ARG instead of `--cflags` and
+#   LIBS-ARG instead of `--libs`, if given.
+#
+#   The SED-EXPR-EXTRACTOR parameter representes the expression used in sed
+#   to extract the version number. Use it if your 'foo-config --version'
+#   dumps something like 'Foo library v1.0.0 (alfa)' instead of '1.0.0'.
+#
+#   Example:
+#
+#     AX_PATH_GENERIC(Foo, 1.0.0)
+#
+#   would run `foo-config --version' and check that it is at least 1.0.0, if
+#   successful the following variables would be defined and substituted:
+#
+#     FOO_CFLAGS to `foo-config --cflags`
+#     FOO_LIBS   to `foo-config --libs`
+#
+#   Example:
+#
+#     AX_PATH_GENERIC([Bar],,,[
+#        AC_MSG_ERROR([Cannot find Bar library])
+#     ])
+#
+#   would check for bar-config program, defining and substituting the
+#   following variables:
+#
+#     BAR_CFLAGS to `bar-config --cflags`
+#     BAR_LIBS   to `bar-config --libs`
+#
+#   This macro is a rearranged version of AC_PATH_GENERIC from Angus Lees.
+#
+# LICENSE
+#
+#   Copyright (c) 2009 Francesco Salvestrini <salvestrini@users.sourceforge.net>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 10
+
+AU_ALIAS([AC_PATH_GENERIC], [AX_PATH_GENERIC])
+AC_DEFUN([AX_PATH_GENERIC],[
+  AC_REQUIRE([AC_PROG_SED])
+
+  dnl we're going to need uppercase and lowercase versions of the
+  dnl string `LIBRARY'
+  pushdef([UP],   translit([$1], [a-z], [A-Z]))dnl
+  pushdef([DOWN], translit([$1], [A-Z], [a-z]))dnl
+
+  AC_ARG_WITH(DOWN-prefix,[AS_HELP_STRING([--with-]DOWN[-prefix=PREFIX], [Prefix where $1 is installed (optional)])],
+    DOWN[]_config_prefix="$withval", DOWN[]_config_prefix="")
+  AC_ARG_WITH(DOWN-exec-prefix,[AS_HELP_STRING([--with-]DOWN[-exec-prefix=EPREFIX], [Exec prefix where $1 is installed (optional)])],
+    DOWN[]_config_exec_prefix="$withval", DOWN[]_config_exec_prefix="")
+
+  AC_ARG_VAR(UP[]_CONFIG, [config script used for $1])
+  AC_ARG_VAR(UP[]_CFLAGS, [CFLAGS used for $1])
+  AC_ARG_VAR(UP[]_LIBS,   [LIBS used for $1])
+
+  AS_IF([test x$DOWN[]_config_exec_prefix != x],[
+    DOWN[]_config_args="$DOWN[]_config_args --exec-prefix=$DOWN[]_config_exec_prefix"
+    AS_IF([test x${UP[]_CONFIG+set} != xset],[
+      UP[]_CONFIG=$DOWN[]_config_exec_prefix/bin/DOWN-config
+    ])
+  ])
+  AS_IF([test x$DOWN[]_config_prefix != x],[
+    DOWN[]_config_args="$DOWN[]_config_args --prefix=$DOWN[]_config_prefix"
+    AS_IF([test x${UP[]_CONFIG+set} != xset],[
+      UP[]_CONFIG=$DOWN[]_config_prefix/bin/DOWN-config
+    ])
+  ])
+
+  AC_PATH_PROGS(UP[]_CONFIG,[$6 DOWN-config],[no])
+  AS_IF([test "$UP[]_CONFIG" == "no"],[
+    :
+    $5
+  ],[
+    dnl Get the CFLAGS from LIBRARY-config script
+    AS_IF([test x"$7" == x],[
+      UP[]_CFLAGS="`$UP[]_CONFIG $DOWN[]_config_args --cflags`"
+    ],[
+      UP[]_CFLAGS="`$UP[]_CONFIG $DOWN[]_config_args $7`"
+    ])
+
+    dnl Get the LIBS from LIBRARY-config script
+    AS_IF([test x"$8" == x],[
+      UP[]_LIBS="`$UP[]_CONFIG $DOWN[]_config_args --libs`"
+    ],[
+      UP[]_LIBS="`$UP[]_CONFIG $DOWN[]_config_args $8`"
+    ])
+
+    AS_IF([test x"$2" != x],[
+      dnl Check for provided library version
+      AS_IF([test x"$3" != x],[
+        dnl Use provided sed expression
+        DOWN[]_version="`$UP[]_CONFIG $DOWN[]_config_args --version | $SED -e $3`"
+      ],[
+        DOWN[]_version="`$UP[]_CONFIG $DOWN[]_config_args --version | $SED -e 's/^\ *\(.*\)\ *$/\1/'`"
+      ])
+
+      AC_MSG_CHECKING([for $1 ($DOWN[]_version) >= $2])
+      AX_COMPARE_VERSION($DOWN[]_version,[ge],[$2],[
+        AC_MSG_RESULT([yes])
+
+        AC_SUBST(UP[]_CFLAGS)
+        AC_SUBST(UP[]_LIBS)
+        :
+        $4
+      ],[
+        AC_MSG_RESULT([no])
+        :
+        $5
+      ])
+    ],[
+      AC_SUBST(UP[]_CFLAGS)
+      AC_SUBST(UP[]_LIBS)
+      :
+      $4
+    ])
+  ])
+
+  popdef([UP])
+  popdef([DOWN])
+])