blob: f836f3ce4a8a04c3ffcb4a4fa31850ed9d214877 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# -------------------------------------------------------------------
# This file contains shared rules used both when building WTF itself
# and for targets that depend in some way on WTF.
#
# See 'Tools/qmake/README' for an overview of the build system
# -------------------------------------------------------------------
# All external modules should include WTF headers by prefixing with "wtf" (#include <wtf/some/thing.h>).
INCLUDEPATH += $$PWD
mac {
# Mac OS does ship libicu but not the associated header files.
# Therefore WebKit provides adequate header files.
INCLUDEPATH += $${ROOT_WEBKIT_DIR}/Source/WTF/icu
LIBS += -licucore
} else {
contains(QT_CONFIG,icu) {
win32: LIBS += -licuin -licuuc -licudt
else: LIBS += -licui18n -licuuc -licudata
} else {
error("To build QtWebKit with Qt 5 you need to build Qt 5 with libICU support. Check for ICU support being mentioned in qtbase/config.summary.")
}
}
linux-*:use?(GSTREAMER) {
DEFINES += ENABLE_GLIB_SUPPORT=1
PKGCONFIG += glib-2.0 gio-2.0
}
win32-* {
LIBS += -lwinmm
LIBS += -lgdi32
}
qnx {
# required for timegm
LIBS += -lnbutil
}
mac {
LIBS += -framework AppKit
}
|
