chromium/chrome/browser/resources/md_extensions/BUILD.gn


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

import("../optimize_webui.gni")
import("//tools/grit/grit_rule.gni")
import("//chrome/common/features.gni")

extensions_pak_file = "extensions_resources.pak"
unpak_folder = "extensions_resources.unpak"

optimize_webui("build") {
  host = "extensions"
  html_in_files = [ "extensions.html" ]
  html_out_files = [ "vulcanized.html" ]
  insert_in_head = "<base href=\"chrome://extensions\">"
  input = rebase_path("$target_gen_dir/$unpak_folder", root_build_dir)
  js_out_files = [ "crisper.js" ]

  deps = [
    ":unpak",
  ]
}

unpak("unpak") {
  pak_file = extensions_pak_file
  out_folder = unpak_folder

  deps = [
    ":flattened_resources",
  ]
}

grit("flattened_resources") {
  source = "extensions_resources.grd"

  # The .grd contains references to generated files.
  source_is_generated = true

  defines = chrome_grit_defines
  outputs = [
    "grit/extensions_resources.h",
    "grit/extensions_resources_map.cc",
    "grit/extensions_resources_map.h",
    extensions_pak_file,
  ]
  output_dir = "$root_gen_dir/chrome/browser/resources/md_extensions"
}