Add all gn, gni, typemap, mojom files

These file are required to gn be able to parse
source tree.

Change-Id: I9cb4a0b3897c1e99dd6e39832a8c55764fb6e1c6
Reviewed-by: Allan Sandfeld Jensen <allan.jensen@qt.io>

3 files changed, 135 insertions, 0 deletions

diff --git a/chromium/tools/perf/BUILD.gn b/chromium/tools/perf/BUILD.gn
new file mode 100644
index 00000000000..333907bafd5
--- /dev/null
+++ b/chromium/tools/perf/BUILD.gn
@@ -0,0 +1,27 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+group("perf") {
+  testonly = true
+  deps = [
+    "//tools/perf/chrome_telemetry_build:telemetry_chrome_test",
+  ]
+
+  data = [
+    "//tools/perf/",
+
+    # Field trial config
+    "//tools/variations/",
+    "//testing/variations/",
+  ]
+}
+
+if (is_android) {
+  import("//build/config/android/rules.gni")
+
+  wrapper_script("run_benchmark_wrapper") {
+    target = "run_benchmark"
+    flag_name = "--chromium-output-directory"
+  }
+}
diff --git a/chromium/tools/perf/chrome_telemetry_build/BUILD.gn b/chromium/tools/perf/chrome_telemetry_build/BUILD.gn
new file mode 100644
index 00000000000..d5663bd6728
--- /dev/null
+++ b/chromium/tools/perf/chrome_telemetry_build/BUILD.gn
@@ -0,0 +1,90 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/compiler/compiler.gni")
+
+if (is_win) {
+  action("copy_cdb_to_output") {
+    script = "//build/win/copy_cdb_to_output.py"
+    inputs = [
+      script,
+    ]
+    outputs = [
+      "$root_out_dir/cdb/cdb.exe",
+      "$root_out_dir/cdb/dbgeng.dll",
+      "$root_out_dir/cdb/dbghelp.dll",
+      "$root_out_dir/cdb/dbgmodel.dll",
+      "$root_out_dir/cdb/winext/ext.dll",
+      "$root_out_dir/cdb/winext/uext.dll",
+      "$root_out_dir/cdb/winxp/exts.dll",
+      "$root_out_dir/cdb/winxp/ntsdexts.dll",
+    ]
+    args = [
+      rebase_path("$root_out_dir/cdb", root_out_dir),
+      current_cpu,
+    ]
+  }
+}
+
+group("telemetry_chrome_test") {
+  testonly = true
+
+  if (is_android) {
+    data_deps = [
+      "//chrome/android:chrome_public_apk",
+    ]
+  } else {
+    data_deps = [
+      "//third_party/catapult/telemetry:bitmaptools",
+    ]
+
+    data_deps += [ "//chrome" ]
+  }
+
+  data = [
+    "//tools/perf/chrome_telemetry_build/",
+    "//third_party/catapult/",
+    "//components/crash/content/tools/generate_breakpad_symbols.py",
+  ]
+
+  if (is_win) {
+    data_deps += [ "//chrome:reorder_imports" ]
+  }
+
+  if (is_linux) {
+    data_deps += [
+      "//tools/xdisplaycheck",
+      "//breakpad:dump_syms($host_toolchain)",
+    ]
+  }
+
+  if (is_mac) {
+    data_deps += [
+      "//breakpad:dump_syms",
+      "//chrome:chrome_framework",
+      "//chrome:chrome_helper_app",
+      "//third_party/crashpad/crashpad/tools:crashpad_database_util",
+    ]
+  }
+
+  if (is_win && (symbol_level == 1 || symbol_level == 2)) {
+    data_deps += [
+      ":copy_cdb_to_output",
+      "//third_party/crashpad/crashpad/tools:crashpad_database_util",
+    ]
+
+    # TODO(GYP): These should be provided automatically through data_deps.
+    data += [ "$root_out_dir/chrome.exe.pdb" ]
+    if (is_component_build) {
+      data += [
+        "$root_out_dir/base.dll.pdb",
+        "$root_out_dir/blink_platform.dll.pdb",
+        "$root_out_dir/blink_web.dll.pdb",
+        "$root_out_dir/content.dll.pdb",
+      ]
+    } else {
+      data += [ "$root_out_dir/chrome_child.dll.pdb" ]
+    }
+  }
+}
diff --git a/chromium/tools/perf/clear_system_cache/BUILD.gn b/chromium/tools/perf/clear_system_cache/BUILD.gn
new file mode 100644
index 00000000000..3072d32285d
--- /dev/null
+++ b/chromium/tools/perf/clear_system_cache/BUILD.gn
@@ -0,0 +1,18 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+executable("clear_system_cache") {
+  testonly = true
+
+  sources = [
+    "clear_system_cache_main.cc",
+  ]
+
+  deps = [
+    "//base",
+    "//base/test:test_support",
+    "//build/config/sanitizers:deps",
+    "//build/win:default_exe_manifest",
+  ]
+}