Move Styles and Private under controls

Register the C++ private API from the controls plugin. The
private plugin is not needed anymore.

The Controls "submodules" Styles and Private are moved to
the controls subfolder in the sources tree.

Change-Id: I98358227c945b6cd1a8dbff9d07e6cad4f044277
Reviewed-by: J-P Nurmi <jpnurmi@digia.com>

1 files changed, 149 insertions, 0 deletions

diff --git a/src/controls/Private/AbstractCheckable.qml b/src/controls/Private/AbstractCheckable.qml
new file mode 100644
index 00000000..02348b71
--- /dev/null
+++ b/src/controls/Private/AbstractCheckable.qml
@@ -0,0 +1,149 @@
+/****************************************************************************
+**
+** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the Qt Quick Controls module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** You may use this file under the terms of the BSD license as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
+**     of its contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.1
+import QtQuick.Controls 1.0
+
+/*!
+    \qmltype AbstractCheckable
+    \inqmlmodule QtQuick.Controls 1.0
+    \ingroup controls
+    \brief An abstract representation of a checkable control with a label
+    \qmlabstract
+    \internal
+
+    A checkable control is one that has two states: checked (on) and
+    unchecked (off). AbstractCheckable encapsulates the basic behavior and
+    states that are required by checkable controls.
+
+    Examples of checkable controls are RadioButton and
+    CheckBox. CheckBox extends AbstractCheckable's behavior by adding a third
+    state: partially checked.
+*/
+
+Control {
+    id: abstractCheckable
+
+    /*!
+        Emitted whenever the control is clicked.
+    */
+    signal clicked
+
+    /*!
+        \qmlproperty bool AbstractCheckable::pressed
+
+        This property is \c true if the control is being pressed.
+        Set this property to manually invoke a mouse click.
+    */
+    property alias pressed: mouseArea.effectivePressed
+
+    /*! \qmlproperty bool AbstractCheckcable::hovered
+
+        This property indicates whether the control is being hovered.
+    */
+    readonly property alias hovered: mouseArea.containsMouse
+
+    /*!
+        This property is \c true if the control is checked.
+    */
+    property bool checked: false
+
+    /*!
+        This property is \c true if the control takes the focus when it is
+        pressed; \l{QQuickItem::forceActiveFocus()}{forceActiveFocus()} will be
+        called on the control.
+    */
+    property bool activeFocusOnPress: false
+
+    /*!
+        This property stores the ExclusiveGroup that the control belongs to.
+    */
+    property ExclusiveGroup exclusiveGroup: null
+
+    /*!
+        This property holds the text that the label should display.
+    */
+    property string text
+
+    /*! \internal */
+    property var __cycleStatesHandler: cycleRadioButtonStates
+
+    activeFocusOnTab: true
+
+    MouseArea {
+        id: mouseArea
+        focus: true
+        anchors.fill: parent
+        hoverEnabled: true
+        enabled: !keyPressed
+
+        property bool keyPressed: false
+        property bool effectivePressed: pressed && containsMouse || keyPressed
+
+        onClicked: abstractCheckable.clicked();
+
+        onPressed: if (activeFocusOnPress) forceActiveFocus();
+
+        onReleased: {
+            if (containsMouse && (!exclusiveGroup || !checked))
+                __cycleStatesHandler();
+        }
+    }
+
+    /*! \internal */
+    onExclusiveGroupChanged: {
+        if (exclusiveGroup)
+            exclusiveGroup.bindCheckable(abstractCheckable)
+    }
+
+    Keys.onPressed: {
+        if (event.key === Qt.Key_Space && !event.isAutoRepeat && !mouseArea.pressed)
+            mouseArea.keyPressed = true;
+    }
+
+    Keys.onReleased: {
+        if (event.key === Qt.Key_Space && !event.isAutoRepeat && mouseArea.keyPressed) {
+            mouseArea.keyPressed = false;
+            if (!exclusiveGroup || !checked)
+                __cycleStatesHandler();
+            clicked();
+        }
+    }
+}