src/plugins/plugins.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

######################################################################
#
# Qt Multimedia
#
######################################################################

TEMPLATE = subdirs
QT_FOR_CONFIG += multimedia-private

SUBDIRS += m3u

qtHaveModule(quick) {
   SUBDIRS += videonode
}

android {
   SUBDIRS += android opensles
}

qnx {
    qtConfig(mmrenderer): SUBDIRS += qnx
    SUBDIRS += audiocapture
}

qnx {
    SUBDIRS += qnx-audio
}

win32 {
    qtConfig(wasapi): SUBDIRS += wasapi
}

win32:!winrt {
    SUBDIRS += audiocapture \
               windowsaudio

    qtConfig(directshow): SUBDIRS += directshow
    qtConfig(wmf): SUBDIRS += wmf
}


winrt {
    SUBDIRS += winrt \
               audiocapture
}

qtConfig(gstreamer): SUBDIRS += gstreamer

unix:!mac:!android {
    !qtConfig(gstreamer): SUBDIRS += audiocapture

    qtConfig(pulseaudio): SUBDIRS += pulseaudio
    qtConfig(alsa): SUBDIRS += alsa

    # v4l is turned off because it is not supported in Qt 5
    # qtConfig(linux_v4l) {
    #     SUBDIRS += v4l
    # }
}

darwin:!watchos {
    SUBDIRS += audiocapture coreaudio
    qtConfig(avfoundation): SUBDIRS += avfoundation
}

qtConfig(resourcepolicy) {
    SUBDIRS += resourcepolicy
}