blob: 7b6baa5fd17f21b83b569c2a47de49c2d5bb6deb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
requires(qtHaveModule(gui))
load(configure)
qtCompileTest(openal)
win32 {
qtCompileTest(directshow) {
qtCompileTest(wshellitem)
}
qtCompileTest(wmsdk)
qtCompileTest(wmp)
contains(QT_CONFIG, wmf-backend): qtCompileTest(wmf)
qtCompileTest(evr)
} else:mac {
qtCompileTest(avfoundation)
} else:android:!android-no-sdk {
SDK_ROOT = $$(ANDROID_SDK_ROOT)
isEmpty(SDK_ROOT): SDK_ROOT = $$DEFAULT_ANDROID_SDK_ROOT
!exists($$SDK_ROOT/platforms/android-11/android.jar): error("QtMultimedia for Android requires API level 11")
} else:qnx {
qtCompileTest(mmrenderer)
} else {
qtCompileTest(alsa)
qtCompileTest(pulseaudio)
!done_config_gstreamer {
gstver=0.10
!isEmpty(GST_VERSION): gstver=$$GST_VERSION
cache(GST_VERSION, set, gstver);
qtCompileTest(gstreamer) {
qtCompileTest(gstreamer_photography)
qtCompileTest(gstreamer_encodingprofiles)
qtCompileTest(gstreamer_appsrc)
} else {
gstver=1.0
cache(GST_VERSION, set, gstver);
# Force a re-run of the test
CONFIG -= done_config_gstreamer
qtCompileTest(gstreamer) {
qtCompileTest(gstreamer_photography)
qtCompileTest(gstreamer_encodingprofiles)
qtCompileTest(gstreamer_appsrc)
}
}
}
qtCompileTest(resourcepolicy)
qtCompileTest(gpu_vivante)
}
load(qt_parts)
|
