Rename QtMultimediaKit to QtMultimedia.

There are a few legacy bits left in place so it passes CI, and
then qt5.git etc can be updated.

Change-Id: I6b082e50e6958c72fdabc2974992e16d90dafa3a
Reviewed-on: http://codereview.qt-project.org/5368
Reviewed-by: Qt Sanity Bot <qt_sanity_bot@ovi.com>
Reviewed-by: Jonas Rabbe <jonas.rabbe@nokia.com>

1 files changed, 68 insertions, 0 deletions

diff --git a/src/multimediawidgets/multimediawidgets.pro b/src/multimediawidgets/multimediawidgets.pro
new file mode 100644
index 000000000..9251f2f71
--- /dev/null
+++ b/src/multimediawidgets/multimediawidgets.pro
@@ -0,0 +1,68 @@
+load(qt_module)
+
+# distinct from QtMultimedia
+TARGET = QtMultimediaWidgets
+QPRO_PWD = $$PWD
+QT = core gui multimedia-private widgets
+
+CONFIG += module no_private_qt_headers_warning
+MODULE_PRI += ../../modules/qt_multimediawidgets.pri
+
+contains(QT_CONFIG, opengl) | contains(QT_CONFIG, opengles2) {
+   QT += opengl
+} else {
+   DEFINES += QT_NO_OPENGL
+}
+
+!static:DEFINES += QT_MAKEDLL
+DEFINES += QT_BUILD_MULTIMEDIAWIDGETS_LIB
+
+load(qt_module_config)
+
+PRIVATE_HEADERS += \
+    qvideowidget_p.h \
+    qpaintervideosurface_p.h \
+
+PUBLIC_HEADERS += \
+    qtmultimediawidgetdefs.h \
+    qtmultimediawidgetsversion.h \
+    qcameraviewfinder.h \
+    qgraphicsvideoitem.h \
+    qvideowidgetcontrol.h \
+    qvideowidget.h \
+    qvideowindowcontrol.h
+
+SOURCES += \
+    qcameraviewfinder.cpp \
+    qpaintervideosurface.cpp \
+    qvideowidgetcontrol.cpp \
+    qvideowidget.cpp \
+    qvideowindowcontrol.cpp \
+
+mac:!qpa {
+!simulator {
+   PRIVATE_HEADERS += qpaintervideosurface_mac_p.h
+   OBJECTIVE_SOURCES += qpaintervideosurface_mac.mm
+}
+   LIBS += -framework AppKit -framework QuartzCore -framework QTKit
+}
+
+maemo6 {
+    isEqual(QT_ARCH,armv6) {
+        PRIVATE_HEADERS += qeglimagetexturesurface_p.h
+        SOURCES += qeglimagetexturesurface.cpp
+
+        SOURCES += qgraphicsvideoitem_maemo6.cpp
+
+        LIBS += -lX11
+    } else {
+        SOURCES += qgraphicsvideoitem.cpp
+    }
+}
+
+!maemo* {
+    SOURCES += qgraphicsvideoitem.cpp
+}
+
+HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS
+