blob: e72eacd66f890eaa7f4e10a41b9802825cc0a3f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
|
TARGET = declarative_location
TARGETPATH = QtLocation
include(qlocationimport.pri)
QT += quick-private network location qml-private 3d core-private gui-private
DESTDIR = $$QT.location.imports/$$TARGETPATH
target.path = $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
INCLUDEPATH += ../../location
INCLUDEPATH += ../../location/maps
INCLUDEPATH *= $$PWD
DEFINES += TOUCH_EVENT_WORKAROUND
LIBS += -L../../3rdparty/poly2tri -lpoly2tri
win32 {
CONFIG(debug, debug|release) {
LIBS += -L../../3rdparty/poly2tri/debug
} else {
LIBS += -L../../3rdparty/poly2tri/release
}
}
# On some platforms, build both versions because debug and release
# versions are incompatible
#win32|mac:!wince*:!win32-msvc:!macx-xcode:CONFIG += debug_and_release
HEADERS += qdeclarativeposition_p.h \
qdeclarativepositionsource_p.h \
qdeclarativecoordinate_p.h \
qdeclarativegeolocation_p.h \
qdeclarativegeomapitemview_p.h \
qdeclarativegeomapmouseevent_p.h \
qdeclarativegeomapmousearea_p.h \
qdeclarativegeoserviceprovider_p.h \
qdeclarativegeoaddress_p.h \
qdeclarativegeoboundingarea_p.h \
qdeclarativegeoboundingbox_p.h \
qdeclarativegeocodemodel_p.h \
qdeclarativegeoroutemodel_p.h \
qdeclarativegeoroute_p.h \
qdeclarativegeoroutesegment_p.h \
qdeclarativegeomaneuver_p.h \
qdeclarativegeoboundingcircle_p.h \
qdeclarativegeomap_p.h \
qdeclarativegeomapflickable_p.h \
qdeclarativegeomappincharea_p.h \
qdeclarativegeomaptype_p.h \
qdeclarativegeomapitembase_p.h \
qdeclarativegeomapquickitem_p.h \
mapnode_p.h \
qdeclarativecirclemapitem_p.h \
qdeclarativerectanglemapitem_p.h \
qdeclarativepolygonmapitem_p.h \
qdeclarativepolylinemapitem_p.h \
qdeclarativeroutemapitem_p.h \
qgeomapitemgeometry_p.h \
qdeclarativegeomapcopyrightsnotice_p.h \
qdeclarativegeomapgesturearea_p.h \
error_messages.h
SOURCES += qdeclarativeposition.cpp \
location.cpp \
qdeclarativepositionsource.cpp \
qdeclarativecoordinate.cpp \
qdeclarativegeolocation.cpp \
qdeclarativegeomapitemview.cpp \
qdeclarativegeomapmouseevent.cpp \
qdeclarativegeomapmousearea.cpp \
qdeclarativegeoserviceprovider.cpp \
qdeclarativegeoaddress.cpp \
qdeclarativegeoboundingarea.cpp \
qdeclarativegeoboundingbox.cpp \
qdeclarativegeocodemodel.cpp \
qdeclarativegeoroutemodel.cpp \
qdeclarativegeoroute.cpp \
qdeclarativegeoroutesegment.cpp \
qdeclarativegeomaneuver.cpp \
qdeclarativegeoboundingcircle.cpp \
qdeclarativegeomap.cpp \
qdeclarativegeomapflickable.cpp \
qdeclarativegeomappincharea.cpp \
qdeclarativegeomaptype.cpp \
qdeclarativegeomapitembase.cpp \
qdeclarativegeomapquickitem.cpp \
mapnode.cpp \
qdeclarativecirclemapitem.cpp \
qdeclarativerectanglemapitem.cpp \
qdeclarativepolygonmapitem.cpp \
qdeclarativepolylinemapitem.cpp \
qdeclarativeroutemapitem.cpp \
qgeomapitemgeometry.cpp \
qdeclarativegeomapcopyrightsnotice.cpp \
qdeclarativegeomapgesturearea.cpp \
error_messages.cpp
include(declarativeplaces/declarativeplaces.pri)
# plugin.qmltypes is used by Qt Creator for syntax highlighting and the QML code model. It needs
# to be regenerated whenever the QML elements exported by the plugin change. This cannot be done
# automatically at compile time because qmlplugindump does not support some QML features and it may
# not be possible when cross-compiling.
#
# To regenerate run 'make qmltypes' which will update the plugins.qmltypes file in the source
# directory. Then review and commit the changes made to plugins.qmltypes.
#
# This will run the following command:
# qmlplugindump <import name> <import version> <path to import plugin> > plugins.qmltypes
# e.g.:
# qmlplugindump QtLocation 5.0 imports/QtLocation/libdeclarative_location.so > plugins.qmltypes
load(resolve_target)
qmltypes.target = qmltypes
qmltypes.commands = $$[QT_INSTALL_BINS]/qmlplugindump QtLocation 5.0 $$QMAKE_RESOLVED_TARGET > $$PWD/plugins.qmltypes
qmltypes.depends = $$QMAKE_RESOLVED_TARGET
QMAKE_EXTRA_TARGETS += qmltypes
# Tell qmake to create such makefile that qmldir, plugins.qmltypes and target
# (i.e. declarative_location) are all copied to $$[QT_INSTALL_IMPORTS]/QtLocation directory,
qmldir.files += $$PWD/qmldir $$PWD/plugins.qmltypes
qmldir.path += $$[QT_INSTALL_IMPORTS]/$$TARGETPATH
INSTALLS += target qmldir
OTHER_FILES += \
plugin.json
|