Add CoreLocation positioning plugin for QtLocation

Implements a QGeoPositionInfoSource plugin using CoreLocation.

Implemented by Ian Dean.

[ChangeLog][QtPositioning][QGeoPositionInfoSource] iOS position backend
added.

Change-Id: I09df434f95e5d72b1f6cf6381412334ae45d3d54
Reviewed-by: Ian Dean <ian@mediator-software.com>
Reviewed-by: Alex Blasche <alexander.blasche@digia.com>

7 files changed, 492 insertions, 0 deletions

diff --git a/src/plugins/position/corelocation/corelocation.pro b/src/plugins/position/corelocation/corelocation.pro
new file mode 100644
index 00000000..bc65ee5d
--- /dev/null
+++ b/src/plugins/position/corelocation/corelocation.pro
@@ -0,0 +1,23 @@
+TARGET = qtposition_cl
+QT += positioning gui
+
+PLUGIN_TYPE = position
+PLUGIN_CLASS_NAME = QGeoPositionInfoSourceFactoryCL
+load(qt_plugin)
+
+INCLUDEPATH += $$QT.location.includes
+
+OBJECTIVE_SOURCES += \
+    qgeopositioninfosource_cl.mm \
+    qgeopositioninfosourcefactory_cl.mm
+
+HEADERS += \
+    qgeopositioninfosource_cl_p.h \
+    qgeopositioninfosourcefactory_cl.h
+
+OTHER_FILES += \
+    plugin.json
+
+osx: LIBS += -framework Foundation
+else: ios: LIBS += -framework CoreFoundation
+LIBS += -framework CoreLocation
diff --git a/src/plugins/position/corelocation/plugin.json b/src/plugins/position/corelocation/plugin.json
new file mode 100644
index 00000000..96e5cbf1
--- /dev/null
+++ b/src/plugins/position/corelocation/plugin.json
@@ -0,0 +1,8 @@
+{
+    "Keys": ["corelocation"],
+    "Provider": "corelocation",
+    "Position": true,
+    "Satellite": false,
+    "Monitor" : false,
+    "Priority": 1000
+}
diff --git a/src/plugins/position/corelocation/qgeopositioninfosource_cl.mm b/src/plugins/position/corelocation/qgeopositioninfosource_cl.mm
new file mode 100644
index 00000000..47ceb6b6
--- /dev/null
+++ b/src/plugins/position/corelocation/qgeopositioninfosource_cl.mm
@@ -0,0 +1,241 @@
+/****************************************************************************
+**
+** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the QtPositioning module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and Digia.  For licensing terms and
+** conditions see http://qt.digia.com/licensing.  For further information
+** use the contact form at http://qt.digia.com/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 2.1 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU Lesser General Public License version 2.1 requirements
+** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
+**
+** In addition, as a special exception, Digia gives you certain additional
+** rights.  These rights are described in the Digia Qt LGPL Exception
+** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 3.0 as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU General Public License version 3.0 requirements will be
+** met: http://www.gnu.org/copyleft/gpl.html.
+**
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#include <QTimerEvent>
+#include <QDebug>
+
+#include "qgeopositioninfosource_cl_p.h"
+
+#define MINIMUM_UPDATE_INTERVAL 1000
+
+@interface locationDelegate : NSObject <CLLocationManagerDelegate>
+{
+    QGeoPositionInfoSourceCL *m_positionInfoSource;
+}
+@end
+
+@implementation locationDelegate
+- (id)initWithInfoSource:(QGeoPositionInfoSourceCL*) positionInfoSource
+{
+    self = [super init];
+    if (self) {
+        m_positionInfoSource = positionInfoSource;
+    }
+    return self;
+}
+
+- (void)locationManager:(CLLocationManager *)manager didUpdateToLocation:(CLLocation *)newLocation fromLocation:(CLLocation *)oldLocation
+{
+    Q_UNUSED(manager)
+    Q_UNUSED(oldLocation)
+
+    // Convert location timestamp to QDateTime
+    QDateTime timeStamp;
+    NSTimeInterval locationTimeStamp = [newLocation.timestamp timeIntervalSince1970];
+    timeStamp.setTime_t((uint) locationTimeStamp);
+    timeStamp.setTime(timeStamp.time().addMSecs((uint)(locationTimeStamp * 1000) % 1000));
+
+    // Construct position info from location data
+    QGeoPositionInfo location(QGeoCoordinate(newLocation.coordinate.latitude,
+                                             newLocation.coordinate.longitude,
+                                             newLocation.altitude),
+                                             timeStamp);
+    location.setAttribute(QGeoPositionInfo::HorizontalAccuracy, newLocation.horizontalAccuracy);
+    location.setAttribute(QGeoPositionInfo::VerticalAccuracy, newLocation.verticalAccuracy);
+    location.setAttribute(QGeoPositionInfo::Direction, newLocation.course);
+    location.setAttribute(QGeoPositionInfo::GroundSpeed, newLocation.speed);
+
+    m_positionInfoSource->locationDataAvailable(location);
+}
+
+- (void)locationManager:(CLLocationManager *)manager didFailWithError:(NSError *)error
+{
+    Q_UNUSED(manager)
+    m_positionInfoSource->setError(QGeoPositionInfoSource::AccessError);
+
+    qWarning() << QString::fromNSString([error localizedDescription]);
+}
+@end
+
+QT_BEGIN_NAMESPACE
+
+QGeoPositionInfoSourceCL::QGeoPositionInfoSourceCL(QObject *parent)
+    : QGeoPositionInfoSource(parent)
+    , m_locationManager(0)
+    , m_started(false)
+    , m_updateTimer(0)
+    , m_updateTimeout(0)
+    , m_positionError(QGeoPositionInfoSource::UnknownSourceError)
+{
+}
+
+QGeoPositionInfoSourceCL::~QGeoPositionInfoSourceCL()
+{
+    stopUpdates();
+    [m_locationManager release];
+}
+
+void QGeoPositionInfoSourceCL::setUpdateInterval(int msec)
+{
+    // If msec is 0 we send updates as data becomes available, otherwise we force msec to be equal
+    // to or larger than the minimum update interval.
+    if (msec != 0 && msec < minimumUpdateInterval())
+        msec = minimumUpdateInterval();
+
+    QGeoPositionInfoSource::setUpdateInterval(msec);
+
+    // Must timeout if update takes longer than specified interval
+    m_updateTimeout = msec;
+    if (m_started) setTimeoutInterval(m_updateTimeout);
+}
+
+bool QGeoPositionInfoSourceCL::enableLocationManager()
+{
+    if (!m_locationManager) {
+        m_locationManager = [[CLLocationManager alloc] init];
+        m_locationManager.desiredAccuracy = kCLLocationAccuracyBest;
+        m_locationManager.delegate = [[locationDelegate alloc] initWithInfoSource:this];
+    }
+
+    return (m_locationManager != 0);
+}
+
+void QGeoPositionInfoSourceCL::setTimeoutInterval(int msec)
+{
+    // Start timeout timer
+    if (m_updateTimer) killTimer(m_updateTimer);
+    if (msec > 0) m_updateTimer = startTimer(msec);
+    else m_updateTimer = 0;
+}
+
+void QGeoPositionInfoSourceCL::startUpdates()
+{
+    if (enableLocationManager()) {
+        [m_locationManager startUpdatingLocation];
+        m_started = true;
+
+        setTimeoutInterval(m_updateTimeout);
+    } else setError(QGeoPositionInfoSource::AccessError);
+}
+
+void QGeoPositionInfoSourceCL::stopUpdates()
+{
+    if (m_locationManager) {
+        [m_locationManager stopUpdatingLocation];
+        m_started = false;
+
+        // Stop timeout timer
+        setTimeoutInterval(0);
+    } else setError(QGeoPositionInfoSource::AccessError);
+}
+
+void QGeoPositionInfoSourceCL::requestUpdate(int timeout)
+{
+    // Get a single update within timeframe
+    if (timeout < minimumUpdateInterval() && timeout != 0)
+        emit updateTimeout();
+    else if (enableLocationManager()) {
+        // This will force LM to generate a new update
+        [m_locationManager stopUpdatingLocation];
+        [m_locationManager startUpdatingLocation];
+
+        setTimeoutInterval(timeout);
+    } else setError(QGeoPositionInfoSource::AccessError);
+}
+
+void QGeoPositionInfoSourceCL::timerEvent( QTimerEvent * event )
+{
+    // Update timed out?
+    if (event->timerId() == m_updateTimer) {
+        emit updateTimeout();
+
+        // Only timeout once since last data
+        setTimeoutInterval(0);
+
+        // Started for single update?
+        if (!m_started) stopUpdates();
+    }
+}
+
+QGeoPositionInfoSource::PositioningMethods QGeoPositionInfoSourceCL::supportedPositioningMethods() const
+{
+    // CoreLocation doesn't say which positioning method(s) it used
+    return QGeoPositionInfoSource::AllPositioningMethods;
+}
+
+int QGeoPositionInfoSourceCL::minimumUpdateInterval() const
+{
+    return MINIMUM_UPDATE_INTERVAL;
+}
+
+void QGeoPositionInfoSourceCL::locationDataAvailable(QGeoPositionInfo location)
+{
+    // Signal position data available
+    m_lastUpdate = location;
+    emit positionUpdated(location);
+
+    // Started for single update?
+    if (!m_started) stopUpdates();
+    // ...otherwise restart timeout timer
+    else setTimeoutInterval(m_updateTimeout);
+}
+
+QGeoPositionInfo QGeoPositionInfoSourceCL::lastKnownPosition(bool fromSatellitePositioningMethodsOnly) const
+{
+    Q_UNUSED(fromSatellitePositioningMethodsOnly)
+
+    return m_lastUpdate;
+}
+
+QGeoPositionInfoSource::Error QGeoPositionInfoSourceCL::error() const
+{
+    return m_positionError;
+}
+
+void QGeoPositionInfoSourceCL::setError(QGeoPositionInfoSource::Error positionError)
+{
+    m_positionError = positionError;
+    emit QGeoPositionInfoSource::error(positionError);
+}
+
+#include "moc_qgeopositioninfosource_cl_p.cpp"
+
+QT_END_NAMESPACE
diff --git a/src/plugins/position/corelocation/qgeopositioninfosource_cl_p.h b/src/plugins/position/corelocation/qgeopositioninfosource_cl_p.h
new file mode 100644
index 00000000..a73ce70e
--- /dev/null
+++ b/src/plugins/position/corelocation/qgeopositioninfosource_cl_p.h
@@ -0,0 +1,99 @@
+/****************************************************************************
+**
+** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the QtPositioning module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and Digia.  For licensing terms and
+** conditions see http://qt.digia.com/licensing.  For further information
+** use the contact form at http://qt.digia.com/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 2.1 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU Lesser General Public License version 2.1 requirements
+** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
+**
+** In addition, as a special exception, Digia gives you certain additional
+** rights.  These rights are described in the Digia Qt LGPL Exception
+** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 3.0 as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU General Public License version 3.0 requirements will be
+** met: http://www.gnu.org/copyleft/gpl.html.
+**
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#ifndef QGEOPOSITIONINFOSOURCECL_H
+#define QGEOPOSITIONINFOSOURCECL_H
+
+#import <CoreLocation/CoreLocation.h>
+
+#include "qgeopositioninfosource.h"
+#include "qgeopositioninfo.h"
+
+QT_BEGIN_HEADER
+
+QT_BEGIN_NAMESPACE
+
+class QGeoPositionInfoSourceCL : public QGeoPositionInfoSource
+{
+    Q_OBJECT
+public:
+    QGeoPositionInfoSourceCL(QObject *parent = 0);
+    ~QGeoPositionInfoSourceCL();
+
+    QGeoPositionInfo lastKnownPosition(bool fromSatellitePositioningMethodsOnly = false) const;
+    PositioningMethods supportedPositioningMethods() const;
+
+    void setUpdateInterval(int msec);
+    int minimumUpdateInterval() const;
+    Error error() const;
+
+    void locationDataAvailable(QGeoPositionInfo location);
+    void setError(QGeoPositionInfoSource::Error positionError);
+
+private:
+    bool enableLocationManager();
+    void setTimeoutInterval(int msec);
+
+public Q_SLOTS:
+    void startUpdates();
+    void stopUpdates();
+
+    void requestUpdate(int timeout = 0);
+
+protected:
+    virtual void timerEvent(QTimerEvent *event);
+
+private:
+    Q_DISABLE_COPY(QGeoPositionInfoSourceCL);
+    CLLocationManager *m_locationManager;
+    bool m_started;
+
+    QGeoPositionInfo m_lastUpdate;
+
+    int m_updateTimer;
+    int m_updateTimeout;
+
+    QGeoPositionInfoSource::Error m_positionError;
+};
+
+QT_END_NAMESPACE
+
+#endif // QGEOPOSITIONINFOSOURCECL_H
diff --git a/src/plugins/position/corelocation/qgeopositioninfosourcefactory_cl.h b/src/plugins/position/corelocation/qgeopositioninfosourcefactory_cl.h
new file mode 100644
index 00000000..2ebbe5fc
--- /dev/null
+++ b/src/plugins/position/corelocation/qgeopositioninfosourcefactory_cl.h
@@ -0,0 +1,60 @@
+/****************************************************************************
+**
+** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the QtPositioning module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and Digia.  For licensing terms and
+** conditions see http://qt.digia.com/licensing.  For further information
+** use the contact form at http://qt.digia.com/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 2.1 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU Lesser General Public License version 2.1 requirements
+** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
+**
+** In addition, as a special exception, Digia gives you certain additional
+** rights.  These rights are described in the Digia Qt LGPL Exception
+** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 3.0 as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU General Public License version 3.0 requirements will be
+** met: http://www.gnu.org/copyleft/gpl.html.
+**
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#ifndef QGEOPOSITIONINFOSOURCEFACTORY_CL_H
+#define QGEOPOSITIONINFOSOURCEFACTORY_CL_H
+
+#include <QObject>
+#include <QGeoPositionInfoSourceFactory>
+
+class QGeoPositionInfoSourceFactoryCL : public QObject, public QGeoPositionInfoSourceFactory
+{
+    Q_OBJECT
+    Q_PLUGIN_METADATA(IID "org.qt-project.qt.position.sourcefactory/5.0"
+                      FILE "plugin.json")
+    Q_INTERFACES(QGeoPositionInfoSourceFactory)
+public:
+    QGeoPositionInfoSource *positionInfoSource(QObject *parent);
+    QGeoSatelliteInfoSource *satelliteInfoSource(QObject *parent);
+    QGeoAreaMonitorSource *areaMonitor(QObject *parent);
+};
+
+#endif // QGEOPOSITIONINFOSOURCEFACTORY_CL_H
diff --git a/src/plugins/position/corelocation/qgeopositioninfosourcefactory_cl.mm b/src/plugins/position/corelocation/qgeopositioninfosourcefactory_cl.mm
new file mode 100644
index 00000000..6566a255
--- /dev/null
+++ b/src/plugins/position/corelocation/qgeopositioninfosourcefactory_cl.mm
@@ -0,0 +1,60 @@
+/****************************************************************************
+**
+** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the QtPositioning module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and Digia.  For licensing terms and
+** conditions see http://qt.digia.com/licensing.  For further information
+** use the contact form at http://qt.digia.com/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 2.1 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU Lesser General Public License version 2.1 requirements
+** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
+**
+** In addition, as a special exception, Digia gives you certain additional
+** rights.  These rights are described in the Digia Qt LGPL Exception
+** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 3.0 as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL included in the
+** packaging of this file.  Please review the following information to
+** ensure the GNU General Public License version 3.0 requirements will be
+** met: http://www.gnu.org/copyleft/gpl.html.
+**
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#include "qgeopositioninfosource_cl_p.h"
+#include "qgeopositioninfosourcefactory_cl.h"
+
+QGeoPositionInfoSource *QGeoPositionInfoSourceFactoryCL::positionInfoSource(QObject *parent)
+{
+    return new QGeoPositionInfoSourceCL(parent);
+}
+
+QGeoSatelliteInfoSource *QGeoPositionInfoSourceFactoryCL::satelliteInfoSource(QObject *parent)
+{
+    Q_UNUSED(parent);
+    return 0;
+}
+
+QGeoAreaMonitorSource *QGeoPositionInfoSourceFactoryCL::areaMonitor(QObject *parent)
+{
+    Q_UNUSED(parent);
+    return 0;
+}
diff --git a/src/plugins/position/position.pro b/src/plugins/position/position.pro
index af2a5009..d6e7c6b6 100644
--- a/src/plugins/position/position.pro
+++ b/src/plugins/position/position.pro
@@ -4,6 +4,7 @@ config_geoclue:SUBDIRS += geoclue
 config_gypsy:SUBDIRS += gypsy
 simulator:SUBDIRS += simulator
 blackberry:SUBDIRS += blackberry
+ios:SUBDIRS += corelocation
 
 SUBDIRS += \
     positionpoll