blob: 5a0ef03340b84e4d54879bcd3f3d1da0784d285a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
#import "MGLShapeCollection.h"
#import "MGLShape_Private.h"
#import "MGLFeature.h"
#import "MGLLoggingConfiguration_Private.h"
#import <mbgl/style/conversion/geojson.hpp>
@implementation MGLShapeCollection
+ (instancetype)shapeCollectionWithShapes:(NSArray<MGLShape *> *)shapes {
return [[self alloc] initWithShapes:shapes];
}
- (instancetype)initWithShapes:(NSArray<MGLShape *> *)shapes {
MGLLogDebug(@"Initializing with %lu shapes.", (unsigned long)shapes.count);
if (self = [super init]) {
_shapes = shapes.copy;
}
return self;
}
- (instancetype)initWithCoder:(NSCoder *)decoder {
MGLLogInfo(@"Initializing with coder.");
if (self = [super initWithCoder:decoder]) {
_shapes = [decoder decodeObjectOfClass:[NSArray class] forKey:@"shapes"];
}
return self;
}
- (void)encodeWithCoder:(NSCoder *)coder {
[super encodeWithCoder:coder];
[coder encodeObject:_shapes forKey:@"shapes"];
}
- (BOOL)isEqual:(id)other {
if (self == other) return YES;
if (![other isKindOfClass:[MGLShapeCollection class]]) return NO;
MGLShapeCollection *otherShapeCollection = other;
return [super isEqual:otherShapeCollection]
&& [_shapes isEqualToArray:otherShapeCollection.shapes];
}
- (NSUInteger)hash {
NSUInteger hash = [super hash];
for (MGLShape *shape in _shapes) {
hash += [shape hash];
}
return hash;
}
- (CLLocationCoordinate2D)coordinate {
return _shapes.firstObject.coordinate;
}
- (NSDictionary *)geoJSONDictionary {
return @{@"type": @"GeometryCollection",
@"geometries": [self geometryCollection]};
}
- (NSArray *)geometryCollection {
NSMutableArray *geometries = [[NSMutableArray alloc] initWithCapacity:self.shapes.count];
for (id shape in self.shapes) {
NSDictionary *geometry = [shape geoJSONDictionary];
[geometries addObject:geometry];
}
return [geometries copy];
}
- (mbgl::Geometry<double>)geometryObject {
mapbox::geojson::geometry_collection collection;
collection.reserve(self.shapes.count);
for (MGLShape *shape in self.shapes) {
collection.push_back([shape geometryObject]);
}
return collection;
}
@end
|
