blob: ae4fbe61de38f78f012c4ef9531437e293fd22d2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
|
#import "MGLPolyline.h"
#import "MGLMultiPoint_Private.h"
#import "MGLGeometry_Private.h"
#import "MGLPolyline+MGLAdditions.h"
#import <mbgl/util/geojson.hpp>
@implementation MGLPolyline
@dynamic overlayBounds;
+ (instancetype)polylineWithCoordinates:(const CLLocationCoordinate2D *)coords
count:(NSUInteger)count
{
return [[self alloc] initWithCoordinates:coords count:count];
}
- (mbgl::LineString<double>)lineString {
NSUInteger count = self.pointCount;
CLLocationCoordinate2D *coordinates = self.coordinates;
mbgl::LineString<double> geometry;
geometry.reserve(self.pointCount);
for (NSUInteger i = 0; i < count; i++) {
geometry.push_back(mbgl::Point<double>(coordinates[i].longitude, coordinates[i].latitude));
}
return geometry;
}
- (mbgl::Annotation)annotationObjectWithDelegate:(id <MGLMultiPointDelegate>)delegate {
mbgl::LineAnnotation annotation { [self lineString] };
annotation.opacity = { static_cast<float>([delegate alphaForShapeAnnotation:self]) };
annotation.color = { [delegate strokeColorForShapeAnnotation:self] };
annotation.width = { static_cast<float>([delegate lineWidthForPolylineAnnotation:self]) };
return annotation;
}
- (mbgl::Geometry<double>)geometryObject {
return [self lineString];
}
- (NSDictionary *)geoJSONDictionary {
return @{@"type": @"LineString",
@"coordinates": self.mgl_coordinates};
}
- (BOOL)isEqual:(id)other {
return self == other || ([other isKindOfClass:[MGLPolyline class]] && [super isEqual:other]);
}
@end
@interface MGLMultiPolyline ()
@property (nonatomic, copy, readwrite) NS_ARRAY_OF(MGLPolyline *) *polylines;
@end
@implementation MGLMultiPolyline {
MGLCoordinateBounds _overlayBounds;
}
@synthesize overlayBounds = _overlayBounds;
+ (instancetype)multiPolylineWithPolylines:(NS_ARRAY_OF(MGLPolyline *) *)polylines {
return [[self alloc] initWithPolylines:polylines];
}
- (instancetype)initWithPolylines:(NS_ARRAY_OF(MGLPolyline *) *)polylines {
if (self = [super init]) {
_polylines = polylines;
mbgl::LatLngBounds bounds = mbgl::LatLngBounds::empty();
for (MGLPolyline *polyline in _polylines) {
bounds.extend(MGLLatLngBoundsFromCoordinateBounds(polyline.overlayBounds));
}
_overlayBounds = MGLCoordinateBoundsFromLatLngBounds(bounds);
}
return self;
}
- (instancetype)initWithCoder:(NSCoder *)decoder {
if (self = [super initWithCoder:decoder]) {
_polylines = [decoder decodeObjectOfClass:[NSArray class] forKey:@"polylines"];
}
return self;
}
- (void)encodeWithCoder:(NSCoder *)coder {
[super encodeWithCoder:coder];
[coder encodeObject:_polylines forKey:@"polylines"];
}
- (BOOL)isEqual:(id)other
{
if (self == other) return YES;
if (![other isKindOfClass:[MGLMultiPolyline class]]) return NO;
MGLMultiPolyline *otherMultipoline = other;
return ([super isEqual:otherMultipoline]
&& [self.polylines isEqualToArray:otherMultipoline.polylines]);
}
- (NSUInteger)hash {
NSUInteger hash = [super hash];
for (MGLPolyline *polyline in self.polylines) {
hash += [polyline hash];
}
return hash;
}
- (BOOL)intersectsOverlayBounds:(MGLCoordinateBounds)overlayBounds {
return MGLCoordinateBoundsIntersectsCoordinateBounds(_overlayBounds, overlayBounds);
}
- (mbgl::Geometry<double>)geometryObject {
mbgl::MultiLineString<double> multiLineString;
multiLineString.reserve(self.polylines.count);
for (MGLPolyline *polyline in self.polylines) {
multiLineString.push_back([polyline lineString]);
}
return multiLineString;
}
- (NSDictionary *)geoJSONDictionary {
NSMutableArray *coordinates = [NSMutableArray array];
for (MGLPolylineFeature *feature in self.polylines) {
[coordinates addObject: feature.mgl_coordinates];
}
return @{@"type": @"MultiLineString",
@"coordinates": coordinates};
}
@end
|
