2 files changed, 71 insertions, 0 deletions
diff --git a/platform/macos/src/NSColor+MGLAdditions.h b/platform/macos/src/NSColor+MGLAdditions.h
index af9b8b0255..21c939fec6 100644
--- a/platform/macos/src/NSColor+MGLAdditions.h
+++ b/platform/macos/src/NSColor+MGLAdditions.h
@@ -18,3 +18,10 @@
 - (mbgl::style::PropertyValue<mbgl::Color>)mgl_colorPropertyValue;
 
 @end
+
+@interface NSExpression (MGLColorAdditions)
+
++ (NSExpression *)mgl_expressionForRGBComponents:(NSArray<NSExpression *> *)components;
++ (NSExpression *)mgl_expressionForRGBAComponents:(NSArray<NSExpression *> *)components;
+
+@end
diff --git a/platform/macos/src/NSColor+MGLAdditions.mm b/platform/macos/src/NSColor+MGLAdditions.mm
index f44cb8d434..8c9086ccf7 100644
--- a/platform/macos/src/NSColor+MGLAdditions.mm
+++ b/platform/macos/src/NSColor+MGLAdditions.mm
@@ -33,3 +33,67 @@
 }
 
 @end
+
+@implementation NSExpression (MGLColorAdditions)
+
++ (NSExpression *)mgl_expressionForRGBComponents:(NSArray<NSExpression *> *)components {
+    if (NSColor *color = [self mgl_colorWithComponentExpressions:components]) {
+        return [NSExpression expressionForConstantValue:color];
+    }
+    
+    NSExpression *color = [NSExpression expressionForConstantValue:[NSColor class]];
+    NSExpression *alpha = [NSExpression expressionForConstantValue:@1.0];
+    return [NSExpression expressionForFunction:color
+                                  selectorName:@"colorWithRed:green:blue:alpha:"
+                                     arguments:[components arrayByAddingObject:alpha]];
+}
+
++ (NSExpression *)mgl_expressionForRGBAComponents:(NSArray<NSExpression *> *)components {
+    if (NSColor *color = [self mgl_colorWithComponentExpressions:components]) {
+        return [NSExpression expressionForConstantValue:color];
+    }
+    
+    NSExpression *color = [NSExpression expressionForConstantValue:[NSColor class]];
+    return [NSExpression expressionForFunction:color
+                                  selectorName:@"colorWithRed:green:blue:alpha:"
+                                     arguments:components];
+}
+
+/**
+ Returns a color object corresponding to the given component expressions.
+ */
++ (NSColor *)mgl_colorWithComponentExpressions:(NSArray<NSExpression *> *)componentExpressions {
+    // Map the component expressions to constant components. If any component is
+    // a non-constant expression, the components cannot be converted into a
+    // constant color value.
+    std::vector<CGFloat> components;
+    for (NSExpression *componentExpression in componentExpressions) {
+        if (componentExpression.expressionType != NSConstantValueExpressionType) {
+            return nil;
+        }
+        
+        NSNumber *component = (NSNumber *)componentExpression.constantValue;
+        if (![component isKindOfClass:[NSNumber class]]) {
+            return nil;
+        }
+        
+        components.push_back(component.doubleValue / 255.0);
+    }
+    // Alpha
+    components.back() *= 255.0;
+    
+    // macOS 10.12 Sierra and below uses calibrated RGB by default.
+    if ([NSColor redColor].colorSpaceName == NSCalibratedRGBColorSpace) {
+        return [NSColor colorWithCalibratedRed:components[0]
+                                         green:components[1]
+                                          blue:components[2]
+                                         alpha:components[3]];
+    }
+    // The Mapbox Style Specification does not specify a color space, but it is
+    // assumed to be sRGB for consistency with CSS.
+    return [NSColor colorWithColorSpace:[NSColorSpace sRGBColorSpace]
+                             components:&components[0]
+                                  count:components.size()];
+}
+
+@end