[ios, macos] Simplify MGLSource and subclasses (#7377)

* [ios, macos] Audited source headers for nullability

* [macos] Made MGLTileSet public

* [ios, macos] Replaced MGLTileSet with MGLTileSource

MGLRasterSource and MGLVectorSource now share a common abstract superclass, MGLTileSource. MGLTileSet has been removed. MGLTileSource is modeled after mbgl::style::RasterSource and mbgl::style::VectorSource. It has initializers that incorporate the parameters of MGLTileSet’s initializers, but it lacks getters for everything but the attribution string. MGLTileSet’s properties have been converted into options that can be passed into MGLTileSource’s initializers in a dictionary.

Properly implement rawSource as a covariant property so that it doesn’t end up getting autosynthesized as a shadow ivar. This prevents concrete subclasses of MGLSource from setting _rawSource directly but getting a different value out of self.rawSource.

Marked -[MGLSource init] as unavailable and ensured that concrete subclasses of MGLSource have the right set of initializers marked as designated initializers.

Documentation comments for each concrete source class identify the corresponding source type in the style specification. Clarified the purpose of MGLTileSetScheme, now known as MGLTileCoordinateSystem.

* [ios, macos] Clarified tile size interpretation

Sticking to a default value of 256 for mapbox: URLs, but other URLs get the standard 512 value.

* [ios, macos] rawSource is always set

* [ios, macos] Cleaned up MGLShapeSource initialization

rawSource is never nil, so there’s no need for a -commonInit method. Extracted -geoJSONOptions from MGLShapeSource into a standalone function for easier testing.

* [ios, macos] Synchronized headers in project

Realphabetized headers in groups. Added headers missing from one project or the other.

* [ios, macos] Added MGLShape methods to (de)serialize GeoJSON data

Added a class initializer and instance method to MGLShape that deserialize and serialize the shape as GeoJSON data, respectively. The new initializer handles parsing errors gracefully.

Removed methods specific to GeoJSON data from MGLShapeSource, in an effort to reduce parallel state. Developers are now expected to go through the new MGLShape initializer to get an MGLShape representation. Alternatively, a local file URL can be passed into the other MGLShapeSource initializer.

* [ios, macos] Typo in assertion message

* [ios, macos] Simplified GeoJSON serialization

Every MGLShape now knows its most specific mbgl::GeoJSON representation.

* [ios, macos] Reremoved MGLFeaturePrivate

mbgl::GeoJSON, which is a variant, allows a single GeoJSON representation method to traffic in whatever type is needed for a particular shape class. This change removes some hidden private protocols, which are a bug waiting to happen.

* [ios, macos] Fixed covariant rawLayer property

Properly implement rawLayer as a covariant property so that it doesn’t end up getting autosynthesized as a shadow ivar. This prevents concrete subclasses of MGLStyleLayer from setting _rawLayer directly but getting a different value out of self.rawLayer.

* [ios, macos] Use MGLAttributionInfo for source attribution

Made MGLAttributionInfo public. Replaced MGLTileSource’s attribution property with an attributionInfos property set to an array of MGLAttributionInfo objects. Added an MGLTileSourceOption for specifying an array of MGLAttributionInfo objects instead of an HTML string (either is acceptable when creating an MGLTileSource).

* [ios, macos] Corrected method references in documentation

1 files changed, 123 insertions, 0 deletions

diff --git a/platform/darwin/src/MGLTileSource.mm b/platform/darwin/src/MGLTileSource.mm
new file mode 100644
index 0000000000..522675bc88
--- /dev/null
+++ b/platform/darwin/src/MGLTileSource.mm
@@ -0,0 +1,123 @@
+#import "MGLTileSource_Private.h"
+
+#import "MGLAttributionInfo_Private.h"
+#import "NSString+MGLAdditions.h"
+
+#if TARGET_OS_IPHONE
+    #import <UIKit/UIKit.h>
+#else
+    #import <Cocoa/Cocoa.h>
+#endif
+
+#include <mbgl/util/tileset.hpp>
+
+const MGLTileSourceOption MGLTileSourceOptionMinimumZoomLevel = @"MGLTileSourceOptionMinimumZoomLevel";
+const MGLTileSourceOption MGLTileSourceOptionMaximumZoomLevel = @"MGLTileSourceOptionMaximumZoomLevel";
+const MGLTileSourceOption MGLTileSourceOptionAttributionHTMLString = @"MGLTileSourceOptionAttributionHTMLString";
+const MGLTileSourceOption MGLTileSourceOptionAttributionInfos = @"MGLTileSourceOptionAttributionInfos";
+const MGLTileSourceOption MGLTileSourceOptionTileCoordinateSystem = @"MGLTileSourceOptionTileCoordinateSystem";
+
+@implementation MGLTileSource
+
+- (instancetype)initWithIdentifier:(NSString *)identifier configurationURL:(NSURL *)configurationURL {
+    return [super initWithIdentifier:identifier];
+}
+
+- (instancetype)initWithIdentifier:(NSString *)identifier tileURLTemplates:(NS_ARRAY_OF(NSString *) *)tileURLTemplates options:(NS_DICTIONARY_OF(MGLTileSourceOption, id) *)options {
+    return [super initWithIdentifier:identifier];
+}
+
+- (NS_ARRAY_OF(MGLAttributionInfo *) *)attributionInfos {
+    return [self attributionInfosWithFontSize:0 linkColor:nil];
+}
+
+- (NS_ARRAY_OF(MGLAttributionInfo *) *)attributionInfosWithFontSize:(CGFloat)fontSize linkColor:(nullable MGLColor *)linkColor {
+    return [MGLAttributionInfo attributionInfosFromHTMLString:self.attributionHTMLString
+                                                     fontSize:fontSize
+                                                    linkColor:linkColor];
+}
+
+- (NSString *)attributionHTMLString {
+    [NSException raise:@"MGLAbstractClassException"
+                format:@"MGLTileSource is an abstract class"];
+    return nil;
+}
+
+@end
+
+mbgl::Tileset MGLTileSetFromTileURLTemplates(NS_ARRAY_OF(NSString *) *tileURLTemplates, NS_DICTIONARY_OF(MGLTileSourceOption, id) * _Nullable options) {
+    mbgl::Tileset tileSet;
+    
+    for (NSString *tileURLTemplate in tileURLTemplates) {
+        tileSet.tiles.push_back(tileURLTemplate.UTF8String);
+    }
+    
+    // set the minimum / maximum zoom range to the values specified by this class if they
+    // were set. otherwise, use the core objects default values
+    if (NSNumber *minimumZoomLevel = options[MGLTileSourceOptionMinimumZoomLevel]) {
+        if (![minimumZoomLevel isKindOfClass:[NSNumber class]]) {
+            [NSException raise:NSInvalidArgumentException
+                        format:@"MGLTileSourceOptionMinimumZoomLevel must be set to an NSNumber."];
+        }
+        tileSet.zoomRange.min = minimumZoomLevel.integerValue;
+    }
+    if (NSNumber *maximumZoomLevel = options[MGLTileSourceOptionMaximumZoomLevel]) {
+        if (![maximumZoomLevel isKindOfClass:[NSNumber class]]) {
+            [NSException raise:NSInvalidArgumentException
+                        format:@"MGLTileSourceOptionMinimumZoomLevel must be set to an NSNumber."];
+        }
+        tileSet.zoomRange.max = maximumZoomLevel.integerValue;
+    }
+    if (tileSet.zoomRange.min > tileSet.zoomRange.max) {
+        [NSException raise:NSInvalidArgumentException
+                    format:@"MGLTileSourceOptionMinimumZoomLevel must be less than MGLTileSourceOptionMaximumZoomLevel."];
+    }
+    
+    if (NSString *attribution = options[MGLTileSourceOptionAttributionHTMLString]) {
+        if (![attribution isKindOfClass:[NSString class]]) {
+            [NSException raise:NSInvalidArgumentException
+                        format:@"MGLTileSourceOptionAttributionHTMLString must be set to a string."];
+        }
+        tileSet.attribution = attribution.UTF8String;
+    }
+    
+    if (NSArray *attributionInfos = options[MGLTileSourceOptionAttributionInfos]) {
+        if (![attributionInfos isKindOfClass:[NSArray class]]) {
+            [NSException raise:NSInvalidArgumentException
+                        format:@"MGLTileSourceOptionAttributionInfos must be set to a string."];
+        }
+        
+        NSAttributedString *attributedString = [MGLAttributionInfo attributedStringForAttributionInfos:attributionInfos];
+#if TARGET_OS_IPHONE
+        static NSString * const NSExcludedElementsDocumentAttribute = @"ExcludedElements";
+#endif
+        NSDictionary *documentAttributes = @{
+            NSDocumentTypeDocumentAttribute: NSHTMLTextDocumentType,
+            NSCharacterEncodingDocumentAttribute: @(NSUTF8StringEncoding),
+            // The attribution string is meant to be a simple, inline fragment, not a full-fledged, validating document.
+            NSExcludedElementsDocumentAttribute: @[@"XML", @"DOCTYPE", @"html", @"head", @"meta", @"title", @"style", @"body", @"p"],
+        };
+        NSData *data = [attributedString dataFromRange:attributedString.mgl_wholeRange documentAttributes:documentAttributes error:NULL];
+        NSString *html = [[NSString alloc] initWithData:data encoding:NSUTF8StringEncoding];
+        tileSet.attribution = html.UTF8String;
+    }
+    
+    if (NSNumber *tileCoordinateSystemNumber = options[MGLTileSourceOptionTileCoordinateSystem]) {
+        if (![tileCoordinateSystemNumber isKindOfClass:[NSValue class]]) {
+            [NSException raise:NSInvalidArgumentException
+                        format:@"MGLTileSourceOptionTileCoordinateSystem must be set to an NSValue or NSNumber."];
+        }
+        MGLTileCoordinateSystem tileCoordinateSystem;
+        [tileCoordinateSystemNumber getValue:&tileCoordinateSystem];
+        switch (tileCoordinateSystem) {
+            case MGLTileCoordinateSystemXYZ:
+                tileSet.scheme = mbgl::Tileset::Scheme::XYZ;
+                break;
+            case MGLTileCoordinateSystemTMS:
+                tileSet.scheme = mbgl::Tileset::Scheme::TMS;
+                break;
+        }
+    }
+    
+    return tileSet;
+}