Fixed several problems with the postlinker for Symbian (elf2e32).

The fixes were too complicated for a profile and so a perl script was
introduced. These are the issues that were addressed:

- Made sure that we link correctly in all cases where there is a
  mismatch between the DEF file and the ELF file. Specifically, these
  two cases:

    - If elf2e32 detects a symbols in the ELF file that is marked as
      absent in the DEF file, an ordinal mapping will not be
      generated in the dso file. This means that binaries linking to
      the library will not find the symbol, even though it exists in
      the code. Since this is completely useless behavior, this was
      fixed to include the symbol regardless.

    - If the DEF file contains a symbol that is not present in the
      ELF file, an ordinal mapping will be created in the dso file
      regardless, which means applications can link to a symbol that
      does not exist. This is even worse than point one, since it is
      not detected until runtime, when the dynamic link will fail.
      Fixed by leaving the symbol out of the dso file if it does not
      exist in the ELF file.

  Both fixes require rerunning elf2e32 to fix the symbol mappings
  that were broken in the first run, but it only happens if at least
  one symbol is broken in the way described above. Also, freezing the
  DEF files will "save" the symbols, so that it does not occur after
  that.

  Note that this does not remove the ability to get the postlinker to
  tell you about mismatches. By doing
  "QMAKE_ELF2E32_FLAGS -= --unfrozen", the symbol mismatches will be
  considered errors instead of warnings, and they can be caught that
  way.

- Code that was previously in the profile was moved to the perl
  script:

    - Detecting that there are errors in the postlink and return
      nonzero. elf2e32 does not do this on its own (at least not when
      using Wine).

    - Only overwriting the old dso file if the new one is different.
      This saves build time, since binaries that depend on the
      library do not trigger relink if the dso has not changed.

  These two points simplify the code, and they will also help the
  porting to Windows, since the old shell script tricks would not
  have worked there.

RevBy:    Trust me

1 files changed, 145 insertions, 0 deletions

diff --git a/bin/elf2e32_qtwrapper b/bin/elf2e32_qtwrapper
new file mode 100755
index 0000000000..694d54a34c
--- /dev/null
+++ b/bin/elf2e32_qtwrapper
@@ -0,0 +1,145 @@
+#!/usr/bin/perl -w
+
+# A script to get around some shortcomings in elf2e32, namely:
+# - Returning 0 even when there are errors.
+# - Excluding symbols from the dso file even when they are present in the ELF file.
+# - Including symbols in the the dso file even when they are not present in the ELF file.
+# - Overwriting the old dso file even when there are no changes (increases build time).
+
+use File::Copy;
+
+my @args = ();
+my @definput;
+my @defoutput;
+my @dso;
+my @tmpdso;
+foreach (@ARGV) {
+    if (/^--definput/o) {
+        @definput = split('=', $_);
+    } elsif (/^--defoutput/o) {
+        @defoutput = split('=', $_);
+    } elsif (/^--dso/o) {
+        @dso = split('=', $_);
+    } elsif (/^--tmpdso/o) {
+        @tmpdso = split('=', $_);
+        $tmpdso[0] = "--dso";
+    } else {
+        push(@args, $_);
+    }
+}
+
+@definput = () if (!@definput || ! -e $definput[1]);
+
+if (@dso && !@tmpdso || !@dso && @tmpdso) {
+    print("--dso and --tmpdso must be used together.\n");
+    exit 1;
+}
+
+my $buildingLibrary = (@defoutput && @dso) ? 1 : 0;
+
+my $fixupFile = "";
+my $runCount = 0;
+my $returnCode = 0;
+
+while (1) {
+    if (++$runCount > 2) {
+        print("Internal error in $0, link succeeded, but exports may be wrong.\n");
+        last;
+    }
+
+    my $elf2e32Pipe;
+    my $elf2e32Cmd = "elf2e32 @args"
+         . " " . join("=", @definput)
+         . " " . join("=", @defoutput)
+         . " " . join("=", @tmpdso);
+    open($elf2e32Pipe, "$elf2e32Cmd 2>&1 |") or die ("Could not run elf2e32");
+
+    my %fixupSymbols;
+    my $foundBrokenSymbols = 0;
+    my $errors = 0;
+    while (<$elf2e32Pipe>) {
+        print;
+        if (/Error:/io) {
+            $errors = 1;
+        } elsif (/symbol ([a-z0-9_]+) absent in the DEF file, but present in the ELF file/io) {
+            $fixupSymbols{$1} = 1;
+            $foundBrokenSymbols = 1;
+        } elsif (/[0-9]+ Frozen Export\(s\) missing from the ELF file/io) {
+            $foundBrokenSymbols = 1;
+        }
+    }
+    close($elf2e32Pipe);
+
+    if ($errors) {
+        $returnCode = 1;
+        last;
+    }
+
+    if ($buildingLibrary) {
+        my $tmpDefFile;
+        my $defFile;
+        open($defFile, "< $defoutput[1]") or die("Could not open $defoutput[1]");
+        open($tmpDefFile, "> $defoutput[1].tmp") or die("Could not open $defoutput[1].tmp");
+        $fixupFile = "$defoutput[1].tmp";
+        while (<$defFile>) {
+            s/\r//;
+            s/\n//;
+            next if (/; NEW:/);
+            if (/([a-z0-9_]+) @/i) {
+                if (exists($fixupSymbols{$1})) {
+                    s/ ABSENT//;
+                } elsif (s/; MISSING://) {
+                    s/$/ ABSENT/;
+                }
+            }
+            print($tmpDefFile "$_\n");
+        }
+        close($defFile);
+        close($tmpDefFile);
+
+        $definput[1] = "$defoutput[1].tmp";
+
+        if (!$foundBrokenSymbols || $errors) {
+            last;
+        }
+
+        print("Rerunning elf2e32 due to DEF file / ELF file mismatch\n");
+    } else {
+        last;
+    }
+};
+
+if ($fixupFile) {
+    unlink($defoutput[1]);
+    move($fixupFile, $defoutput[1]);
+}
+
+exit $returnCode if ($returnCode != 0);
+
+if ($buildingLibrary) {
+    my $differenceFound = 0;
+
+    if (-e $dso[1]) {
+        my $dsoFile;
+        my $tmpdsoFile;
+        my $dsoBuf;
+        my $tmpdsoBuf;
+        open($dsoFile, "< $dso[1]") or die("Could not open $dso[1]");
+        open($tmpdsoFile, "< $tmpdso[1]") or die("Could not open $tmpdso[1]");
+        binmode($dsoFile);
+        binmode($tmpdsoFile);
+        while(read($dsoFile, $dsoBuf, 4096) && read($tmpdsoFile, $tmpdsoBuf, 4096)) {
+            if ($dsoBuf ne $tmpdsoBuf) {
+                $differenceFound = 1;
+            }
+        }
+        close($tmpdsoFile);
+        close($dsoFile);
+    } else {
+        $differenceFound = 1;
+    }
+
+    if ($differenceFound) {
+        copy($tmpdso[1], $dso[1]);
+    }
+}