Split image handler plugin project files

One pri for each handler, e.g. src/gui/image/qjpeghandler.pri.
One pri for each 3rd party package, e.g src/3rdparty/libjpeg.pri.
One shared pri for zlib dependency of 3rd party packages.

This was really about image handler plugins, but PNG got the
same treatment for consistency's sake.

Also, moved image handler source files from plugins to src/gui/image
so they are with the other image handlers.

Merge-request: 715
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com>

25 files changed, 204 insertions, 208 deletions

diff --git a/configure b/configure
index 4650229932..7f998fcc5d 100755
--- a/configure
+++ b/configure
@@ -3636,7 +3636,7 @@ Third Party Libraries:
 
     -no-gif ............ Do not compile the plugin for GIF reading support.
  *  -qt-gif ............ Compile the plugin for GIF reading support.
-                         See also src/plugins/imageformats/gif/qgifhandler.h
+                         See also src/gui/image/qgifhandler.h
 
     -no-libtiff ........ Do not compile the plugin for TIFF support.
     -qt-libtiff ........ Use the libtiff bundled with Qt.
diff --git a/src/3rdparty/libjpeg.pri b/src/3rdparty/libjpeg.pri
new file mode 100644
index 0000000000..4551d7bed1
--- /dev/null
+++ b/src/3rdparty/libjpeg.pri
@@ -0,0 +1,48 @@
+INCLUDEPATH += $$PWD/libjpeg
+SOURCES += \
+    $$PWD/libjpeg/jaricom.c \
+    $$PWD/libjpeg/jcapimin.c \
+    $$PWD/libjpeg/jcapistd.c \
+    $$PWD/libjpeg/jcarith.c \
+    $$PWD/libjpeg/jccoefct.c \
+    $$PWD/libjpeg/jccolor.c \
+    $$PWD/libjpeg/jcdctmgr.c \
+    $$PWD/libjpeg/jchuff.c \
+    $$PWD/libjpeg/jcinit.c \
+    $$PWD/libjpeg/jcmainct.c \
+    $$PWD/libjpeg/jcmarker.c \
+    $$PWD/libjpeg/jcmaster.c \
+    $$PWD/libjpeg/jcomapi.c \
+    $$PWD/libjpeg/jcparam.c \
+    $$PWD/libjpeg/jcprepct.c \
+    $$PWD/libjpeg/jcsample.c \
+    $$PWD/libjpeg/jctrans.c \
+    $$PWD/libjpeg/jdapimin.c \
+    $$PWD/libjpeg/jdapistd.c \
+    $$PWD/libjpeg/jdarith.c \
+    $$PWD/libjpeg/jdatadst.c \
+    $$PWD/libjpeg/jdatasrc.c \
+    $$PWD/libjpeg/jdcoefct.c \
+    $$PWD/libjpeg/jdcolor.c \
+    $$PWD/libjpeg/jddctmgr.c \
+    $$PWD/libjpeg/jdhuff.c \
+    $$PWD/libjpeg/jdinput.c \
+    $$PWD/libjpeg/jdmainct.c \
+    $$PWD/libjpeg/jdmarker.c \
+    $$PWD/libjpeg/jdmaster.c \
+    $$PWD/libjpeg/jdmerge.c \
+    $$PWD/libjpeg/jdpostct.c \
+    $$PWD/libjpeg/jdsample.c \
+    $$PWD/libjpeg/jdtrans.c \
+    $$PWD/libjpeg/jerror.c \
+    $$PWD/libjpeg/jfdctflt.c \
+    $$PWD/libjpeg/jfdctfst.c \
+    $$PWD/libjpeg/jfdctint.c \
+    $$PWD/libjpeg/jidctflt.c \
+    $$PWD/libjpeg/jidctfst.c \
+    $$PWD/libjpeg/jidctint.c \
+    $$PWD/libjpeg/jquant1.c \
+    $$PWD/libjpeg/jquant2.c \
+    $$PWD/libjpeg/jutils.c \
+    $$PWD/libjpeg/jmemmgr.c \
+    $$PWD/libjpeg/jmemnobs.c
diff --git a/src/3rdparty/libmng.pri b/src/3rdparty/libmng.pri
new file mode 100644
index 0000000000..7b682100ee
--- /dev/null
+++ b/src/3rdparty/libmng.pri
@@ -0,0 +1,25 @@
+DEFINES += MNG_BUILD_SO
+DEFINES += MNG_NO_INCLUDE_JNG
+INCLUDEPATH += $$PWD/libmng
+SOURCES += \
+    $$PWD/libmng/libmng_callback_xs.c \
+    $$PWD/libmng/libmng_chunk_io.c \
+    $$PWD/libmng/libmng_chunk_descr.c \
+    $$PWD/libmng/libmng_chunk_prc.c \
+    $$PWD/libmng/libmng_chunk_xs.c \
+    $$PWD/libmng/libmng_cms.c \
+    $$PWD/libmng/libmng_display.c \
+    $$PWD/libmng/libmng_dither.c \
+    $$PWD/libmng/libmng_error.c \
+    $$PWD/libmng/libmng_filter.c \
+    $$PWD/libmng/libmng_hlapi.c \
+    $$PWD/libmng/libmng_jpeg.c \
+    $$PWD/libmng/libmng_object_prc.c \
+    $$PWD/libmng/libmng_pixels.c \
+    $$PWD/libmng/libmng_prop_xs.c \
+    $$PWD/libmng/libmng_read.c \
+    $$PWD/libmng/libmng_trace.c \
+    $$PWD/libmng/libmng_write.c \
+    $$PWD/libmng/libmng_zlib.c
+
+include($$PWD/zlib_dependency.pri)
diff --git a/src/3rdparty/libpng.pri b/src/3rdparty/libpng.pri
new file mode 100644
index 0000000000..7ac1910151
--- /dev/null
+++ b/src/3rdparty/libpng.pri
@@ -0,0 +1,20 @@
+DEFINES *= QT_USE_BUNDLED_LIBPNG
+!isEqual(QT_ARCH, i386):!isEqual(QT_ARCH, x86_64):DEFINES += PNG_NO_ASSEMBLER_CODE
+INCLUDEPATH += $$PWD/libpng
+SOURCES += $$PWD/libpng/png.c \
+  $$PWD/libpng/pngerror.c \
+  $$PWD/libpng/pngget.c \
+  $$PWD/libpng/pngmem.c \
+  $$PWD/libpng/pngpread.c \
+  $$PWD/libpng/pngread.c \
+  $$PWD/libpng/pngrio.c \
+  $$PWD/libpng/pngrtran.c \
+  $$PWD/libpng/pngrutil.c \
+  $$PWD/libpng/pngset.c \
+  $$PWD/libpng/pngtrans.c \
+  $$PWD/libpng/pngwio.c \
+  $$PWD/libpng/pngwrite.c \
+  $$PWD/libpng/pngwtran.c \
+  $$PWD/libpng/pngwutil.c
+
+include($$PWD/zlib_dependency.pri)
diff --git a/src/3rdparty/libtiff.pri b/src/3rdparty/libtiff.pri
new file mode 100644
index 0000000000..5a522bea0b
--- /dev/null
+++ b/src/3rdparty/libtiff.pri
@@ -0,0 +1,43 @@
+INCLUDEPATH += $$PWD/libtiff/libtiff
+SOURCES += \
+    $$PWD/libtiff/libtiff/tif_aux.c \
+    $$PWD/libtiff/libtiff/tif_close.c \
+    $$PWD/libtiff/libtiff/tif_codec.c \
+    $$PWD/libtiff/libtiff/tif_color.c \
+    $$PWD/libtiff/libtiff/tif_compress.c \
+    $$PWD/libtiff/libtiff/tif_dir.c \
+    $$PWD/libtiff/libtiff/tif_dirinfo.c \
+    $$PWD/libtiff/libtiff/tif_dirread.c \
+    $$PWD/libtiff/libtiff/tif_dirwrite.c \
+    $$PWD/libtiff/libtiff/tif_dumpmode.c \
+    $$PWD/libtiff/libtiff/tif_error.c \
+    $$PWD/libtiff/libtiff/tif_extension.c \
+    $$PWD/libtiff/libtiff/tif_fax3.c \
+    $$PWD/libtiff/libtiff/tif_fax3sm.c \
+    $$PWD/libtiff/libtiff/tif_flush.c \
+    $$PWD/libtiff/libtiff/tif_getimage.c \
+    $$PWD/libtiff/libtiff/tif_luv.c \
+    $$PWD/libtiff/libtiff/tif_lzw.c \
+    $$PWD/libtiff/libtiff/tif_next.c \
+    $$PWD/libtiff/libtiff/tif_open.c \
+    $$PWD/libtiff/libtiff/tif_packbits.c \
+    $$PWD/libtiff/libtiff/tif_pixarlog.c \
+    $$PWD/libtiff/libtiff/tif_predict.c \
+    $$PWD/libtiff/libtiff/tif_print.c \
+    $$PWD/libtiff/libtiff/tif_read.c \
+    $$PWD/libtiff/libtiff/tif_strip.c \
+    $$PWD/libtiff/libtiff/tif_swab.c \
+    $$PWD/libtiff/libtiff/tif_thunder.c \
+    $$PWD/libtiff/libtiff/tif_tile.c \
+    $$PWD/libtiff/libtiff/tif_version.c \
+    $$PWD/libtiff/libtiff/tif_warning.c \
+    $$PWD/libtiff/libtiff/tif_write.c \
+    $$PWD/libtiff/libtiff/tif_zip.c
+
+wince*:       SOURCES += $$PWD/../corelib/kernel/qfunctions_wince.cpp \
+                         $$PWD/libtiff/libtiff/tif_wince.c
+win32:        SOURCES += $$PWD/libtiff/libtiff/tif_win32.c
+else:unix:    SOURCES += $$PWD/libtiff/libtiff/tif_unix.c
+else:symbian: SOURCES += $$PWD/libtiff/port/lfind.c
+
+include($$PWD/zlib_dependency.pri)
diff --git a/src/3rdparty/zlib_dependency.pri b/src/3rdparty/zlib_dependency.pri
new file mode 100644
index 0000000000..042eb1373f
--- /dev/null
+++ b/src/3rdparty/zlib_dependency.pri
@@ -0,0 +1,8 @@
+# zlib dependency satisfied by bundled 3rd party zlib or system zlib
+contains(QT_CONFIG, system-zlib) {
+    symbian:                 LIBS_PRIVATE += -llibz
+    else:if(unix|win32-g++*):LIBS_PRIVATE += -lz
+    else:                    LIBS += zdll.lib
+} else {
+    INCLUDEPATH +=  $$PWD/zlib
+}
diff --git a/src/gui/image/image.pri b/src/gui/image/image.pri
index f1b02b01a9..9f0c87ebf4 100644
--- a/src/gui/image/image.pri
+++ b/src/gui/image/image.pri
@@ -85,42 +85,10 @@ SOURCES += \
         image/qxbmhandler.cpp \
         image/qxpmhandler.cpp
 
-# 3rd party / system PNG support
-!contains(QT_CONFIG, no-png) {
-    HEADERS += image/qpnghandler_p.h
-    SOURCES += image/qpnghandler.cpp
+!contains(QT_CONFIG, no-png):include($$PWD/qpnghandler.pri)
+else:DEFINES *= QT_NO_IMAGEFORMAT_PNG
 
-    contains(QT_CONFIG, system-png) {
-        unix|win32-g++*:LIBS_PRIVATE  += -lpng
-        win32:!win32-g++*:LIBS += libpng.lib
-    } else {
-        DEFINES *= QT_USE_BUNDLED_LIBPNG
-        !isEqual(QT_ARCH, i386):!isEqual(QT_ARCH, x86_64):DEFINES += PNG_NO_ASSEMBLER_CODE
-        INCLUDEPATH += ../3rdparty/libpng
-        SOURCES += ../3rdparty/libpng/png.c \
-          ../3rdparty/libpng/pngerror.c \
-          ../3rdparty/libpng/pngget.c \
-          ../3rdparty/libpng/pngmem.c \
-          ../3rdparty/libpng/pngpread.c \
-          ../3rdparty/libpng/pngread.c \
-          ../3rdparty/libpng/pngrio.c \
-          ../3rdparty/libpng/pngrtran.c \
-          ../3rdparty/libpng/pngrutil.c \
-          ../3rdparty/libpng/pngset.c \
-          ../3rdparty/libpng/pngtrans.c \
-          ../3rdparty/libpng/pngwio.c \
-          ../3rdparty/libpng/pngwrite.c \
-          ../3rdparty/libpng/pngwtran.c \
-          ../3rdparty/libpng/pngwutil.c
-
-        contains(QT_CONFIG, system-zlib) {
-            symbian:LIBS_PRIVATE += -llibz
-            else:if(unix|win32-g++*):LIBS_PRIVATE += -lz
-            else:LIBS += zdll.lib
-        } else {
-            INCLUDEPATH  += ../3rdparty/zlib
-        }
-    }
-} else {
-    DEFINES *= QT_NO_IMAGEFORMAT_PNG
-}
+contains(QT_CONFIG, jpeg):include($$PWD/qjpeghandler.pri)
+contains(QT_CONFIG, mng):include($$PWD/qmnghandler.pri)
+contains(QT_CONFIG, tiff):include($$PWD/qtiffhandler.pri)
+contains(QT_CONFIG, gif):include($$PWD/qgifhandler.pri)
diff --git a/src/plugins/imageformats/gif/qgifhandler.cpp b/src/gui/image/qgifhandler.cpp
index 129a11b591..129a11b591 100644
--- a/src/plugins/imageformats/gif/qgifhandler.cpp
+++ b/src/gui/image/qgifhandler.cpp
diff --git a/src/plugins/imageformats/gif/qgifhandler.h b/src/gui/image/qgifhandler.h
index 8e07aff931..8e07aff931 100644
--- a/src/plugins/imageformats/gif/qgifhandler.h
+++ b/src/gui/image/qgifhandler.h
diff --git a/src/gui/image/qgifhandler.pri b/src/gui/image/qgifhandler.pri
new file mode 100644
index 0000000000..003476a8ce
--- /dev/null
+++ b/src/gui/image/qgifhandler.pri
@@ -0,0 +1,4 @@
+# common to plugin and built-in forms
+INCLUDEPATH *= $$PWD
+HEADERS += $$PWD/qgifhandler.h
+SOURCES += $$PWD/qgifhandler.cpp
diff --git a/src/plugins/imageformats/jpeg/qjpeghandler.cpp b/src/gui/image/qjpeghandler.cpp
index 60e7cce913..60e7cce913 100644
--- a/src/plugins/imageformats/jpeg/qjpeghandler.cpp
+++ b/src/gui/image/qjpeghandler.cpp
diff --git a/src/plugins/imageformats/jpeg/qjpeghandler.h b/src/gui/image/qjpeghandler.h
index c879f21c8a..c879f21c8a 100644
--- a/src/plugins/imageformats/jpeg/qjpeghandler.h
+++ b/src/gui/image/qjpeghandler.h
diff --git a/src/gui/image/qjpeghandler.pri b/src/gui/image/qjpeghandler.pri
new file mode 100644
index 0000000000..28ec7dc1fa
--- /dev/null
+++ b/src/gui/image/qjpeghandler.pri
@@ -0,0 +1,10 @@
+# common to plugin and built-in forms
+INCLUDEPATH *= $$PWD
+HEADERS += $$PWD/qjpeghandler.h
+SOURCES += $$PWD/qjpeghandler.cpp
+contains(QT_CONFIG, system-jpeg) {
+    if(unix|win32-g++*): LIBS += -ljpeg
+    else:win32:          LIBS += libjpeg.lib
+} else {
+    include($$PWD/../../3rdparty/libjpeg.pri)
+}
diff --git a/src/plugins/imageformats/mng/qmnghandler.cpp b/src/gui/image/qmnghandler.cpp
index ec442a19cc..ec442a19cc 100644
--- a/src/plugins/imageformats/mng/qmnghandler.cpp
+++ b/src/gui/image/qmnghandler.cpp
diff --git a/src/plugins/imageformats/mng/qmnghandler.h b/src/gui/image/qmnghandler.h
index 65243bee16..65243bee16 100644
--- a/src/plugins/imageformats/mng/qmnghandler.h
+++ b/src/gui/image/qmnghandler.h
diff --git a/src/gui/image/qmnghandler.pri b/src/gui/image/qmnghandler.pri
new file mode 100644
index 0000000000..ec1c19e1fe
--- /dev/null
+++ b/src/gui/image/qmnghandler.pri
@@ -0,0 +1,10 @@
+# common to plugin and built-in forms
+INCLUDEPATH *= $$PWD
+HEADERS += $$PWD/qmnghandler.h
+SOURCES += $$PWD/qmnghandler.cpp
+contains(QT_CONFIG, system-mng) {
+        if(unix|win32-g++*):LIBS += -lmng
+        else:win32:         LIBS += libmng.lib
+} else {
+    include($$PWD/../../3rdparty/libmng.pri)
+}
diff --git a/src/gui/image/qpnghandler.pri b/src/gui/image/qpnghandler.pri
new file mode 100644
index 0000000000..bedf23ff12
--- /dev/null
+++ b/src/gui/image/qpnghandler.pri
@@ -0,0 +1,10 @@
+INCLUDEPATH *= $$PWD
+HEADERS += $$PWD/qpnghandler_p.h
+SOURCES += $$PWD/qpnghandler.cpp
+contains(QT_CONFIG, system-png) {
+    if(unix|win32-g++*): LIBS_PRIVATE  += -lpng
+    else:win32:          LIBS += libpng.lib
+
+} else {
+    include($$PWD/../../3rdparty/libpng.pri)
+}
diff --git a/src/plugins/imageformats/tiff/qtiffhandler.cpp b/src/gui/image/qtiffhandler.cpp
index 619aa4ee26..619aa4ee26 100644
--- a/src/plugins/imageformats/tiff/qtiffhandler.cpp
+++ b/src/gui/image/qtiffhandler.cpp
diff --git a/src/plugins/imageformats/tiff/qtiffhandler.h b/src/gui/image/qtiffhandler.h
index 4534ed53e3..4534ed53e3 100644
--- a/src/plugins/imageformats/tiff/qtiffhandler.h
+++ b/src/gui/image/qtiffhandler.h
diff --git a/src/gui/image/qtiffhandler.pri b/src/gui/image/qtiffhandler.pri
new file mode 100644
index 0000000000..8ac70d9685
--- /dev/null
+++ b/src/gui/image/qtiffhandler.pri
@@ -0,0 +1,10 @@
+# common to plugin and built-in forms
+INCLUDEPATH *= $$PWD
+HEADERS += $$PWD/qtiffhandler.h
+SOURCES += $$PWD/qtiffhandler.cpp
+contains(QT_CONFIG, system-tiff) {
+        if(unix|win32-g++*):LIBS += -ltiff
+        else:win32:         LIBS += libtiff.lib
+} else {
+    include($$PWD/../../3rdparty/libtiff.pri)
+}
diff --git a/src/plugins/imageformats/gif/gif.pro b/src/plugins/imageformats/gif/gif.pro
index 8a5c51a587..439b43136c 100644
--- a/src/plugins/imageformats/gif/gif.pro
+++ b/src/plugins/imageformats/gif/gif.pro
@@ -1,9 +1,8 @@
 TARGET  = qgif
 include(../../qpluginbase.pri)
 
-HEADERS += qgifhandler.h
-SOURCES += main.cpp \
-           qgifhandler.cpp
+include(../../../gui/image/qgifhandler.pri)
+SOURCES += $$PWD/main.cpp
 
 QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/imageformats
 target.path += $$[QT_INSTALL_PLUGINS]/imageformats
diff --git a/src/plugins/imageformats/jpeg/jpeg.pro b/src/plugins/imageformats/jpeg/jpeg.pro
index d4b0fef4ea..c5671c3a63 100644
--- a/src/plugins/imageformats/jpeg/jpeg.pro
+++ b/src/plugins/imageformats/jpeg/jpeg.pro
@@ -3,10 +3,6 @@ include(../../qpluginbase.pri)
 
 QTDIR_build:REQUIRES = "!contains(QT_CONFIG, no-jpeg)"
 
-HEADERS += qjpeghandler.h
-SOURCES += main.cpp \
-           qjpeghandler.cpp
-
 wince*: {
     DEFINES += NO_GETENV
     contains(CE_ARCH,x86):CONFIG -= stl exceptions
@@ -21,61 +17,9 @@ symbian: {
     QMAKE_CFLAGS_WARN_ON += -Wno-unused-parameter -Wno-main
 }
 
-contains(QT_CONFIG, system-jpeg) {
-        unix|win32-g++*:LIBS += -ljpeg
-        win32:!win32-g++*:LIBS += libjpeg.lib
-} else {
-	INCLUDEPATH += ../../../3rdparty/libjpeg
-	SOURCES  += \
-	    ../../../3rdparty/libjpeg/jaricom.c \
-	    ../../../3rdparty/libjpeg/jcapimin.c \
-	    ../../../3rdparty/libjpeg/jcapistd.c \
-	    ../../../3rdparty/libjpeg/jcarith.c \
-	    ../../../3rdparty/libjpeg/jccoefct.c \
-	    ../../../3rdparty/libjpeg/jccolor.c \
-	    ../../../3rdparty/libjpeg/jcdctmgr.c \
-	    ../../../3rdparty/libjpeg/jchuff.c \
-	    ../../../3rdparty/libjpeg/jcinit.c \
-	    ../../../3rdparty/libjpeg/jcmainct.c \
-	    ../../../3rdparty/libjpeg/jcmarker.c \
-	    ../../../3rdparty/libjpeg/jcmaster.c \
-	    ../../../3rdparty/libjpeg/jcomapi.c \
-	    ../../../3rdparty/libjpeg/jcparam.c \
-	    ../../../3rdparty/libjpeg/jcprepct.c \
-	    ../../../3rdparty/libjpeg/jcsample.c \
-	    ../../../3rdparty/libjpeg/jctrans.c \
-	    ../../../3rdparty/libjpeg/jdapimin.c \
-	    ../../../3rdparty/libjpeg/jdapistd.c \
-	    ../../../3rdparty/libjpeg/jdarith.c \
-	    ../../../3rdparty/libjpeg/jdatadst.c \
-	    ../../../3rdparty/libjpeg/jdatasrc.c \
-	    ../../../3rdparty/libjpeg/jdcoefct.c \
-	    ../../../3rdparty/libjpeg/jdcolor.c \
-	    ../../../3rdparty/libjpeg/jddctmgr.c \
-	    ../../../3rdparty/libjpeg/jdhuff.c \
-	    ../../../3rdparty/libjpeg/jdinput.c \
-	    ../../../3rdparty/libjpeg/jdmainct.c \
-	    ../../../3rdparty/libjpeg/jdmarker.c \
-	    ../../../3rdparty/libjpeg/jdmaster.c \
-	    ../../../3rdparty/libjpeg/jdmerge.c \
-	    ../../../3rdparty/libjpeg/jdpostct.c \
-	    ../../../3rdparty/libjpeg/jdsample.c \
-	    ../../../3rdparty/libjpeg/jdtrans.c \
-	    ../../../3rdparty/libjpeg/jerror.c \
-	    ../../../3rdparty/libjpeg/jfdctflt.c \
-	    ../../../3rdparty/libjpeg/jfdctfst.c \
-	    ../../../3rdparty/libjpeg/jfdctint.c \
-	    ../../../3rdparty/libjpeg/jidctflt.c \
-	    ../../../3rdparty/libjpeg/jidctfst.c \
-	    ../../../3rdparty/libjpeg/jidctint.c \
-	    ../../../3rdparty/libjpeg/jquant1.c \
-	    ../../../3rdparty/libjpeg/jquant2.c \
-	    ../../../3rdparty/libjpeg/jutils.c \
-	    ../../../3rdparty/libjpeg/jmemmgr.c \
-	    ../../../3rdparty/libjpeg/jmemnobs.c
-}
+include(../../../gui/image/qjpeghandler.pri)
+SOURCES += main.cpp
 
 QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/imageformats
 target.path += $$[QT_INSTALL_PLUGINS]/imageformats
 INSTALLS += target
-
diff --git a/src/plugins/imageformats/mng/mng.pro b/src/plugins/imageformats/mng/mng.pro
index 1f3ad53a47..88085f363c 100644
--- a/src/plugins/imageformats/mng/mng.pro
+++ b/src/plugins/imageformats/mng/mng.pro
@@ -3,54 +3,15 @@ include(../../qpluginbase.pri)
 
 QTDIR_build:REQUIRES = "!contains(QT_CONFIG, no-mng)"
 
-HEADERS += qmnghandler.h
-SOURCES += main.cpp \
-           qmnghandler.cpp
-
 symbian: {
         #Disable warnings in 3rdparty code due to unused variables and arguments
         QMAKE_CXXFLAGS.CW += -W nounused
         TARGET.UID3=0x2001E619
 }
 
-contains(QT_CONFIG, system-mng) {
-        unix|win32-g++*:LIBS += -lmng
-        win32:!win32-g++*:LIBS += libmng.lib
-} else {
-    DEFINES += MNG_BUILD_SO
-    DEFINES += MNG_NO_INCLUDE_JNG
-    INCLUDEPATH += ../../../3rdparty/libmng
-    SOURCES  += \
-        ../../../3rdparty/libmng/libmng_callback_xs.c \
-        ../../../3rdparty/libmng/libmng_chunk_io.c \
-        ../../../3rdparty/libmng/libmng_chunk_descr.c \
-        ../../../3rdparty/libmng/libmng_chunk_prc.c \
-        ../../../3rdparty/libmng/libmng_chunk_xs.c \
-        ../../../3rdparty/libmng/libmng_cms.c \
-        ../../../3rdparty/libmng/libmng_display.c \
-        ../../../3rdparty/libmng/libmng_dither.c \
-        ../../../3rdparty/libmng/libmng_error.c \
-        ../../../3rdparty/libmng/libmng_filter.c \
-        ../../../3rdparty/libmng/libmng_hlapi.c \
-        ../../../3rdparty/libmng/libmng_jpeg.c \
-        ../../../3rdparty/libmng/libmng_object_prc.c \
-        ../../../3rdparty/libmng/libmng_pixels.c \
-        ../../../3rdparty/libmng/libmng_prop_xs.c \
-        ../../../3rdparty/libmng/libmng_read.c \
-        ../../../3rdparty/libmng/libmng_trace.c \
-        ../../../3rdparty/libmng/libmng_write.c \
-        ../../../3rdparty/libmng/libmng_zlib.c
-
-    contains(QT_CONFIG, system-zlib) {
-        symbian:LIBS_PRIVATE += -llibz
-        else:if(unix|win32-g++*):LIBS_PRIVATE += -lz
-        else:LIBS += zdll.lib
-    } else {
-        INCLUDEPATH +=  ../../../3rdparty/zlib
-    }
-}
+include(../../../gui/image/qmnghandler.pri)
+SOURCES += main.cpp
 
 QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/imageformats
 target.path += $$[QT_INSTALL_PLUGINS]/imageformats
 INSTALLS += target
-
diff --git a/src/plugins/imageformats/tiff/tiff.pro b/src/plugins/imageformats/tiff/tiff.pro
index 49d635e4af..e78152611c 100644
--- a/src/plugins/imageformats/tiff/tiff.pro
+++ b/src/plugins/imageformats/tiff/tiff.pro
@@ -3,72 +3,8 @@ include(../../qpluginbase.pri)
 
 QTDIR_build:REQUIRES = "!contains(QT_CONFIG, no-tiff)"
 
-HEADERS += qtiffhandler.h
-SOURCES += main.cpp \
-           qtiffhandler.cpp
-
-contains(QT_CONFIG, system-tiff) {
-        unix|win32-g++*:LIBS += -ltiff
-        win32:!win32-g++*:LIBS += libtiff.lib
-} else {
-    INCLUDEPATH += ../../../3rdparty/libtiff/libtiff
-    SOURCES  += \
-        ../../../3rdparty/libtiff/libtiff/tif_aux.c \
-        ../../../3rdparty/libtiff/libtiff/tif_close.c \
-        ../../../3rdparty/libtiff/libtiff/tif_codec.c \
-        ../../../3rdparty/libtiff/libtiff/tif_color.c \
-        ../../../3rdparty/libtiff/libtiff/tif_compress.c \
-        ../../../3rdparty/libtiff/libtiff/tif_dir.c \
-        ../../../3rdparty/libtiff/libtiff/tif_dirinfo.c \
-        ../../../3rdparty/libtiff/libtiff/tif_dirread.c \
-        ../../../3rdparty/libtiff/libtiff/tif_dirwrite.c \
-        ../../../3rdparty/libtiff/libtiff/tif_dumpmode.c \
-        ../../../3rdparty/libtiff/libtiff/tif_error.c \
-        ../../../3rdparty/libtiff/libtiff/tif_extension.c \
-        ../../../3rdparty/libtiff/libtiff/tif_fax3.c \
-        ../../../3rdparty/libtiff/libtiff/tif_fax3sm.c \
-        ../../../3rdparty/libtiff/libtiff/tif_flush.c \
-        ../../../3rdparty/libtiff/libtiff/tif_getimage.c \
-        ../../../3rdparty/libtiff/libtiff/tif_luv.c \
-        ../../../3rdparty/libtiff/libtiff/tif_lzw.c \
-        ../../../3rdparty/libtiff/libtiff/tif_next.c \
-        ../../../3rdparty/libtiff/libtiff/tif_open.c \
-        ../../../3rdparty/libtiff/libtiff/tif_packbits.c \
-        ../../../3rdparty/libtiff/libtiff/tif_pixarlog.c \
-        ../../../3rdparty/libtiff/libtiff/tif_predict.c \
-        ../../../3rdparty/libtiff/libtiff/tif_print.c \
-        ../../../3rdparty/libtiff/libtiff/tif_read.c \
-        ../../../3rdparty/libtiff/libtiff/tif_strip.c \
-        ../../../3rdparty/libtiff/libtiff/tif_swab.c \
-        ../../../3rdparty/libtiff/libtiff/tif_thunder.c \
-        ../../../3rdparty/libtiff/libtiff/tif_tile.c \
-        ../../../3rdparty/libtiff/libtiff/tif_version.c \
-        ../../../3rdparty/libtiff/libtiff/tif_warning.c \
-        ../../../3rdparty/libtiff/libtiff/tif_write.c \
-        ../../../3rdparty/libtiff/libtiff/tif_zip.c
-        win32:!wince*: {
-            SOURCES += ../../../3rdparty/libtiff/libtiff/tif_win32.c
-        }
-        unix: {
-          SOURCES += ../../../3rdparty/libtiff/libtiff/tif_unix.c
-        }
-        wince*: {
-            SOURCES += ../../../corelib/kernel/qfunctions_wince.cpp \
-                       ../../../3rdparty/libtiff/libtiff/tif_wince.c \
-                       ../../../3rdparty/libtiff/libtiff/tif_win32.c
-        }
-        symbian: {
-            SOURCES += ../../../3rdparty/libtiff/port/lfind.c
-        }
-
-    contains(QT_CONFIG, system-zlib) {
-        symbian:LIBS_PRIVATE += -llibz
-        else:if(unix|win32-g++*):LIBS_PRIVATE += -lz
-        else:LIBS += zdll.lib
-    } else {
-        INCLUDEPATH +=  ../../../3rdparty/zlib
-    }
-}
+include(../../../gui/image/qtiffhandler.pri)
+SOURCES += main.cpp
 
 QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/imageformats
 target.path += $$[QT_INSTALL_PLUGINS]/imageformats
diff --git a/tools/configure/configureapp.cpp b/tools/configure/configureapp.cpp
index c3de09ec26..70668c0527 100644
--- a/tools/configure/configureapp.cpp
+++ b/tools/configure/configureapp.cpp
@@ -1751,7 +1751,7 @@ bool Configure::displayHelp()
         desc("ZLIB", "system",  "-system-zlib",         "Use zlib from the operating system.\nSee http://www.gzip.org/zlib\n");
 
         desc("GIF", "no",       "-no-gif",              "Do not compile the plugin for GIF reading support.");
-        desc("GIF", "auto",     "-qt-gif",              "Compile the plugin for GIF reading support.\nSee also src/plugins/imageformats/gif/qgifhandler.h\n");
+        desc("GIF", "auto",     "-qt-gif",              "Compile the plugin for GIF reading support.\nSee also src/gui/image/qgifhandler.h\n");
 
         desc("LIBPNG", "no",    "-no-libpng",           "Do not compile in PNG support.");
         desc("LIBPNG", "qt",    "-qt-libpng",           "Use the libpng bundled with Qt.");