blob: ad64cea6d52ad97e43808f0424b388f122b9a366 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
include(../../library_dirname.pri)
include(../../shared/variant/variant.pri)
isEmpty(QBSLIBDIR) {
QBSLIBDIR = $${OUT_PWD}/../../../$${QBS_LIBRARY_DIRNAME}
}
QBSPKGCONFIG_LIBNAME=qbspkgconfig
unix {
LIBS += -L$${QBSLIBDIR} -l$${QBSPKGCONFIG_LIBNAME}
}
win32 {
CONFIG(debug, debug|release) {
QBSPKGCONFIG_LIB = $${QBSPKGCONFIG_LIBNAME}d
}
CONFIG(release, debug|release) {
QBSPKGCONFIG_LIB = $${QBSPKGCONFIG_LIBNAME}
}
msvc {
LIBS += /LIBPATH:$$QBSLIBDIR
QBSPKGCONFIG_LIB = $${QBSPKGCONFIG_LIB}.lib
LIBS += Shell32.lib
} else {
LIBS += -L$${QBSLIBDIR}
QBSPKGCONFIG_LIB = lib$${QBSPKGCONFIG_LIB}
}
LIBS += $${QBSPKGCONFIG_LIB}
}
gcc {
isEmpty(COMPILER_VERSION) {
COMPILER_VERSION = $$system($$QMAKE_CXX " -dumpversion")
COMPILER_MAJOR_VERSION = $$str_member($$COMPILER_VERSION)
lessThan(COMPILER_MAJOR_VERSION, 9) {
LIBS += -lstdc++fs
}
}
}
INCLUDEPATH += \
$$PWD
CONFIG += depend_includepath
CONFIG(static, static|shared) {
DEFINES += QBS_STATIC_LIB
}
DEFINES += \
QBS_PC_WITH_QT_SUPPORT=1
|
