1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
|
C nettle, low-level cryptographics library
C
C Copyright (C) 2001, 2002 Rafael R. Sevilla, Niels Möller
C
C The nettle library is free software; you can redistribute it and/or modify
C it under the terms of the GNU Lesser General Public License as published by
C the Free Software Foundation; either version 2.1 of the License, or (at your
C option) any later version.
C
C The nettle library is distributed in the hope that it will be useful, but
C WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
C or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
C License for more details.
C
C You should have received a copy of the GNU Lesser General Public License
C along with the nettle library; see the file COPYING.LIB. If not, write to
C the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
C MA 02111-1307, USA.
.file "aes-decrypt.asm"
C aes_decrypt(struct aes_context *ctx,
C unsigned length, uint8_t *dst,
C uint8_t *src)
.align 16
.globl aes_decrypt
.type aes_decrypt,@function
aes_decrypt:
C // save all registers that need to be saved
pushl %ebx C 16(%esp)
pushl %ebp C 12(%esp)
pushl %esi C 8(%esp)
pushl %edi C 4(%esp)
C ctx = 20(%esp)
C length = 24(%esp)
C dst = 28(%esp)
C src = 32(%esp)
movl 24(%esp), %ebp
C What's the right way to set the flags?
addl $0, %ebp
jz .Ldecrypt_end
.Ldecrypt_block_loop:
movl 32(%esp),%esi C address of ciphertext
movl (%esi),%eax C load ciphertext into registers
movl 4(%esi),%ebx
movl 8(%esi),%ecx
movl 12(%esi),%edx
addl $16, 32(%esp) C Increment src pointer
movl 20(%esp),%esi C address of context struct ctx
xorl (%esi),%eax C add first key to ciphertext
xorl 4(%esi),%ebx
xorl 8(%esi),%ecx
xorl 12(%esi),%edx
movl AES_NROUNDS (%esi),%ebp C get number of rounds to do from struct
C shll $4,%ebp
C leal 240(%esi, %ebp),%esi
C shrl $4,%ebp
C xorl (%esi),%eax C add last key to ciphertext
C xorl 4(%esi),%ebx
C xorl 8(%esi),%ecx
C xorl 12(%esi),%edx
subl $1,%ebp C one round is complete
addl $16,%esi C point to next key
.Ldecrypt_loop:
pushl %esi C save this first: we'll clobber it later
C Why???
xchgl %ebx,%edx
C // First column
C a b c d
movl %eax,%esi C copy first in
andl $0x000000ff,%esi C clear all but offset
shll $2,%esi C index in itbl1
movl AES_TABLE0 + _aes_decrypt_table (%esi),%edi
movl %ebx,%esi C second one
shrl $6,%esi
andl $0x000003fc,%esi C clear all but offset bytes
xorl AES_TABLE1 + _aes_decrypt_table (%esi),%edi
movl %ecx,%esi C third one
shrl $14,%esi
andl $0x000003fc,%esi
xorl AES_TABLE2 + _aes_decrypt_table (%esi),%edi
movl %edx,%esi C fourth one
shrl $22,%esi
andl $0x000003fc,%esi
xorl AES_TABLE3 + _aes_decrypt_table (%esi),%edi
pushl %edi C save first on stack
C // Second column
C d a b c
movl %edx,%esi C copy first in
andl $0x000000ff,%esi C clear all but offset
shll $2,%esi C index in itbl1
movl AES_TABLE0 + _aes_decrypt_table (%esi),%edi
movl %eax,%esi C second one
shrl $6,%esi
andl $0x000003fc,%esi C clear all but offset bytes
xorl AES_TABLE1 + _aes_decrypt_table (%esi),%edi
movl %ebx,%esi C third one
shrl $14,%esi
andl $0x000003fc,%esi
xorl AES_TABLE2 + _aes_decrypt_table (%esi),%edi
movl %ecx,%esi C fourth one
shrl $22,%esi
andl $0x000003fc,%esi
xorl AES_TABLE3 + _aes_decrypt_table (%esi),%edi
pushl %edi
C // Third column
C c d a b
movl %ecx,%esi C copy first in
andl $0x000000ff,%esi C clear all but offset
shll $2,%esi C index in itbl1
movl AES_TABLE0 + _aes_decrypt_table (%esi),%edi
movl %edx,%esi C second one
shrl $6,%esi
andl $0x000003fc,%esi C clear all but offset bytes
xorl AES_TABLE1 + _aes_decrypt_table (%esi),%edi
movl %eax,%esi C third one
shrl $14,%esi
andl $0x000003fc,%esi
xorl AES_TABLE2 + _aes_decrypt_table (%esi),%edi
movl %ebx,%esi C fourth one
shrl $22,%esi
andl $0x000003fc,%esi
xorl AES_TABLE3 + _aes_decrypt_table (%esi),%edi
pushl %edi C save first on stack
C // Fourth column
C b c d a
movl %ebx,%esi C copy first in
andl $0x000000ff,%esi C clear all but offset
shll $2,%esi C index in itbl1
movl AES_TABLE0 + _aes_decrypt_table (%esi),%edi
movl %ecx,%esi C second one
shrl $6,%esi
andl $0x000003fc,%esi C clear all but offset bytes
xorl AES_TABLE1 + _aes_decrypt_table (%esi),%edi
movl %edx,%esi C third one
shrl $14,%esi
andl $0x000003fc,%esi
xorl AES_TABLE2 + _aes_decrypt_table (%esi),%edi
movl %eax,%esi C fourth one
shrl $22,%esi
andl $0x000003fc,%esi
xorl AES_TABLE3 + _aes_decrypt_table (%esi),%edi
movl %edi,%edx
popl %ecx
popl %ebx
popl %eax
popl %esi
xorl (%esi),%eax C add current session key to plaintext
xorl 4(%esi),%ebx
xorl 8(%esi),%ecx
xorl 12(%esi),%edx
addl $16,%esi C point to next key
decl %ebp
jnz .Ldecrypt_loop
C Foo?
xchgl %ebx,%edx
C // last round
C // first column
C a b c d
movl %eax,%edi
andl $0x000000ff,%edi
movl %ebx,%ebp
andl $0x0000ff00,%ebp
orl %ebp,%edi
movl %ecx,%ebp
andl $0x00ff0000,%ebp
orl %ebp,%edi
movl %edx,%ebp
andl $0xff000000,%ebp
orl %ebp,%edi
pushl %edi
C // second column
C b c d a
movl %eax,%edi
andl $0xff000000,%edi
movl %ebx,%ebp
andl $0x000000ff,%ebp
orl %ebp,%edi
movl %ecx,%ebp
andl $0x0000ff00,%ebp
orl %ebp,%edi
movl %edx,%ebp
andl $0x00ff0000,%ebp
orl %ebp,%edi
pushl %edi
C // third column
C c d a b
movl %eax,%edi
andl $0x00ff0000,%edi
movl %ebx,%ebp
andl $0xff000000,%ebp
orl %ebp,%edi
movl %ecx,%ebp
andl $0x000000ff,%ebp
orl %ebp,%edi
movl %edx,%ebp
andl $0x0000ff00,%ebp
orl %ebp,%edi
pushl %edi
C // fourth column
C d a b c
movl %eax,%edi
andl $0x0000ff00,%edi
movl %ebx,%ebp
andl $0x00ff0000,%ebp
orl %ebp,%edi
movl %ecx,%ebp
andl $0xff000000,%ebp
orl %ebp,%edi
movl %edx,%ebp
andl $0x000000ff,%ebp
orl %ebp,%edi
movl %edi,%edx
popl %ecx
popl %ebx
popl %eax
xchgl %ebx,%edx
C // inverse S-box substitution
mov $4,%edi
.Lisubst:
movl %eax,%ebp
andl $0x000000ff,%ebp
movb AES_SBOX + _aes_decrypt_table (%ebp),%al
roll $8,%eax
movl %ebx,%ebp
andl $0x000000ff,%ebp
movb AES_SBOX + _aes_decrypt_table (%ebp),%bl
roll $8,%ebx
movl %ecx,%ebp
andl $0x000000ff,%ebp
movb AES_SBOX + _aes_decrypt_table (%ebp),%cl
roll $8,%ecx
movl %edx,%ebp
andl $0x000000ff,%ebp
movb AES_SBOX + _aes_decrypt_table (%ebp),%dl
roll $8,%edx
decl %edi
jnz .Lisubst
xorl (%esi),%eax C add last key to plaintext
xorl 4(%esi),%ebx
xorl 8(%esi),%ecx
xorl 12(%esi),%edx
C // store decrypted data back to caller's buffer
movl 28(%esp),%edi
movl %eax,(%edi)
movl %ebx,4(%edi)
movl %ecx,8(%edi)
movl %edx,12(%edi)
addl $16, 28(%esp) C Increment destination pointer
subl $16, 24(%esp)
jnz .Ldecrypt_block_loop
.Ldecrypt_end:
popl %edi
popl %esi
popl %ebp
popl %ebx
ret
.eord:
.size aes_decrypt,.eord-aes_decrypt
|
