WL#5665: Removal of the autotools-based build system

The autotools-based build system has been superseded and
is being removed in order to ease the maintenance burden on
developers tweaking and maintaining the build system.

In order to support tools that need to extract the server
version, a new file that (only) contains the server version,
called VERSION, is introduced. The file contents are human
and machine-readable. The format is:

MYSQL_VERSION_MAJOR=5
MYSQL_VERSION_MINOR=5
MYSQL_VERSION_PATCH=8
MYSQL_VERSION_EXTRA=-rc

The CMake based version extraction in cmake/mysql_version.cmake
is changed to extract the version from this file. The configure
to CMake wrapper is retained for backwards compatibility and to
support the BUILD/ scripts. Also, a new a makefile target
show-dist-name that prints the server version is introduced.

VERSION:
  Add top-level version file.
cmake/mysql_version.cmake:
  Get version information from the top-level VERSION file.
  Do not cache the version components (MAJOR_VERSION, etc).
  Add MYSQL_RPM_VERSION as a replacement for MYSQL_U_SCORE_VERSION.

1 files changed, 0 insertions, 66 deletions

diff --git a/config/ac-macros/maintainer.m4 b/config/ac-macros/maintainer.m4
deleted file mode 100644
index b4d2f08e558..00000000000
--- a/config/ac-macros/maintainer.m4
+++ /dev/null
@@ -1,66 +0,0 @@
-#
-# Control aspects of the development environment which are
-# specific to MySQL maintainers and developers.
-#
-AC_DEFUN([MY_MAINTAINER_MODE], [
-  AC_MSG_CHECKING([whether to enable the maintainer-specific development environment])
-  AC_ARG_ENABLE([mysql-maintainer-mode],
-    [AS_HELP_STRING([--enable-mysql-maintainer-mode],
-                    [Enable a MySQL maintainer-specific development environment])],
-    [USE_MYSQL_MAINTAINER_MODE=$enableval],
-    [AS_IF([test "$with_debug" != "no"],
-      [USE_MYSQL_MAINTAINER_MODE=yes], [USE_MYSQL_MAINTAINER_MODE=no])])
-  AC_MSG_RESULT([$USE_MYSQL_MAINTAINER_MODE])
-])
-
-# Set warning options required under maintainer mode.
-AC_DEFUN([MY_MAINTAINER_MODE_WARNINGS], [
-  # Setup GCC warning options.
-  AS_IF([test "$GCC" = "yes"], [
-    C_WARNINGS="-Wall -Wextra -Wunused -Wwrite-strings -Wno-strict-aliasing -Werror"
-    CXX_WARNINGS="${C_WARNINGS} -Wno-unused-parameter"
-    C_WARNINGS="${C_WARNINGS} -Wdeclaration-after-statement"
-  ])
-
-  # Test whether the warning options work.
-  # Test C options
-  AS_IF([test -n "$C_WARNINGS"], [
-    save_CFLAGS="$CFLAGS"
-    AC_MSG_CHECKING([whether to use C warning options ${C_WARNINGS}])
-    AC_LANG_PUSH(C)
-    CFLAGS="$CFLAGS ${C_WARNINGS}"
-    AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [myac_c_warning_flags=yes],
-                      [myac_c_warning_flags=no])
-    AC_LANG_POP()
-    AC_MSG_RESULT([$myac_c_warning_flags])
-    CFLAGS="$save_CFLAGS"
-  ])
-
-  # Test C++ options
-  AS_IF([test -n "$CXX_WARNINGS"], [
-    save_CXXFLAGS="$CXXFLAGS"
-    AC_MSG_CHECKING([whether to use C++ warning options ${CXX_WARNINGS}])
-    AC_LANG_PUSH(C++)
-    CXXFLAGS="$CXXFLAGS ${CXX_WARNINGS}"
-    AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [myac_cxx_warning_flags=yes],
-                      [myac_cxx_warning_flags=no])
-    AC_LANG_POP()
-    AC_MSG_RESULT([$myac_cxx_warning_flags])
-    CXXFLAGS="$save_CXXFLAGS"
-  ])
-
-  # Set compile flag variables.
-  AS_IF([test "$myac_c_warning_flags" = "yes"], [
-    AM_CFLAGS="${AM_CFLAGS} ${C_WARNINGS}"
-    AC_SUBST([AM_CFLAGS])])
-  AS_IF([test "$myac_cxx_warning_flags" = "yes"], [
-    AM_CXXFLAGS="${AM_CXXFLAGS} ${CXX_WARNINGS}"
-    AC_SUBST([AM_CXXFLAGS])])
-])
-
-
-# Set compiler flags required under maintainer mode.
-AC_DEFUN([MY_MAINTAINER_MODE_SETUP], [
-  AS_IF([test "$USE_MYSQL_MAINTAINER_MODE" = "yes"],
-        [MY_MAINTAINER_MODE_WARNINGS])
-])