Hadrian: simple targets for building libraries and executables

This patch introduces (phony) build targets of the form

    (1) stage<N>:<lib>:<name>   (e.g: stage1:lib:Cabal)
    (2) stage<N>:<exe>:<name>   (e.g: stage2:exe:ghc-bin)

where (1) builds the given library with the stage N compiler and (2)
builds the given executable with the stage N-1 compiler. This patch may
be generating too many such targets but it's a first stab that we can
refine.

This fixes #15949.

Test Plan: hadrian/build.sh stage1:exe:ghc-bin

Reviewers: bgamari, snowleopard

Reviewed By: bgamari

Subscribers: rwbarton, carter

GHC Trac Issues: #15949

Differential Revision: https://phabricator.haskell.org/D5434

2 files changed, 51 insertions, 0 deletions

diff --git a/hadrian/src/Rules.hs b/hadrian/src/Rules.hs
index 69a151c206..e51dae4e07 100644
--- a/hadrian/src/Rules.hs
+++ b/hadrian/src/Rules.hs
@@ -20,6 +20,7 @@ import qualified Rules.Libffi
 import qualified Rules.Library
 import qualified Rules.Program
 import qualified Rules.Register
+import qualified Rules.SimpleTargets
 import Settings
 import Target
 import UserSettings
@@ -109,6 +110,7 @@ packageRules = do
     let vanillaContexts = liftM2 vanillaContext allStages knownPackages
 
     forM_ vanillaContexts Rules.Generate.generatePackageCode
+    Rules.SimpleTargets.simplePackageTargets
 
 buildRules :: Rules ()
 buildRules = do
diff --git a/hadrian/src/Rules/SimpleTargets.hs b/hadrian/src/Rules/SimpleTargets.hs
new file mode 100644
index 0000000000..d005043164
--- /dev/null
+++ b/hadrian/src/Rules/SimpleTargets.hs
@@ -0,0 +1,49 @@
+module Rules.SimpleTargets (simplePackageTargets) where
+
+import Base
+import Context
+import Packages
+import Settings
+
+import Data.Foldable
+
+-- | Simple aliases for library and executable targets.
+--
+--  - @stage<N>:lib:<name>@ will build library @name@ with
+--    the stage N compiler, putting the result under
+--    @<build root>/stage<N>/lib@.
+--  - @stage<N>:exe:<name>@ will build executable @name@
+--    with the stage N-1 compiler, putting the result under
+--    @<build root>/stage<N-1>/bin.
+simplePackageTargets :: Rules ()
+simplePackageTargets = traverse_ simpleTarget targets
+
+  where targets = [ (stage, target)
+                  | stage <- [minBound..maxBound]
+                  , target <- knownPackages
+                  ]
+
+simpleTarget :: (Stage, Package) -> Rules ()
+simpleTarget (stage, target) = do
+  let tgt = intercalate ":" [stagestr, typ, pkgname]
+  tgt ~> do
+    p <- getTargetPath stage target
+    need [ p ]
+
+  where typ = if isLibrary target then "lib" else "exe"
+        stagestr = stageString stage
+        pkgname = pkgName target
+
+getTargetPath :: Stage -> Package -> Action FilePath
+getTargetPath stage pkg
+  | isLibrary pkg = getLibraryPath stage pkg
+  | otherwise     = getProgramPath stage pkg
+
+getLibraryPath :: Stage -> Package -> Action FilePath
+getLibraryPath stage pkg = pkgConfFile (vanillaContext stage pkg)
+
+getProgramPath :: Stage -> Package -> Action FilePath
+getProgramPath Stage0 _ =
+  error ("Cannot build a stage 0 executable target: " ++
+         "it is the boot compiler's toolchain")
+getProgramPath stage pkg = programPath (vanillaContext (pred stage) pkg)