Add doctest examples for Data.Maybe

To actually *run* the doctests, you need to do a little
hacking. Somewhere after the `GHC.Base` import, you'll need to reimport
`Maybe(..)` from `Prelude`, clobbering the `GHC.Base` definition. After
that, doctest should be runnable from the `Data/` directory.

Reviewed By: austin, hvr

Differential Revision: https://phabricator.haskell.org/D561

1 files changed, 189 insertions, 0 deletions

diff --git a/libraries/base/Data/Maybe.hs b/libraries/base/Data/Maybe.hs
index 23d393da02..3d9a5a9f36 100644
--- a/libraries/base/Data/Maybe.hs
+++ b/libraries/base/Data/Maybe.hs
@@ -33,6 +33,10 @@ module Data.Maybe
 
 import GHC.Base
 
+-- $setup
+-- Allow the use of some Prelude functions in doctests.
+-- >>> import Prelude ( (*), odd, show, sum )
+
 -- ---------------------------------------------------------------------------
 -- Functions over Maybe
 
@@ -40,23 +44,105 @@ import GHC.Base
 -- value.  If the 'Maybe' value is 'Nothing', the function returns the
 -- default value.  Otherwise, it applies the function to the value inside
 -- the 'Just' and returns the result.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> maybe False odd (Just 3)
+-- True
+--
+-- >>> maybe False odd Nothing
+-- False
+--
+-- Read an integer from a string using 'readMaybe'. If we succeed,
+-- return twice the integer; that is, apply @(*2)@ to it. If instead
+-- we fail to parse an integer, return @0@ by default:
+--
+-- >>> import Text.Read ( readMaybe )
+-- >>> maybe 0 (*2) (readMaybe "5")
+-- 10
+-- >>> maybe 0 (*2) (readMaybe "")
+-- 0
+--
+-- Apply 'show' to a @Maybe Int@. If we have @Just n@, we want to show
+-- the underlying 'Int' @n@. But if we have 'Nothing', we return the
+-- empty string instead of (for example) \"Nothing\":
+--
+-- >>> maybe "" show (Just 5)
+-- "5"
+-- >>> maybe "" show Nothing
+-- ""
+--
 maybe :: b -> (a -> b) -> Maybe a -> b
 maybe n _ Nothing  = n
 maybe _ f (Just x) = f x
 
 -- | The 'isJust' function returns 'True' iff its argument is of the
 -- form @Just _@.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> isJust (Just 3)
+-- True
+--
+-- >>> isJust (Just ())
+-- True
+--
+-- >>> isJust Nothing
+-- False
+--
+-- Only the outer constructor is taken into consideration:
+--
+-- >>> isJust (Just Nothing)
+-- True
+--
 isJust         :: Maybe a -> Bool
 isJust Nothing = False
 isJust _       = True
 
 -- | The 'isNothing' function returns 'True' iff its argument is 'Nothing'.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> isNothing (Just 3)
+-- False
+--
+-- >>> isNothing (Just ())
+-- False
+--
+-- >>> isNothing Nothing
+-- True
+--
+-- Only the outer constructor is taken into consideration:
+--
+-- >>> isNothing (Just Nothing)
+-- False
+--
 isNothing         :: Maybe a -> Bool
 isNothing Nothing = True
 isNothing _       = False
 
 -- | The 'fromJust' function extracts the element out of a 'Just' and
 -- throws an error if its argument is 'Nothing'.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> fromJust (Just 1)
+-- 1
+--
+-- >>> 2 * (fromJust (Just 10))
+-- 20
+--
+-- >>> 2 * (fromJust Nothing)
+-- *** Exception: Maybe.fromJust: Nothing
+--
 fromJust          :: Maybe a -> a
 fromJust Nothing  = error "Maybe.fromJust: Nothing" -- yuck
 fromJust (Just x) = x
@@ -64,23 +150,108 @@ fromJust (Just x) = x
 -- | The 'fromMaybe' function takes a default value and and 'Maybe'
 -- value.  If the 'Maybe' is 'Nothing', it returns the default values;
 -- otherwise, it returns the value contained in the 'Maybe'.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> fromMaybe "" (Just "Hello, World!")
+-- "Hello, World!"
+--
+-- >>> fromMaybe "" Nothing
+-- ""
+--
+-- Read an integer from a string using 'readMaybe'. If we fail to
+-- parse an integer, we want to return @0@ by default:
+--
+-- >>> import Text.Read ( readMaybe )
+-- >>> fromMaybe 0 (readMaybe "5")
+-- 5
+-- >>> fromMaybe 0 (readMaybe "")
+-- 0
+--
 fromMaybe     :: a -> Maybe a -> a
 fromMaybe d x = case x of {Nothing -> d;Just v  -> v}
 
 -- | The 'maybeToList' function returns an empty list when given
 -- 'Nothing' or a singleton list when not given 'Nothing'.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> maybeToList (Just 7)
+-- [7]
+--
+-- >>> maybeToList Nothing
+-- []
+--
+-- One can use 'maybeToList' to avoid pattern matching when combined
+-- with a function that (safely) works on lists:
+--
+-- >>> import Text.Read ( readMaybe )
+-- >>> sum $ maybeToList (readMaybe "3")
+-- 3
+-- >>> sum $ maybeToList (readMaybe "")
+-- 0
+--
 maybeToList            :: Maybe a -> [a]
 maybeToList  Nothing   = []
 maybeToList  (Just x)  = [x]
 
 -- | The 'listToMaybe' function returns 'Nothing' on an empty list
 -- or @'Just' a@ where @a@ is the first element of the list.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> listToMaybe []
+-- Nothing
+--
+-- >>> listToMaybe [9]
+-- Just 9
+--
+-- >>> listToMaybe [1,2,3]
+-- Just 1
+--
+-- Composing 'maybeToList' with 'listToMaybe' should be the identity
+-- on singleton/empty lists:
+--
+-- >>> maybeToList $ listToMaybe [5]
+-- [5]
+-- >>> maybeToList $ listToMaybe []
+-- []
+--
+-- But not on lists with more than one element:
+--
+-- >>> maybeToList $ listToMaybe [1,2,3]
+-- [1]
+--
 listToMaybe           :: [a] -> Maybe a
 listToMaybe []        =  Nothing
 listToMaybe (a:_)     =  Just a
 
 -- | The 'catMaybes' function takes a list of 'Maybe's and returns
 -- a list of all the 'Just' values.
+--
+-- ==== __Examples__
+--
+-- Basic usage:
+--
+-- >>> catMaybes [Just 1, Nothing, Just 3]
+-- [1,3]
+--
+-- When constructing a list of 'Maybe' values, 'catMaybes' can be used
+-- to return all of the \"success\" results (if the list is the result
+-- of a 'map', then 'mapMaybe' would be more appropriate):
+--
+-- >>> import Text.Read ( readMaybe )
+-- >>> [readMaybe x :: Maybe Int | x <- ["1", "Foo", "3"] ]
+-- [Just 1,Nothing,Just 3]
+-- >>> catMaybes $ [readMaybe x :: Maybe Int | x <- ["1", "Foo", "3"] ]
+-- [1,3]
+--
 catMaybes              :: [Maybe a] -> [a]
 catMaybes ls = [x | Just x <- ls]
 
@@ -89,6 +260,24 @@ catMaybes ls = [x | Just x <- ls]
 -- something of type @'Maybe' b@.  If this is 'Nothing', no element
 -- is added on to the result list.  If it is @'Just' b@, then @b@ is
 -- included in the result list.
+--
+-- ==== __Examples__
+--
+-- Using @'mapMaybe' f x@ is a shortcut for @'catMaybes' $ 'map' f x@
+-- in most cases:
+--
+-- >>> import Text.Read ( readMaybe )
+-- >>> let readMaybeInt = readMaybe :: String -> Maybe Int
+-- >>> mapMaybe readMaybeInt ["1", "Foo", "3"]
+-- [1,3]
+-- >>> catMaybes $ map readMaybeInt ["1", "Foo", "3"]
+-- [1,3]
+--
+-- If we map the 'Just' constructor, the entire list should be returned:
+--
+-- >>> mapMaybe Just [1,2,3]
+-- [1,2,3]
+--
 mapMaybe          :: (a -> Maybe b) -> [a] -> [b]
 mapMaybe _ []     = []
 mapMaybe f (x:xs) =