build: Move Vulkan shader handling to its own directory

Spooky action at a distance is not really allowed in Meson, so the rules
to generate the SPV files should go in their own directory.

Tested by: Rico Tzschichholz <ricotz@ubuntu.com>

1 files changed, 56 insertions, 0 deletions

diff --git a/gsk/resources/vulkan/meson.build b/gsk/resources/vulkan/meson.build
new file mode 100644
index 0000000000..d3b01fae2d
--- /dev/null
+++ b/gsk/resources/vulkan/meson.build
@@ -0,0 +1,56 @@
+# FIXME: what's up with these?
+#gsk_private_vulkan_include_shaders = [
+#  'clip.frag.glsl',
+#  'clip.vert.glsl',
+#  'constants.glsl',
+#  'rounded-rect.glsl',
+#]
+
+gsk_private_vulkan_fragment_shaders = [
+  'blend.frag',
+  'border.frag',
+  'color.frag',
+  'color-matrix.frag',
+  'inset-shadow.frag',
+  'linear.frag',
+  'outset-shadow.frag',
+]
+
+gsk_private_vulkan_vertex_shaders = [
+  'blend.vert',
+  'border.vert',
+  'color.vert',
+  'color-matrix.vert',
+  'inset-shadow.vert',
+  'linear.vert',
+  'outset-shadow.vert',
+]
+
+gsk_private_vulkan_shaders += gsk_private_vulkan_fragment_shaders
+gsk_private_vulkan_shaders += gsk_private_vulkan_vertex_shaders
+
+glslc = find_program('glslc', required: false)
+foreach shader: gsk_private_vulkan_shaders
+  basefn = shader.split('.').get(0)
+  suffix = shader.split('.').get(1)
+
+  stage_arg = suffix == 'frag' ? '-fshader-stage=fragment' : '-fshader-stage=vertex'
+  spv_shader = '@0@.@1@.spv'.format(basefn, suffix)
+
+  if glslc.found()
+    compiled_shader = custom_target(spv_shader,
+                                    input: shader,
+                                    output: spv_shader,
+                                    build_by_default: true,
+                                    command: [
+                                      glslc,
+                                      stage_arg,
+                                      '-DCLIP_NONE',
+                                      '@INPUT@',
+                                      '-o', '@OUTPUT@'
+                                    ])
+  endif
+  gsk_private_vulkan_compiled_shaders += files(spv_shader)
+  gsk_private_vulkan_compiled_shaders += '@0@-clip.@1@.spv'.format(basefn, suffix)
+  gsk_private_vulkan_compiled_shaders += '@0@-clip-rounded.@1@.spv'.format(basefn, suffix)
+endforeach